mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-19 11:30:06 +00:00
ab95290c78
2000-06-13 Ulrich Drepper <drepper@redhat.com> * misc/sys/cdefs.h: Define __bounded and __unbounded if __BOUNDED_POINTERS__ is not defined. 2000-06-07 Greg McGary <greg@mcgary.org> * sysdeps/generic/bp-sym.h: New file. * sysdeps/generic/bp-start.h: New file. * sysdeps/i386/elf/start.S: Designate BP symbols. * sysdeps/generic/libc-start.c: Wrap bounds around argv & envp and each of their string members. 2000-06-07 Greg McGary <greg@mcgary.org> * sysdeps/unix/make-syscalls.sh: Add comments to output that aid debugging & comprehension. Map simple syscall signatures to number of args. Generate BP syscall thunk definitions. * sysdeps/generic/bp-thunks.h: New file. * sysdeps/unix/syscalls.list: Replace arg-count with simple return+arg signature. * sysdeps/unix/common/syscalls.list: Likewise. * sysdeps/unix/inet/syscalls.list: Likewise. * sysdeps/unix/mman/syscalls.list: Likewise. * sysdeps/unix/sysv/syscalls.list: Likewise. * sysdeps/unix/sysv/linux/syscalls.list: Likewise. * sysdeps/unix/sysv/linux/i386/syscalls.list: Likewise. 2000-06-07 Greg McGary <greg@mcgary.org> * Makeconfig (CPPFLAGS-.ob): pass -fbounded-pointers for all files *.[cS]. (CFLAGS-.ob): Don't optimize sibling calls. (bppfx): New variable. * Makerules (elide-bp-thunks): New variable. (elide-routines.*): Elide BP-* files for all but *.ob. (sources): Include bp-thunks. * iconv/gconv_simple.c: Remove unnecessary prototype. * iconv/gconv_trans.c: Pretty print.
97 lines
3.2 KiB
ArmAsm
97 lines
3.2 KiB
ArmAsm
/* Startup code compliant to the ELF i386 ABI.
|
|
Copyright (C) 1995, 1996, 1997, 1998, 2000 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
/* This is the canonical entry point, usually the first thing in the text
|
|
segment. The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
|
|
point runs, most registers' values are unspecified, except for:
|
|
|
|
%edx Contains a function pointer to be registered with `atexit'.
|
|
This is how the dynamic linker arranges to have DT_FINI
|
|
functions called for shared libraries that have been loaded
|
|
before this code runs.
|
|
|
|
%esp The stack contains the arguments and environment:
|
|
0(%esp) argc
|
|
4(%esp) argv[0]
|
|
...
|
|
(4*argc)(%esp) NULL
|
|
(4*(argc+1))(%esp) envp[0]
|
|
...
|
|
NULL
|
|
*/
|
|
|
|
#include "bp-sym.h"
|
|
|
|
.text
|
|
.globl _start
|
|
_start:
|
|
/* Clear the frame pointer. The ABI suggests this be done, to mark
|
|
the outermost frame obviously. */
|
|
xorl %ebp, %ebp
|
|
|
|
/* Extract the arguments as encoded on the stack and set up
|
|
the arguments for `main': argc, argv. envp will be determined
|
|
later in __libc_start_main. */
|
|
popl %esi /* Pop the argument count. */
|
|
movl %esp, %ecx /* argv starts just at the current stack top.*/
|
|
|
|
/* Before pushing the arguments align the stack to a double word
|
|
boundary to avoid penalties from misaligned accesses. Thanks
|
|
to Edward Seidl <seidl@janed.com> for pointing this out. */
|
|
andl $0xfffffff8, %esp
|
|
pushl %eax /* Push garbage because we allocate
|
|
28 more bytes. */
|
|
|
|
/* Provide the highest stack address to the user code (for stacks
|
|
which grow downwards). */
|
|
pushl %esp
|
|
|
|
pushl %edx /* Push address of the shared library
|
|
termination function. */
|
|
|
|
/* Push address of our own entry points to .fini and .init. */
|
|
pushl $_fini
|
|
pushl $_init
|
|
|
|
pushl %ecx /* Push second argument: argv. */
|
|
pushl %esi /* Push first argument: argc. */
|
|
|
|
pushl $BP_SYM (main)
|
|
|
|
/* Call the user's main function, and exit with its value.
|
|
But let the libc call main. */
|
|
call BP_SYM (__libc_start_main)
|
|
|
|
hlt /* Crash if somehow `exit' does return. */
|
|
|
|
/* To fulfill the System V/i386 ABI we need this symbol. Yuck, it's so
|
|
meaningless since we don't support machines < 80386. */
|
|
.section .rodata
|
|
.globl _fp_hw
|
|
.long 3
|
|
.size _fp_hw, 4
|
|
|
|
/* Define a symbol for the first piece of initialized data. */
|
|
.data
|
|
.globl __data_start
|
|
__data_start:
|
|
.long 0
|
|
.weak data_start
|
|
data_start = __data_start
|