mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-22 13:00:06 +00:00
d9266ea02f
* iconvdata/extra-module.mk: Use build-module-asneeded. needed. 2006-01-09 Richard Henderson <rth@redhat.com> * iconvdata/extra-module.mk ($(objpfx)$(mod).so): Depend on ld.so. * sysdeps/alpha/__longjmp.S: Use PTR_DEMANGLE. * sysdeps/alpha/setjmp.S: Likewise. Avoid __sigjmp_save for rtld; tailcall in libc.so. * sysdeps/unix/sysv/linux/alpha/sysdep.h (PTR_MANGLE): Define. (PTR_MANGLE2): Define. 2006-01-11 Ulrich Drepper <drepper@redhat.com>
123 lines
2.7 KiB
ArmAsm
123 lines
2.7 KiB
ArmAsm
/* Copyright (C) 1992, 1994, 1996, 1997, 2002 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
#define __ASSEMBLY__
|
|
|
|
#include <sysdep.h>
|
|
#define _ASM
|
|
#define _SETJMP_H
|
|
#include <bits/setjmp.h>
|
|
|
|
.ent __sigsetjmp
|
|
.global __sigsetjmp
|
|
__sigsetjmp:
|
|
ldgp gp, 0(pv)
|
|
|
|
$sigsetjmp_local:
|
|
#ifndef PIC
|
|
#define FRAME 16
|
|
subq sp, FRAME, sp
|
|
.frame sp, FRAME, ra, 0
|
|
stq ra, 0(sp)
|
|
.mask 0x04000000, -FRAME
|
|
#else
|
|
#define FRAME 0
|
|
.frame sp, FRAME, ra, 0
|
|
#endif
|
|
#ifdef PROF
|
|
.set noat
|
|
lda AT, _mcount
|
|
jsr AT, (AT), _mcount
|
|
.set at
|
|
#endif
|
|
.prologue 1
|
|
|
|
stq s0, JB_S0*8(a0)
|
|
stq s1, JB_S1*8(a0)
|
|
stq s2, JB_S2*8(a0)
|
|
stq s3, JB_S3*8(a0)
|
|
stq s4, JB_S4*8(a0)
|
|
stq s5, JB_S5*8(a0)
|
|
#ifdef PTR_MANGLE
|
|
PTR_MANGLE(t1, ra, t0)
|
|
stq t1, JB_PC*8(a0)
|
|
#else
|
|
stq ra, JB_PC*8(a0)
|
|
#endif
|
|
#if defined(PTR_MANGLE) && FRAME == 0
|
|
PTR_MANGLE2(t1, sp, t0)
|
|
#else
|
|
addq sp, FRAME, t1
|
|
# ifdef PTR_MANGLE
|
|
PTR_MANGLE2(t1, t1, t0)
|
|
# endif
|
|
#endif
|
|
stq t1, JB_SP*8(a0)
|
|
#ifdef PTR_MANGLE
|
|
PTR_MANGLE2(t1, fp, t0)
|
|
stq t1, JB_FP*8(a0)
|
|
#else
|
|
stq fp, JB_FP*8(a0)
|
|
#endif
|
|
stt $f2, JB_F2*8(a0)
|
|
stt $f3, JB_F3*8(a0)
|
|
stt $f4, JB_F4*8(a0)
|
|
stt $f5, JB_F5*8(a0)
|
|
stt $f6, JB_F6*8(a0)
|
|
stt $f7, JB_F7*8(a0)
|
|
stt $f8, JB_F8*8(a0)
|
|
stt $f9, JB_F9*8(a0)
|
|
|
|
#ifndef PIC
|
|
/* Call to C to (potentially) save our signal mask. */
|
|
jsr ra, __sigjmp_save
|
|
ldq ra, 0(sp)
|
|
addq sp, 16, sp
|
|
ret
|
|
#elif defined NOT_IN_libc && defined IS_IN_rtld
|
|
/* In ld.so we never save the signal mask. */
|
|
mov 0, v0
|
|
ret
|
|
#else
|
|
/* Tailcall to save the signal mask. */
|
|
br $31, __sigjmp_save !samegp
|
|
#endif
|
|
|
|
END(__sigsetjmp)
|
|
|
|
/* Put these traditional entry points in the same file so that we can
|
|
elide much of the nonsense in trying to jmp to the real function. */
|
|
|
|
ENTRY(_setjmp)
|
|
ldgp gp, 0(pv)
|
|
.prologue 1
|
|
mov 0, a1
|
|
br $sigsetjmp_local
|
|
END(_setjmp)
|
|
libc_hidden_def (_setjmp)
|
|
|
|
ENTRY(setjmp)
|
|
ldgp gp, 0(pv)
|
|
.prologue 1
|
|
mov 1, a1
|
|
br $sigsetjmp_local
|
|
END(setjmp)
|
|
|
|
weak_extern(_setjmp)
|
|
weak_extern(setjmp)
|