mirror of
https://sourceware.org/git/glibc.git
synced 2024-09-21 17:04:05 +00:00
e15867921d
1998-02-09 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * sysdeps/unix/sysv/linux/syscalls.list: Don't mark lchown as extra syscall. * grp/Makefile: Fix logic when checking for thread package. * pwd/Makefile: Likewise. 1998-02-11 08:23 H.J. Lu <hjl@gnu.org> * elf/Makefile (rtld-map): Replaced by libc-map. * elf/rtld.map: Removed. * libc.map (__libc_enable_secure, _dl_catch_error, _dl_check_all_versions, _dl_debug_initialize, _dl_debug_state, _dl_default_scope, _dl_global_scope_end, _dl_init_next, _dl_lookup_symbol, _dl_map_object, _dl_map_object_deps, _dl_object_relocation_scope, _dl_relocate_object, _dl_signal_error, _dl_starting_up, _dl_sysdep_start, _r_debug): Added for ld.so. 1998-02-10 08:38 H.J. Lu <hjl@gnu.org> * libio/iofclose.c: Check PIC && DO_VERSIONING instead of DO_VERSIONING. * libio/iofdopen.c: Ditto. * libio/iofopen.c: Ditto. * libio/oldfileops.c: Ditto. * libc.map (sys_nerr, _sys_errlist, sys_errlist): Added for version GLIBC_2.1. * sysdeps/unix/sysv/linux/Makefile (stdio-common): Removed oldsiglist from sysdep_routines and shared-only-routines. * sysdeps/unix/sysv/linux/errlist.c: New. * sysdeps/unix/sysv/linux/errlist.h: New. * sysdeps/unix/sysv/linux/sizes.h: New. * sysdeps/unix/sysv/linux/alpha/sizes.h: New. * sysdeps/unix/sysv/linux/sparc64/sizes.h: New. * sysdeps/unix/sysv/linux/oldsiglist.c: Removed. * sysdeps/unix/sysv/linux/siglist.c: Include <sizes.h>. (__old_sys_siglist, __old_sys_sigabbrev): Use ELF .size directive. * sysdeps/unix/sysv/linux/siglist.h (OLD_SIGLIST_SIZE_STR): New. * sysdeps/unix/sysv/linux/Dist (errlist.h, sizes.h.): Added. (oldsiglist.c): Removed. * sysdeps/gnu/errlist.awk (SYS_SIGLIST, SYS_NERR): New. (_sys_siglist): Use SYS_SIGLIST instead. (_sys_nerr): Use SYS_NERR instead. * sysdeps/gnu/errlist.c: Rebuilt. 1998-02-11 08:35 H.J. Lu <hjl@gnu.org> * elf/Makefile (others-static): New, set to ldconfig. ($(objpfx)ldconfig): Removed. * Rules (binaries-all, binaries-static, binaries-shared): New. Create targets for $(binaries-static) and $(binaries-shared). * Makeconfig (+link-static, link-libc-static, link-extra-libs-static): New for static linking.
93 lines
2.7 KiB
Awk
93 lines
2.7 KiB
Awk
# Copyright (C) 1991, 92, 93, 94, 95, 96, 97, 98 Free Software Foundation, Inc.
|
|
# This file is part of the GNU C Library.
|
|
|
|
# The GNU C Library is free software; you can redistribute it and/or
|
|
# modify it under the terms of the GNU Library General Public License
|
|
# as published by the Free Software Foundation; either version 2 of
|
|
# the License, or (at your option) any later version.
|
|
|
|
# The GNU C Library is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
# Library General Public License for more details.
|
|
|
|
# You should have received a copy of the GNU Library General Public
|
|
# License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
# write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
# Boston, MA 02111-1307, USA.
|
|
|
|
# errno.texi contains lines like:
|
|
# @comment errno.h
|
|
# @comment POSIX.1: Function not implemented
|
|
# @deftypevr Macro int ENOSYS
|
|
# @comment errno 78
|
|
# Descriptive paragraph...
|
|
# @end deftypevr
|
|
|
|
BEGIN {
|
|
alias["EWOULDBLOCK"] = "EAGAIN";
|
|
alias["EDEADLOCK"] = "EDEADLK";
|
|
|
|
print "/* This file is generated from errno.texi by errlist.awk. */"
|
|
print "";
|
|
print "#include <errno.h>";
|
|
print "";
|
|
print "#ifndef SYS_ERRLIST";
|
|
print "# define SYS_ERRLIST _sys_errlist";
|
|
print "#endif";
|
|
print "#ifndef SYS_NERR";
|
|
print "# define SYS_NERR _sys_nerr";
|
|
print "#endif";
|
|
print "";
|
|
print "const char *const SYS_ERRLIST[] =";
|
|
print " {";
|
|
print " [0] = N_(\"Success\"),"
|
|
}
|
|
$1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
|
|
errnoh == 1 && $1 == "@comment" \
|
|
{
|
|
++errnoh;
|
|
etext = $3;
|
|
for (i = 4; i <= NF; ++i)
|
|
etext = etext " " $i;
|
|
next;
|
|
}
|
|
errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
|
|
{
|
|
e = $4; errnoh++; next;
|
|
}
|
|
errnoh == 3 && $1 == "@comment" && $2 == "errno" \
|
|
{
|
|
errno = $3 + 0;
|
|
if (alias[e])
|
|
printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
|
|
else
|
|
printf "#ifdef %s\n", e;
|
|
errnoh = 4;
|
|
desc="";
|
|
next;
|
|
}
|
|
errnoh == 4 && $1 == "@end" && $2 == "deftypevr" \
|
|
{
|
|
printf "/*%s */\n", desc;
|
|
printf " [%s] = N_(\"%s\"),\n", e, etext;
|
|
print "#endif";
|
|
errnoh = 0;
|
|
next;
|
|
}
|
|
errnoh == 4 \
|
|
{
|
|
# This magic tag in C comments gets them copied into libc.pot.
|
|
desc = desc "\nTRANS " $0; next
|
|
}
|
|
{ errnoh=0 }
|
|
END {
|
|
print " };";
|
|
print "";
|
|
print "const int SYS_NERR = sizeof SYS_ERRLIST / sizeof SYS_ERRLIST [0];";
|
|
print "#ifndef PIC";
|
|
print "weak_alias (_sys_errlist, sys_errlist)";
|
|
print "weak_alias (_sys_nerr, sys_nerr)";
|
|
print "#endif";
|
|
}
|