mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-06 13:20:06 +00:00
8cb079d41b
* sysdeps/sparc/sparc64/add_n.S: Avoid using %g2, %g3, %g7 registers as much as possible. Declare them using .register pseudo-op if they are still used. * sysdeps/sparc/sparc64/lshift.S: Likewise. * sysdeps/sparc/sparc64/memchr.S: Likewise. * sysdeps/sparc/sparc64/memcmp.S: Likewise. * sysdeps/sparc/sparc64/memcpy.S: Likewise. * sysdeps/sparc/sparc64/memset.S: Likewise. * sysdeps/sparc/sparc64/rawmemchr.S: Likewise. * sysdeps/sparc/sparc64/rshift.S: Likewise. * sysdeps/sparc/sparc64/stpcpy.S: Likewise. * sysdeps/sparc/sparc64/stpncpy.S: Likewise. * sysdeps/sparc/sparc64/strcat.S: Likewise. * sysdeps/sparc/sparc64/strchr.S: Likewise. * sysdeps/sparc/sparc64/strcmp.S: Likewise. * sysdeps/sparc/sparc64/strcpy.S: Likewise. * sysdeps/sparc/sparc64/strcspn.S: Likewise. * sysdeps/sparc/sparc64/strlen.S: Likewise. * sysdeps/sparc/sparc64/strncmp.S: Likewise. * sysdeps/sparc/sparc64/strncpy.S: Likewise. * sysdeps/sparc/sparc64/strpbrk.S: Likewise. * sysdeps/sparc/sparc64/strspn.S: Likewise. * sysdeps/sparc/sparc64/sub_n.S: Likewise. * sysdeps/sparc/sparc64/dl-machine.h: Likewise. Optimize trampoline code for .plt4-.plt32767. Fix trampolines for .plt32768+. 1999-07-25 Jakub Jelinek <jj@ultra.linux.cz>
59 lines
1.8 KiB
ArmAsm
59 lines
1.8 KiB
ArmAsm
/* SPARC v9 __mpn_add_n -- Add two limb vectors of the same length > 0 and
|
|
store sum in a third limb vector.
|
|
|
|
Copyright (C) 1995, 1996, 1997, 1999 Free Software Foundation, Inc.
|
|
|
|
This file is part of the GNU MP Library.
|
|
|
|
The GNU MP Library is free software; you can redistribute it and/or modify
|
|
it under the terms of the GNU Library General Public License as published by
|
|
the Free Software Foundation; either version 2 of the License, or (at your
|
|
option) any later version.
|
|
|
|
The GNU MP Library is distributed in the hope that it will be useful, but
|
|
WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public License
|
|
along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
MA 02111-1307, USA. */
|
|
|
|
|
|
#include <sysdep.h>
|
|
|
|
|
|
/* INPUT PARAMETERS
|
|
res_ptr %o0
|
|
s1_ptr %o1
|
|
s2_ptr %o2
|
|
size %o3 */
|
|
|
|
|
|
ENTRY(__mpn_add_n)
|
|
|
|
sub %g0,%o3,%g5
|
|
sllx %o3,3,%g1
|
|
add %o1,%g1,%o1 ! make s1_ptr point at end
|
|
add %o2,%g1,%o2 ! make s2_ptr point at end
|
|
add %o0,%g1,%o0 ! make res_ptr point at end
|
|
mov 0,%o4 ! clear carry variable
|
|
sllx %g5,3,%o5 ! compute initial address index
|
|
|
|
1: ldx [%o2+%o5],%g1 ! load s2 limb
|
|
add %g5,1,%g5 ! increment loop count
|
|
ldx [%o1+%o5],%o3 ! load s1 limb
|
|
addcc %g1,%o4,%g1 ! add s2 limb and carry variable
|
|
movcc %xcc,0,%o4 ! if carry-out, o4 was 1; clear it
|
|
addcc %g1,%o3,%g1 ! add s1 limb to sum
|
|
stx %g1,[%o0+%o5] ! store result
|
|
add %o5,8,%o5 ! increment address index
|
|
brnz,pt %g5,1b
|
|
movcs %xcc,1,%o4 ! if s1 add gave carry, record it
|
|
|
|
retl
|
|
mov %o4,%o0
|
|
|
|
END(__mpn_add_n)
|