mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-02 01:40:07 +00:00
0cb313f7cb
As discussed in libc-alpha [1] current clone with CLONE_VM (without
CLONE_THREAD set) will reset the pthread pid/tid fields to -1. The
issue is since memory is shared between the parent and child it will
clobber parent's cached pid/tid leading to internal inconsistencies
if the value is not restored.
And even it is restored it may lead to racy conditions when between
set/restore a thread might invoke pthread function that validate the
pthread with INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P and thus get
wrong results.
As stated in BZ19957, previously reports of this behaviour was close
with EWONTFIX due the fact usage of clone outside glibc is tricky
since glibc requires consistent internal pthread, while using clone
directly may not provide it. However since now posix_spawn uses
clone (CLONE_VM) to fixes various issues related to previous vfork
usage this issue requires fixing.
The vfork implementation also does something similar, but instead
it negates and restores only the *pid* field and functions that
might access its value know to handle such case (getpid, raise
and pthread ones that uses INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P
macros that check only *tid* field). Also vfork does not call
__clone directly, instead calling either __NR_vfork or __NR_clone
directly.
So this patch removes this clone behavior by avoiding setting
the pthread pid/tid field for CLONE_VM. There is no need to
check for CLONE_THREAD, since the minimum supported kernel in all
architecture implies that CLONE_VM must be used with CLONE_THREAD,
otherwise clone returns EINVAL.
Instead of current approach of:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_THREAD)
goto do_syscall;
pid_t new_value;
if (flags & CLONE_VM)
new_value = -1;
else
new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
The new approach uses:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_VM)
goto do_syscall;
pid_t new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
It also removes the linux tst-getpid2.c test which expects the previous
behavior and instead add another clone test.
Tested on x86_64, i686, x32, powerpc64le, aarch64, armhf, s390, and
s390x. I also did limited check on mips32 and sparc64 (using the new
added test).
I also got reviews from both m68k, hppa, and tile. So I presume for
these architecture the patch works.
The fixes for alpha, microblaze, sh, ia64, and nio2 have not been
tested.
[1] https://sourceware.org/ml/libc-alpha/2016-04/msg00307.html
* sysdeps/unix/sysv/linux/Makefile [$(subdir) == nptl] (test): Remove
tst-getpid2.
(test): Add tst-clone2.
* sysdeps/unix/sysv/linux/tst-clone2.c: New file.
* sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Do not change
pid/tid fields for CLONE_VM.
* sysdeps/unix/sysv/linux/arm/clone.S: Likewise.
* sysdeps/unix/sysv/linux/i386/clone.S: Likewise.
* sysdeps/unix/sysv/linux/mips/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/x86_64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/tst-getpid2.c: Remove file.
99 lines
2.3 KiB
ArmAsm
99 lines
2.3 KiB
ArmAsm
/* Copyright (C) 1996-2016 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Richard Henderson (rth@tamu.edu).
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <asm/errno.h>
|
|
#include <asm/unistd.h>
|
|
#include <tcb-offsets.h>
|
|
#include <sysdep.h>
|
|
|
|
#define CLONE_VM 0x00000100
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *ptid, void *tls, pid_t *ctid); */
|
|
|
|
.text
|
|
ENTRY (__clone)
|
|
save %sp,-96,%sp
|
|
cfi_def_cfa_register(%fp)
|
|
cfi_window_save
|
|
cfi_register(%o7, %i7)
|
|
|
|
/* sanity check arguments */
|
|
orcc %i0,%g0,%g2
|
|
be .Leinval
|
|
orcc %i1,%g0,%o1
|
|
be .Leinval
|
|
mov %i2,%o0
|
|
|
|
/* The child_stack is the top of the stack, allocate one
|
|
whole stack frame from that as this is what the kernel
|
|
expects. */
|
|
sub %o1, 96, %o1
|
|
mov %i3, %g3
|
|
mov %i2, %g4
|
|
|
|
/* ptid */
|
|
mov %i4,%o2
|
|
/* tls */
|
|
mov %i5,%o3
|
|
/* ctid */
|
|
ld [%fp+92],%o4
|
|
|
|
/* Do the system call */
|
|
set __NR_clone,%g1
|
|
ta 0x10
|
|
bcs .Lerror
|
|
tst %o1
|
|
bne __thread_start
|
|
nop
|
|
jmpl %i7 + 8, %g0
|
|
restore %o0,%g0,%o0
|
|
|
|
.Leinval:
|
|
mov EINVAL, %o0
|
|
.Lerror:
|
|
call HIDDEN_JUMPTARGET(__errno_location)
|
|
mov %o0, %i0
|
|
st %i0,[%o0]
|
|
jmpl %i7 + 8, %g0
|
|
restore %g0,-1,%o0
|
|
END(__clone)
|
|
|
|
.type __thread_start,@function
|
|
__thread_start:
|
|
andcc %g4, CLONE_VM, %g0
|
|
bne 1f
|
|
set __NR_getpid,%g1
|
|
ta 0x10
|
|
st %o0,[%g7 + PID]
|
|
st %o0,[%g7 + TID]
|
|
1:
|
|
mov %g0, %fp /* terminate backtrace */
|
|
call %g2
|
|
mov %g3,%o0
|
|
call HIDDEN_JUMPTARGET(_exit),0
|
|
nop
|
|
|
|
.size __thread_start, .-__thread_start
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|