mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-03 02:11:08 +00:00
30891f35fa
We stopped adding "Contributed by" or similar lines in sources in 2012 in favour of git logs and keeping the Contributors section of the glibc manual up to date. Removing these lines makes the license header a bit more consistent across files and also removes the possibility of error in attribution when license blocks or files are copied across since the contributed-by lines don't actually reflect reality in those cases. Move all "Contributed by" and similar lines (Written by, Test by, etc.) into a new file CONTRIBUTED-BY to retain record of these contributions. These contributors are also mentioned in manual/contrib.texi, so we just maintain this additional record as a courtesy to the earlier developers. The following scripts were used to filter a list of files to edit in place and to clean up the CONTRIBUTED-BY file respectively. These were not added to the glibc sources because they're not expected to be of any use in future given that this is a one time task: https://gist.github.com/siddhesh/b5ecac94eabfd72ed2916d6d8157e7dc https://gist.github.com/siddhesh/15ea1f5e435ace9774f485030695ee02 Reviewed-by: Carlos O'Donell <carlos@redhat.com>
98 lines
2.0 KiB
ArmAsm
98 lines
2.0 KiB
ArmAsm
/* Copy memory block and return pointer to beginning of destination block
|
|
For Intel 80x86, x>=6.
|
|
This file is part of the GNU C Library.
|
|
Copyright (C) 1999-2021 Free Software Foundation, Inc.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<https://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
#include "asm-syntax.h"
|
|
|
|
#define PARMS 4 /* no space for saved regs */
|
|
#define RTN PARMS
|
|
#define DEST RTN
|
|
#define SRC DEST+4
|
|
#define LEN SRC+4
|
|
|
|
.text
|
|
#if defined PIC && IS_IN (libc)
|
|
ENTRY_CHK (__memcpy_chk)
|
|
movl 12(%esp), %eax
|
|
cmpl %eax, 16(%esp)
|
|
jb HIDDEN_JUMPTARGET (__chk_fail)
|
|
END_CHK (__memcpy_chk)
|
|
#endif
|
|
ENTRY (memcpy)
|
|
|
|
movl %edi, %eax
|
|
movl DEST(%esp), %edi
|
|
movl %esi, %edx
|
|
movl SRC(%esp), %esi
|
|
|
|
movl %edi, %ecx
|
|
xorl %esi, %ecx
|
|
andl $3, %ecx
|
|
movl LEN(%esp), %ecx
|
|
cld
|
|
jne .Lunaligned
|
|
|
|
cmpl $3, %ecx
|
|
jbe .Lunaligned
|
|
|
|
testl $3, %esi
|
|
je 1f
|
|
movsb
|
|
decl %ecx
|
|
testl $3, %esi
|
|
je 1f
|
|
movsb
|
|
decl %ecx
|
|
testl $3, %esi
|
|
je 1f
|
|
movsb
|
|
decl %ecx
|
|
1: pushl %eax
|
|
movl %ecx, %eax
|
|
shrl $2, %ecx
|
|
andl $3, %eax
|
|
rep
|
|
movsl
|
|
movl %eax, %ecx
|
|
rep
|
|
movsb
|
|
popl %eax
|
|
|
|
.Lend: movl %eax, %edi
|
|
movl %edx, %esi
|
|
movl DEST(%esp), %eax
|
|
|
|
ret
|
|
|
|
/* When we come here the pointers do not have the same
|
|
alignment or the length is too short. No need to optimize for
|
|
aligned memory accesses. */
|
|
.Lunaligned:
|
|
shrl $1, %ecx
|
|
jnc 1f
|
|
movsb
|
|
1: shrl $1, %ecx
|
|
jnc 2f
|
|
movsw
|
|
2: rep
|
|
movsl
|
|
jmp .Lend
|
|
END (memcpy)
|
|
libc_hidden_builtin_def (memcpy)
|