mirror of
https://sourceware.org/git/glibc.git
synced 2024-10-03 04:27:39 +00:00
f166d86530
1997-03-09 06:59 Ulrich Drepper <drepper@cygnus.com> * Makeconfig: Add ASFLAGS-% flags for SPARC assembler which need -fPIC. * Makerules (compile.S): Use ASFLAGS-%. (COMPILE.S): Likewise. * config.make.in (ASFLAGS-.so): Define from ASFLAGS_SO. * configure.in: Substitute ASFLAGS_SO. * sysdeps/sparc/configure.in: New file. * posix/unitstd.h: Add prototype for __euidaccess. * sysdeps/posix/euidaccess.c: Define as __euidaccess and make euidaccess weak alias. * sysdeps/stubs/euidaccess.c: Likewise. * inet/rcmd.c: Use __ protected versions of non-standard functions. * locale/setlocale.c (setlocale): Don't set usage_count to MAX_USAGE_COUNT if it already has this value. * locale/programs/localedef.c: Don't use LOCALE_PATH to find binary locale files. Use LOCALEDIR only. * locale/programs/locfile.c: When named file not found and not absolute use path in I18NPATH. * stdlib/Makefile (headers): Add inttypes.h. * sysdpes/generic/socketbits.h: Add PF_FILE as synonym for PF_LOCAL and AF_FILE as synonym for AF_LOCAL. * sysdpes/unix/sysv/linux/socketbits.h: Likewise. * time/Makefile: Rewrite rules for test to handle parallel builds. 1997-03-09 05:26 Ulrich Drepper <drepper@cygnus.com> * manual/startup.texi (EXIT_FAILURE): Fix typo. Patch by robbe@orcus.priv.at. 1997-03-09 05:10 Edward Seidl <seidl@janed.com> * sysdeps/i386/elf/start.S (nofini): *Really* align stack to 8-byte boundary. 1997-03-09 01:48 Ulrich Drepper <drepper@cygnus.com> * elf/link.h: Define __need_NULL to get definition. Include <features.h>. Patch by Andreas Jaeger <aj@arthur.pfalz.de>. 1997-03-08 21:48 Thorsten Kukuk <kukuk@tk.uni-paderborn.de> Rewrite NIS code to allow empty keys. * nis/nss_nis/nis-ethers.c: Rewritten. * nis/nss_nis/nis-proto.c: Rewritten. * nis/nss_nis/nis-publickey.c: Rewritten. * nis/nss_nis/nis-rpc.c: Rewritten. * nis/nss_nis/nis-service.c: Rewritten. 1997-03-08 16:02 Andreas Jaeger <aj@arthur.pfalz.de> * time/scheck.c (scheck): Add extra const to second argument. * time/private.h: Correct prototypes to match definition. 1997-03-08 18:55 Ulrich Drepper <drepper@cygnus.com> * sysdeps/alpha/__math.h: Remove cabs inline definition. Reported by Philip Blundell <pjb27@cam.ac.uk>. Reported by Andreas Schwab <schwab@issan.informatik.uni-dortmund.de>. Bug report by Andreas Jaeger <jaeger@informatik.uni-kl.de>.
104 lines
3.7 KiB
ArmAsm
104 lines
3.7 KiB
ArmAsm
/* Startup code compliant to the ELF i386 ABI.
|
|
Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
/* This is the canonical entry point, usually the first thing in the text
|
|
segment. The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
|
|
point runs, most registers' values are unspecified, except for:
|
|
|
|
%edx Contains a function pointer to be registered with `atexit'.
|
|
This is how the dynamic linker arranges to have DT_FINI
|
|
functions called for shared libraries that have been loaded
|
|
before this code runs.
|
|
|
|
%esp The stack contains the arguments and environment:
|
|
0(%esp) argc
|
|
4(%esp) argv[0]
|
|
...
|
|
(4*argc)(%esp) NULL
|
|
(4*(argc+1))(%esp) envp[0]
|
|
...
|
|
NULL
|
|
*/
|
|
|
|
.text
|
|
.globl _start
|
|
_start:
|
|
/* Clear the frame pointer. The ABI suggests this be done, to mark
|
|
the outermost frame obviously. */
|
|
xorl %ebp, %ebp
|
|
|
|
/* %edx contains the address of the shared library termination
|
|
function, which we will register with `atexit' to be called by
|
|
`exit'. I suspect that on some systems, and when statically
|
|
linked, this will not be set by anything to any function
|
|
pointer; hopefully it will be zero so we don't try to call
|
|
random pointers. */
|
|
testl %edx,%edx
|
|
jz nofini
|
|
pushl %edx
|
|
call atexit
|
|
popl %eax /* Pop value to unused register to remove
|
|
argument from stack. */
|
|
nofini:
|
|
|
|
/* Do essential libc initialization. In statically linked
|
|
programs under the GNU Hurd, this is what sets up the
|
|
arguments on the stack for the code below. */
|
|
call __libc_init_first
|
|
|
|
/* Extract the arguments and environment as encoded on the stack
|
|
and set up the arguments for `main': argc, argv, envp. */
|
|
popl %esi /* Pop the argument count. */
|
|
leal 4(%esp,%esi,4), %eax /* envp = &argv[argc + 1] */
|
|
movl %eax, _environ /* Store it in the global variable. */
|
|
movl %esp, %edx /* argv starts just at the current stack top.*/
|
|
|
|
/* Before pushing the arguments align the stack to a double word
|
|
boundary to avoid penalties from misaligned accesses. Thanks
|
|
to Edward Seidl <seidl@janed.com> for pointing this out. */
|
|
andl $0xfffffff8, %esp
|
|
pushl %eax /* Push garbage because we allocate
|
|
twelve more bytes. */
|
|
|
|
pushl %eax /* Push third argument: envp. */
|
|
pushl %edx /* Push second argument: argv. */
|
|
pushl %esi /* Push first argument: argc. */
|
|
|
|
/* Call `_init', which is the entry point to our own `.init'
|
|
section; and register with `atexit' to have `exit' call
|
|
`_fini', which is the entry point to our own `.fini' section. */
|
|
call _init
|
|
pushl $_fini
|
|
call atexit
|
|
popl %eax
|
|
|
|
/* Call the user's main function, and exit with its value. */
|
|
call main
|
|
pushl %eax
|
|
call exit
|
|
hlt /* Crash if somehow `exit' does return. */
|
|
|
|
/* Define a symbol for the first piece of initialized data. */
|
|
.data
|
|
.globl __data_start
|
|
__data_start:
|
|
.long 0
|
|
.weak data_start
|
|
data_start = __data_start
|