mirror of
https://sourceware.org/git/glibc.git
synced 2024-11-15 01:21:06 +00:00
f8ba1b5654
As with other issues of this kind, bug 17042 is log2 (1) wrongly returning -0 instead of +0 in round-downward mode because of implementations effectively in terms of log1p (x - 1). This patch fixes the issue in the same way used for log and log10. Tested x86_64 and x86 and ulps updated accordingly. Also tested for mips64 to confirm a fix was needed for ldbl-128 and to validate that fix (also applied to ldbl-128ibm since that version of log2l is essentially the same as the ldbl-128 one). [BZ #17042] * sysdeps/i386/fpu/e_log2.S (__ieee754_log2): Take absolete value when x - 1 is zero. * sysdeps/i386/fpu/e_log2f.S (__ieee754_log2f): Likewise. * sysdeps/i386/fpu/e_log2l.S (__ieee754_log2l): Likewise. * sysdeps/ieee754/ldbl-128/e_log2l.c (__ieee754_log2l): Return 0.0L for an argument of 1.0L. * sysdeps/ieee754/ldbl-128ibm/e_log2l.c (__ieee754_log2l): Likewise. * sysdeps/x86_64/fpu/e_log2l.S (__ieee754_log2l): Take absolute value when x - 1 is zero. * math/libm-test.inc (log2_test): Use ALL_RM_TEST. * sysdeps/i386/fpu/libm-test-ulps: Update. * sysdeps/x86_64/fpu/libm-test-ulps: Likewise.
85 lines
1.6 KiB
ArmAsm
85 lines
1.6 KiB
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@netbsd.org>.
|
|
* Adapted for use as log2 by Ulrich Drepper <drepper@cygnus.com>.
|
|
* Public domain.
|
|
*
|
|
* Changed to use fyl2xp1 for values near 1, <drepper@cygnus.com>.
|
|
* Adapted for x86-64 by Andreas Jaeger <aj@suse.de>.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
.section .rodata.cst8,"aM",@progbits,8
|
|
|
|
.p2align 3
|
|
.type one,@object
|
|
one: .double 1.0
|
|
ASM_SIZE_DIRECTIVE(one)
|
|
/* It is not important that this constant is precise. It is only
|
|
a value which is known to be on the safe side for using the
|
|
fyl2xp1 instruction. */
|
|
.type limit,@object
|
|
limit: .double 0.29
|
|
ASM_SIZE_DIRECTIVE(limit)
|
|
|
|
|
|
#ifdef PIC
|
|
# define MO(op) op##(%rip)
|
|
#else
|
|
# define MO(op) op
|
|
#endif
|
|
|
|
.text
|
|
ENTRY(__ieee754_log2l)
|
|
fldl MO(one)
|
|
fldt 8(%rsp) // x : 1
|
|
fxam
|
|
fnstsw
|
|
fld %st // x : x : 1
|
|
testb $1, %ah
|
|
jnz 3f // in case x is NaN or ±Inf
|
|
4: fsub %st(2), %st // x-1 : x : 1
|
|
fld %st // x-1 : x-1 : x : 1
|
|
fabs // |x-1| : x-1 : x : 1
|
|
fcompl MO(limit) // x-1 : x : 1
|
|
fnstsw // x-1 : x : 1
|
|
andb $0x45, %ah
|
|
jz 2f
|
|
fxam
|
|
fnstsw
|
|
andb $0x45, %ah
|
|
cmpb $0x40, %ah
|
|
jne 5f
|
|
fabs // log2(1) is +0 in all rounding modes.
|
|
5: fstp %st(1) // x-1 : 1
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
|
|
2: fstp %st(0) // x : 1
|
|
fyl2x // log(x)
|
|
ret
|
|
|
|
3: testb $4, %ah
|
|
jnz 4b // in case x is ±Inf
|
|
fstp %st(1)
|
|
fstp %st(1)
|
|
ret
|
|
END (__ieee754_log2l)
|
|
|
|
|
|
ENTRY(__log2l_finite)
|
|
fldl MO(one)
|
|
fldt 8(%rsp) // x : 1
|
|
fld %st // x : x : 1
|
|
fsub %st(2), %st // x-1 : x : 1
|
|
fld %st // x-1 : x-1 : x : 1
|
|
fabs // |x-1| : x-1 : x : 1
|
|
fcompl MO(limit) // x-1 : x : 1
|
|
fnstsw // x-1 : x : 1
|
|
andb $0x45, %ah
|
|
jz 2b
|
|
fstp %st(1) // x-1 : 1
|
|
fyl2xp1 // log(x)
|
|
ret
|
|
END (__log2l_finite)
|