mirror of
https://sourceware.org/git/glibc.git
synced 2024-09-29 18:47:50 +00:00
65c6899079
2003-02-07 Jakub Jelinek <jakub@redhat.com> * tst-popen2.c: New test. * Makefile (tests): Add tst-popen2. * sysdeps/unix/sysv/linux/alpha/vfork.S (__vfork): Branch to __fork whenever libpthread.so is loaded. * sysdeps/unix/sysv/linux/i386/vfork.S (__vfork): Likewise. * sysdeps/unix/sysv/linux/ia64/vfork.S (__vfork): Likewise. * sysdeps/unix/sysv/linux/s390/s390-64/vfork.S (__vfork): Likewise. * sysdeps/unix/sysv/linux/powerpc/powerpc32/vfork.S (__vfork): Likewise. * sysdeps/unix/sysv/linux/sparc/sparc32/vfork.S (__vfork): Likewise. * sysdeps/unix/sysv/linux/sparc/sparc64/vfork.S (__vfork): Likewise. * sysdeps/unix/sysv/linux/x86_64/vfork.S (__vfork): Likewise.
94 lines
2.5 KiB
ArmAsm
94 lines
2.5 KiB
ArmAsm
/* Copyright (C) 1999, 2002, 2003 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Andreas Schwab <schwab@gnu.org>.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
#include <sysdep-cancel.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <kernel-features.h>
|
|
|
|
/* Clone the calling process, but without copying the whole address space.
|
|
The calling process is suspended until the new process exits or is
|
|
replaced by a call to `execve'. Return -1 for errors, 0 to the new process,
|
|
and the process ID of the new process to the old process. */
|
|
|
|
ENTRY (__vfork)
|
|
|
|
#ifdef __NR_vfork
|
|
|
|
# ifdef SHARED
|
|
# if !defined HAVE_HIDDEN || !USE___THREAD
|
|
SETUP_PIC_REG (cx)
|
|
# else
|
|
call __i686.get_pc_thunk.cx
|
|
# endif
|
|
addl $_GLOBAL_OFFSET_TABLE_, %ecx
|
|
cmpl $0, __libc_pthread_functions@GOTOFF(%ecx)
|
|
# else
|
|
.weak __pthread_fork
|
|
movl $__pthread_fork, %eax
|
|
testl %eax, %eax
|
|
# endif
|
|
jne HIDDEN_JUMPTARGET (__fork)
|
|
|
|
/* Pop the return PC value into ECX. */
|
|
popl %ecx
|
|
|
|
/* Stuff the syscall number in EAX and enter into the kernel. */
|
|
movl $SYS_ify (vfork), %eax
|
|
int $0x80
|
|
|
|
/* Jump to the return PC. Don't jump directly since this
|
|
disturbs the branch target cache. Instead push the return
|
|
address back on the stack. */
|
|
pushl %ecx
|
|
|
|
cmpl $-4095, %eax
|
|
/* Branch forward if it failed. */
|
|
# ifdef __ASSUME_VFORK_SYSCALL
|
|
jae SYSCALL_ERROR_LABEL
|
|
.Lpseudo_end:
|
|
# else
|
|
jae .Lerror
|
|
# endif
|
|
|
|
ret
|
|
|
|
# ifndef __ASSUME_VFORK_SYSCALL
|
|
.Lerror:
|
|
/* Check if vfork syscall is known at all. */
|
|
cmpl $-ENOSYS, %eax
|
|
jne SYSCALL_ERROR_LABEL
|
|
# endif
|
|
#endif
|
|
|
|
#ifndef __ASSUME_VFORK_SYSCALL
|
|
/* If we don't have vfork, fork is close enough. */
|
|
|
|
movl $SYS_ify (fork), %eax
|
|
int $0x80
|
|
cmpl $-4095, %eax
|
|
jae SYSCALL_ERROR_LABEL
|
|
.Lpseudo_end:
|
|
ret
|
|
#endif
|
|
PSEUDO_END (__vfork)
|
|
libc_hidden_def (__vfork)
|
|
|
|
weak_alias (__vfork, vfork)
|