# Process this file with autoconf to produce a configure script.
AC_INIT(glib.h)

dnl Initialize automake stuff
AM_INIT_AUTOMAKE(glib, 971201)

# Specify a configuration file
AM_CONFIG_HEADER(glibconfig.h)

dnl Initialize libtool
AM_PROG_LIBTOOL

dnl Initialize maintainer mode
AM_MAINTAINER_MODE

AC_CANONICAL_HOST

AC_ARG_ENABLE(debug, [  --enable-debug          turn on debugging [default=no]],
if eval "test x$enable_debug = xyes"; then
  DEBUGFLAG="-g"
fi)

AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
		    , enable_ansi=no)

if test -n "$DEBUGFLAG"; then
  test "${CFLAGS+set}" = set || CFLAGS="$DEBUGFLAG"
fi

# Checks for programs.
AC_PROG_CC
AM_PROG_CC_STDC
AC_PROG_INSTALL

if eval "test x$GCC = xyes"; then
  if test -z `echo "$CFLAGS" | grep "\-Wall" 2> /dev/null` ; then
    CFLAGS="$CFLAGS -Wall"
  fi

  if eval "test x$enable_ansi = xyes"; then
    if test -z `echo "$CFLAGS" | grep "\-ansi" 2> /dev/null` ; then
      CFLAGS="$CFLAGS -ansi"
    fi

    if test -z `echo "$CFLAGS" | grep "\-pedantic" 2> /dev/null` ; then
      CFLAGS="$CFLAGS -pedantic"
    fi
  fi
fi

# Checks for header files.
AC_HEADER_STDC

# Checks for library functions.
AC_FUNC_VPRINTF

AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(void *)

# long doubles were not used, and a portability problem 
# AC_C_LONG_DOUBLE
AC_C_CONST
AC_C_INLINE

AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))

# Check for strerror, strsignal, and memmove functions
AC_CHECK_FUNCS(strerror strsignal memmove)

# Check for sys_errlist
AC_MSG_CHECKING(sys_errlist)
AC_TRY_LINK(, [
extern char *sys_errlist[];
extern int sys_nerr;
sys_errlist[sys_nerr-1][0] = 0;
], glib_ok=yes, glib_ok=no)
AC_MSG_RESULT($glib_ok)
if test $glib_ok = no; then
    AC_DEFINE(NO_SYS_ERRLIST)
fi

# Check for sys_siglist
AC_MSG_CHECKING(sys_siglist)
AC_TRY_LINK(, [
extern char *sys_siglist[];
sys_siglist[1][0] = 0;
], glib_ok=yes, glib_ok=no)
AC_MSG_RESULT($glib_ok)
if test $glib_ok = no; then
    AC_DEFINE(NO_SYS_SIGLIST)
fi

# Check for sys/select.h

AC_MSG_CHECKING([fd_set and sys/select])
AC_TRY_COMPILE([#include <sys/types.h>],
        [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
if test $gtk_ok = no; then
    AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
    if test $gtk_ok = yes; then
        AC_DEFINE(HAVE_SYS_SELECT_H)
    fi
fi
AC_MSG_RESULT($gtk_ok)
if test $gtk_ok = no; then
    AC_DEFINE(NO_FD_SET)
fi

# This stuff is here, only so that we can define these
# things in glibconfig.h. If ../config.h was installed
# (under some other name?) then the definitions would
# belong there. (They are only used in GDK)

# Look for wide string functions in wchar.h or wcstr.h

AC_MSG_CHECKING(for <wchar.h> or <wcstr.h>)
AC_TRY_CPP([#include <wchar.h>], gtk_ok=yes, gtk_ok=no)
if test $gtk_ok = yes; then
   AC_DEFINE(HAVE_WCHAR_H)
else
   AC_TRY_CPP([#include <wcstr.h>], gtk_ok=yes, gtk_ok=no)
   if test $gtk_ok = yes; then
       AC_DEFINE(HAVE_WCSTR_H)
   fi
fi

# Check for wctype.h (for iswalnum)
AC_MSG_CHECKING(for <wctype.h>)
AC_TRY_CPP([#include <wctype.h>], gtk_ok=yes, gtk_ok=no)
if test $gtk_ok = yes; then
   AC_DEFINE(HAVE_WCTYPE_H)
fi
AC_MSG_RESULT($gtk_ok)

AC_OUTPUT(Makefile)