mirror of
https://gitlab.gnome.org/GNOME/gtk.git
synced 2024-09-20 05:50:11 +00:00
96b9ac84f8
Determine the location to save testcases in dynamically, trying first a GTK_SOURCE_DIR environment variable and then the current directory as the GTK source dir, ultimatively falling back to just saving in the current directory. This avoids leaking details of the build environment into the produced artifacts and should make GTK builds more reproducible. Fixes: #5403
41 lines
989 B
Meson
41 lines
989 B
Meson
node_editor_sources = [
|
|
'gtkrendererpaintable.c',
|
|
'main.c',
|
|
'node-editor-application.c',
|
|
'node-editor-window.c',
|
|
]
|
|
|
|
node_editor_resources = gnome.compile_resources('node_editor_resources',
|
|
'node-editor.gresource.xml',
|
|
source_dir: '.',
|
|
)
|
|
|
|
executable('gtk4-node-editor',
|
|
sources: [node_editor_sources, node_editor_resources],
|
|
dependencies: [ libgtk_dep, demo_conf_h ],
|
|
include_directories: confinc,
|
|
c_args: common_cflags,
|
|
win_subsystem: 'windows',
|
|
link_args: extra_demo_ldflags,
|
|
install: true,
|
|
)
|
|
|
|
# icons
|
|
icontheme_dir = join_paths(gtk_datadir, 'icons/hicolor')
|
|
|
|
foreach size: ['scalable', 'symbolic']
|
|
install_subdir('data/' + size, install_dir: icontheme_dir)
|
|
endforeach
|
|
|
|
# desktop file
|
|
install_data('org.gtk.gtk4.NodeEditor.desktop', install_dir: gtk_applicationsdir)
|
|
|
|
# appdata
|
|
configure_file(
|
|
input: 'org.gtk.gtk4.NodeEditor.appdata.xml.in',
|
|
output: 'org.gtk.gtk4.NodeEditor.appdata.xml',
|
|
configuration: appdata_config,
|
|
install_dir: gtk_appdatadir
|
|
)
|
|
|