mirror of
https://gitlab.gnome.org/GNOME/gtk.git
synced 2024-11-18 17:30:10 +00:00
4a4d6d9491
2001-04-11 Alexander Larsson <alexl@redhat.com> * gtk-2.0.m4: Pass pkg-config options before the other args so it works even if POSIXLY_CORRECT is set.
186 lines
7.4 KiB
Plaintext
186 lines
7.4 KiB
Plaintext
# Configure paths for GLIB
|
|
# Owen Taylor 1997-2001
|
|
|
|
dnl AM_PATH_GLIB_2_0([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, MODULES]]]])
|
|
dnl Test for GLIB, and define GLIB_CFLAGS and GLIB_LIBS, if "gmodule" or
|
|
dnl gthread is specified in MODULES, pass to glib-config
|
|
dnl
|
|
AC_DEFUN(AM_PATH_GLIB_2_0,
|
|
[dnl
|
|
dnl Get the cflags and libraries from the glib-config-2.0 script
|
|
dnl
|
|
AC_ARG_ENABLE(glibtest, [ --disable-glibtest Do not try to compile and run a test GLIB program],
|
|
, enable_glibtest=yes)
|
|
|
|
pkg_config_args=gtk+-2.0
|
|
for module in . $4
|
|
do
|
|
case "$module" in
|
|
gthread)
|
|
pkg_config_args="$pkg_config_args gthread-2.0"
|
|
;;
|
|
esac
|
|
done
|
|
|
|
min_glib_version=ifelse([$1], ,1.3.3,$1)
|
|
AC_MSG_CHECKING(for GLIB - version >= $min_glib_version)
|
|
|
|
no_glib=""
|
|
|
|
AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
|
|
|
|
if test x$PKG_CONFIG != xno ; then
|
|
if pkg-config --atleast-pkgconfig-version 0.5 ; then
|
|
:
|
|
else
|
|
echo *** pkg-config too old; version 0.5 or better required.
|
|
no_glib=yes
|
|
PKG_CONFIG=no
|
|
fi
|
|
fi
|
|
|
|
if test x"$no_glib" = x ; then
|
|
GLIB_CFLAGS=`$PKG_CONFIG --cflags $pkg_config_args`
|
|
GLIB_LIBS=`$PKG_CONFIG --libs $pkg_config_args`
|
|
glib_config_major_version=`$PKG_CONFIG --modversion glib-2.0 | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
|
|
glib_config_minor_version=`$PKG_CONFIG --modversion glib-2.0 | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
|
|
glib_config_micro_version=`$PKG_CONFIG --modversion glib-2.0 | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
|
|
if test "x$enable_glibtest" = "xyes" ; then
|
|
ac_save_CFLAGS="$CFLAGS"
|
|
ac_save_LIBS="$LIBS"
|
|
CFLAGS="$CFLAGS $GLIB_CFLAGS"
|
|
LIBS="$GLIB_LIBS $LIBS"
|
|
dnl
|
|
dnl Now check if the installed GLIB is sufficiently new. (Also sanity
|
|
dnl checks the results of glib-config-2.0 to some extent
|
|
dnl
|
|
rm -f conf.glibtest
|
|
AC_TRY_RUN([
|
|
#include <glib.h>
|
|
#include <stdio.h>
|
|
#include <stdlib.h>
|
|
|
|
int
|
|
main ()
|
|
{
|
|
int major, minor, micro;
|
|
char *tmp_version;
|
|
|
|
system ("touch conf.glibtest");
|
|
|
|
/* HP/UX 9 (%@#!) writes to sscanf strings */
|
|
tmp_version = g_strdup("$min_glib_version");
|
|
if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, µ) != 3) {
|
|
printf("%s, bad version string\n", "$min_glib_version");
|
|
exit(1);
|
|
}
|
|
|
|
if ((glib_major_version != $glib_config_major_version) ||
|
|
(glib_minor_version != $glib_config_minor_version) ||
|
|
(glib_micro_version != $glib_config_micro_version))
|
|
{
|
|
printf("\n*** 'pkg-config --modversion glib-2.0' returned %d.%d.%d, but GLIB (%d.%d.%d)\n",
|
|
$glib_config_major_version, $glib_config_minor_version, $glib_config_micro_version,
|
|
glib_major_version, glib_minor_version, glib_micro_version);
|
|
printf ("*** was found! If pkg-config was correct, then it is best\n");
|
|
printf ("*** to remove the old version of GLib. You may also be able to fix the error\n");
|
|
printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
|
|
printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
|
|
printf("*** required on your system.\n");
|
|
printf("*** If pkg-config was wrong, set the environment variable PKG_CONFIG_PATH\n");
|
|
printf("*** to point to the correct configuration files\n");
|
|
}
|
|
else if ((glib_major_version != GLIB_MAJOR_VERSION) ||
|
|
(glib_minor_version != GLIB_MINOR_VERSION) ||
|
|
(glib_micro_version != GLIB_MICRO_VERSION))
|
|
{
|
|
printf("*** GLIB header files (version %d.%d.%d) do not match\n",
|
|
GLIB_MAJOR_VERSION, GLIB_MINOR_VERSION, GLIB_MICRO_VERSION);
|
|
printf("*** library (version %d.%d.%d)\n",
|
|
glib_major_version, glib_minor_version, glib_micro_version);
|
|
}
|
|
else
|
|
{
|
|
if ((glib_major_version > major) ||
|
|
((glib_major_version == major) && (glib_minor_version > minor)) ||
|
|
((glib_major_version == major) && (glib_minor_version == minor) && (glib_micro_version >= micro)))
|
|
{
|
|
return 0;
|
|
}
|
|
else
|
|
{
|
|
printf("\n*** An old version of GLIB (%d.%d.%d) was found.\n",
|
|
glib_major_version, glib_minor_version, glib_micro_version);
|
|
printf("*** You need a version of GLIB newer than %d.%d.%d. The latest version of\n",
|
|
major, minor, micro);
|
|
printf("*** GLIB is always available from ftp://ftp.gtk.org.\n");
|
|
printf("***\n");
|
|
printf("*** If you have already installed a sufficiently new version, this error\n");
|
|
printf("*** probably means that the wrong copy of the pkg-config shell script is\n");
|
|
printf("*** being found. The easiest way to fix this is to remove the old version\n");
|
|
printf("*** of GLIB, but you can also set the PKG_CONFIG environment to point to the\n");
|
|
printf("*** correct copy of pkg-config. (In this case, you will have to\n");
|
|
printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
|
|
printf("*** so that the correct libraries are found at run-time))\n");
|
|
}
|
|
}
|
|
return 1;
|
|
}
|
|
],, no_glib=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
|
|
CFLAGS="$ac_save_CFLAGS"
|
|
LIBS="$ac_save_LIBS"
|
|
fi
|
|
fi
|
|
if test "x$no_glib" = x ; then
|
|
AC_MSG_RESULT(yes (version $glib_config_major_version.$glib_config_minor_version.$glib_config_micro_version))
|
|
ifelse([$2], , :, [$2])
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
if test "$PKG_CONFIG" = "no" ; then
|
|
echo "*** A new enough version of pkg-config was not found."
|
|
echo "*** See http://pkgconfig.sourceforge.net"
|
|
else
|
|
if test -f conf.glibtest ; then
|
|
:
|
|
else
|
|
echo "*** Could not run GLIB test program, checking why..."
|
|
CFLAGS="$CFLAGS $GLIB_CFLAGS"
|
|
LIBS="$LIBS $GLIB_LIBS"
|
|
AC_TRY_LINK([
|
|
#include <glib.h>
|
|
#include <stdio.h>
|
|
], [ return ((glib_major_version) || (glib_minor_version) || (glib_micro_version)); ],
|
|
[ echo "*** The test program compiled, but did not run. This usually means"
|
|
echo "*** that the run-time linker is not finding GLIB or finding the wrong"
|
|
echo "*** version of GLIB. If it is not finding GLIB, you'll need to set your"
|
|
echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
|
|
echo "*** to the installed location Also, make sure you have run ldconfig if that"
|
|
echo "*** is required on your system"
|
|
echo "***"
|
|
echo "*** If you have an old version installed, it is best to remove it, although"
|
|
echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"
|
|
echo "***"
|
|
echo "*** If you have a RedHat 5.0 system, you should remove the GTK package that"
|
|
echo "*** came with the system with the command"
|
|
echo "***"
|
|
echo "*** rpm --erase --nodeps gtk gtk-devel" ],
|
|
[ echo "*** The test program failed to compile or link. See the file config.log for the"
|
|
echo "*** exact error that occured. This usually means GLIB was incorrectly installed"
|
|
echo "*** or that you have moved GLIB since it was installed. In the latter case, you"
|
|
echo "*** may want to edit the pkg-config script: $PKG_CONFIG" ])
|
|
CFLAGS="$ac_save_CFLAGS"
|
|
LIBS="$ac_save_LIBS"
|
|
fi
|
|
fi
|
|
GLIB_CFLAGS=""
|
|
GLIB_LIBS=""
|
|
ifelse([$3], , :, [$3])
|
|
fi
|
|
AC_SUBST(GLIB_CFLAGS)
|
|
AC_SUBST(GLIB_LIBS)
|
|
rm -f conf.glibtest
|
|
])
|