mirror of
https://gitlab.gnome.org/GNOME/gtk.git
synced 2024-11-06 00:30:08 +00:00
72d5843898
Tue Feb 9 19:11:43 1999 Owen Taylor <otaylor@redhat.com> * gtk/gtkstyle.c (gtk_style_new): If we can't find helvetica, fall back to "fixed". If we can't find "fixed", exit cleanly.
504 lines
13 KiB
Plaintext
504 lines
13 KiB
Plaintext
# Process this file with autoconf to produce a configure script.
|
|
AC_INIT(gdk/gdktypes.h)
|
|
|
|
# In the following, there are a the following variants
|
|
# of GLib cflags and libs variables
|
|
#
|
|
# GLIB_CFLAGS: cflags for compiling libraries and example progs
|
|
# GLIB_LIBS: libraries for linking example programs
|
|
# GLIB_DEPLIBS: libraries for linking libraries against
|
|
# glib_cflags: cflags to store in gtk-config
|
|
# glib_libs: libs to store in gtk-config
|
|
# glib_thread_cflags: cflags to store in gtk-config for gtk-config gthread
|
|
# glib_thread_libs: libs to store in gtk-config for gtk-config gthread
|
|
|
|
# Save this value here, since automake will set cflags later
|
|
cflags_set=${CFLAGS+set}
|
|
|
|
# Making releases:
|
|
# GTK_MICRO_VERSION += 1;
|
|
# GTK_INTERFACE_AGE += 1;
|
|
# GTK_BINARY_AGE += 1;
|
|
# if any functions have been added, set GTK_INTERFACE_AGE to 0.
|
|
# if backwards compatibility has been broken,
|
|
# set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
|
|
#
|
|
GTK_MAJOR_VERSION=1
|
|
GTK_MINOR_VERSION=1
|
|
GTK_MICRO_VERSION=15
|
|
GTK_INTERFACE_AGE=1
|
|
GTK_BINARY_AGE=1
|
|
GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
|
|
AC_SUBST(GTK_MAJOR_VERSION)
|
|
AC_SUBST(GTK_MINOR_VERSION)
|
|
AC_SUBST(GTK_MICRO_VERSION)
|
|
AC_SUBST(GTK_INTERFACE_AGE)
|
|
AC_SUBST(GTK_BINARY_AGE)
|
|
AC_SUBST(GTK_VERSION)
|
|
|
|
# libtool versioning
|
|
LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
|
|
LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
|
|
LT_REVISION=$GTK_INTERFACE_AGE
|
|
LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
|
|
AC_SUBST(LT_RELEASE)
|
|
AC_SUBST(LT_CURRENT)
|
|
AC_SUBST(LT_REVISION)
|
|
AC_SUBST(LT_AGE)
|
|
|
|
# For automake.
|
|
VERSION=$GTK_VERSION
|
|
PACKAGE=gtk+
|
|
|
|
# Save this value here, since automake will set cflags later
|
|
cflags_set=${CFLAGS+set}
|
|
|
|
dnl Initialize automake stuff
|
|
AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
|
|
|
|
# Specify a configuration file
|
|
AM_CONFIG_HEADER(config.h)
|
|
|
|
dnl Initialize libtool
|
|
AM_PROG_LIBTOOL
|
|
|
|
dnl Initialize maintainer mode
|
|
AM_MAINTAINER_MODE
|
|
|
|
AC_CANONICAL_HOST
|
|
|
|
AC_ARG_ENABLE(shm, [ --enable-shm support shared memory if available [default=yes]],
|
|
echo $enable_shm, enable_shm="yes")
|
|
AC_ARG_ENABLE(debug, [ --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
|
|
AC_ARG_ENABLE(ansi, [ --enable-ansi turn on strict ansi [default=no]],
|
|
, enable_ansi=no)
|
|
AC_ARG_WITH(glib, [ --with-glib=DIR Use uninstalled copy of glib])
|
|
AC_ARG_ENABLE(xim, [ --enable-xim support XIM [default=yes]],
|
|
, enable_xim="yes")
|
|
AC_ARG_ENABLE(xim_inst, [ --disable-xim-inst does not use xim instantiate callback],
|
|
, enable_xim_inst="maybe")
|
|
AC_ARG_WITH(locale, [ --with-locale=LOCALE locale name you want to use ])
|
|
|
|
AC_ARG_WITH(xinput, [ --with-xinput=[no/gxi/xfree] support XInput ])
|
|
|
|
if test "x$enable_debug" = "xyes"; then
|
|
test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
|
|
GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
|
|
else
|
|
if test "x$enable_debug" = "xno"; then
|
|
GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
|
|
else
|
|
GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
|
|
fi
|
|
fi
|
|
|
|
AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
|
|
|
|
# Build time sanity check...
|
|
AM_SANITY_CHECK
|
|
|
|
# Checks for programs.
|
|
AC_PROG_CC
|
|
AC_ISC_POSIX
|
|
AM_PROG_CC_STDC
|
|
AC_PROG_INSTALL
|
|
AC_PROG_MAKE_SET
|
|
|
|
changequote(,)dnl
|
|
if test "x$GCC" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wall[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wall" ;;
|
|
esac
|
|
|
|
if test "x$enable_ansi" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-ansi[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -ansi" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-pedantic[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -pedantic" ;;
|
|
esac
|
|
fi
|
|
fi
|
|
changequote([,])dnl
|
|
|
|
# define a MAINT-like variable REBUILD which is set if Perl
|
|
# and awk are found, so autogenerated sources can be rebuilt
|
|
|
|
AC_PROG_AWK
|
|
AC_CHECK_PROGS(PERL, perl5 perl)
|
|
|
|
# We would like indent, but don't require it.
|
|
AC_CHECK_PROG(INDENT, indent, indent)
|
|
|
|
REBUILD=\#
|
|
if test -n "$PERL" && perl -v | grep 'version 5.' > /dev/null ; then
|
|
if test -n "$AWK" ; then
|
|
REBUILD=
|
|
fi
|
|
fi
|
|
AC_SUBST(REBUILD)
|
|
|
|
# i18n stuff
|
|
ALL_LINGUAS="cs de es fr it ja ko nl no pl pt ru sv"
|
|
AM_GTK_GNU_GETTEXT
|
|
AC_CHECK_FUNC(gettext,
|
|
,
|
|
AC_CHECK_LIB(intl, gettext)
|
|
)
|
|
# AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
|
|
# this is the directory where the *.{mo,gmo} files are installed
|
|
gtklocaledir='${prefix}/${DATADIRNAME}/locale'
|
|
AC_SUBST(gtklocaledir)
|
|
|
|
dnl The DU4 header files don't provide library prototypes unless
|
|
dnl -std1 is given to the native cc.
|
|
AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
|
|
|
|
gtk_save_LIBS=$LIBS
|
|
LIBS="$LIBS -lm"
|
|
AC_TRY_RUN([#include <math.h>
|
|
int main (void) { return (log(1) != log(1.)); }],
|
|
AC_MSG_RESULT(none needed),
|
|
gtk_save_CFLAGS=$CFLAGS
|
|
CFLAGS="$CFLAGS -std1"
|
|
AC_TRY_RUN([#include <math.h>
|
|
int main (void) { return (log(1) != log(1.)); }],
|
|
AC_MSG_RESULT(-std1),
|
|
AC_MSG_RESULT()
|
|
CFLAGS=$gtk_save_CFLAGS
|
|
AC_MSG_WARN(
|
|
[No ANSI prototypes found in library. (-std1 didn't work.)])
|
|
)
|
|
)
|
|
LIBS=$gtk_save_LIBS
|
|
|
|
dnl NeXTStep cc seems to need this
|
|
AC_MSG_CHECKING([for extra flags for POSIX compliance])
|
|
AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
|
|
AC_MSG_RESULT(none needed),
|
|
gtk_save_CFLAGS=$CFLAGS
|
|
CFLAGS="$CFLAGS -posix"
|
|
AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
|
|
AC_MSG_RESULT(-posix),
|
|
AC_MSG_RESULT()
|
|
CFLAGS=$gtk_save_CFLAGS
|
|
AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
|
|
|
|
if test x$with_glib = xyes ; then
|
|
AC_MSG_ERROR([
|
|
*** Directory must be specified for --with-glib])
|
|
fi
|
|
|
|
if test x$with_glib = x ; then
|
|
# Look for separately installed glib
|
|
|
|
AM_PATH_GLIB(1.1.15,,
|
|
AC_MSG_ERROR([
|
|
*** GLIB 1.1.15 or better is required. The latest version of GLIB
|
|
*** is always available from ftp://ftp.gtk.org.]),
|
|
gmodule gthread)
|
|
|
|
# we do not want to make all gtk progs to link to thread libraries.
|
|
glib_cflags=`$GLIB_CONFIG glib gmodule --cflags`
|
|
glib_thread_cflags="$GLIB_CFLAGS"
|
|
glib_libs=`$GLIB_CONFIG glib gmodule --libs`
|
|
glib_thread_libs="$GLIB_LIBS"
|
|
GLIB_LIBS="$glib_libs"
|
|
GLIB_DEPLIBS="$glib_libs"
|
|
else
|
|
# Use uninstalled glib (assume they got the version right)
|
|
|
|
GLIB_CONFIG=$with_glib/glib-config
|
|
if test -x $GLIB_CONFIG ; then
|
|
:
|
|
else
|
|
AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
|
|
fi
|
|
|
|
# For use in gtk-config
|
|
glib_cflags=`$GLIB_CONFIG --cflags gmodule`
|
|
glib_thread_cflags=`$GLIB_CONFIG --cflags gmodule gthread`
|
|
glib_libs=`$GLIB_CONFIG --libs gmodule`
|
|
glib_thread_libs=`$GLIB_CONFIG --libs gmodule gthread`
|
|
|
|
glib_release=`$GLIB_CONFIG --version | sed 's%\\.[[0-9]]*$%%'`
|
|
|
|
# canonicalize relative paths
|
|
case $with_glib in
|
|
/*)
|
|
glib_dir=$with_glib
|
|
;;
|
|
*)
|
|
glib_dir="\$(top_builddir)/$with_glib"
|
|
;;
|
|
esac
|
|
|
|
GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
|
|
GLIB_LIBS="$glib_dir/libglib.la $glib_dir/gmodule.la"
|
|
GLIB_DEPLIBS=
|
|
|
|
AC_SUBST(GLIB_CFLAGS)
|
|
AC_SUBST(GLIB_LIBS)
|
|
fi
|
|
|
|
AC_SUBST(glib_cflags)
|
|
AC_SUBST(glib_libs)
|
|
AC_SUBST(glib_thread_cflags)
|
|
AC_SUBST(glib_thread_libs)
|
|
AC_SUBST(GLIB_DEPLIBS)
|
|
|
|
# Find the X11 include and library directories
|
|
AC_PATH_X
|
|
AC_PATH_XTRA
|
|
|
|
if test "x$x_includes" = "x"; then
|
|
x_includes="/usr/include"
|
|
fi
|
|
|
|
saved_cflags="$CFLAGS"
|
|
saved_ldflags="$LDFLAGS"
|
|
|
|
CFLAGS="$CFLAGS $X_CFLAGS"
|
|
LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
|
|
|
|
if test "x$no_x" = "xyes"; then
|
|
AC_MSG_ERROR([
|
|
*** X libraries or include files not found. Check 'config.log' for
|
|
*** more details.])
|
|
fi
|
|
|
|
# Checks for libraries.
|
|
# Check for the X11 library
|
|
AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
|
|
AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
|
|
$X_EXTRA_LIBS)
|
|
|
|
if test "x$enable_shm" = "xyes"; then
|
|
# Check for the Xext library (needed for XShm extention)
|
|
AC_CHECK_LIB(Xext, XShmAttach,
|
|
x_libs="-lXext $x_libs",
|
|
# On AIX, it is in XextSam instead, but we still need -lXext
|
|
AC_CHECK_LIB(XextSam, XShmAttach,
|
|
x_libs="-lXextSam -lXext $x_libs",
|
|
no_xext_lib=yes, $x_libs),
|
|
$x_libs)
|
|
fi
|
|
|
|
# Check for shaped window extension
|
|
|
|
AC_CHECK_LIB(Xext, XShapeCombineMask,
|
|
if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
|
|
x_libs="-lXext $x_libs"
|
|
fi
|
|
AC_DEFINE(HAVE_SHAPE_EXT),
|
|
,
|
|
$x_libs)
|
|
|
|
# Check for XConvertCase (X11R6 specific)
|
|
|
|
AC_CHECK_LIB(X11, XConvertCase,
|
|
AC_DEFINE(HAVE_XCONVERTCASE),
|
|
,
|
|
$x_libs)
|
|
|
|
# Check for XIM support.
|
|
|
|
AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
|
|
: ,
|
|
enable_xim_inst="no",
|
|
$x_libs)
|
|
|
|
# On Solaris, calling XRegisterIMInstantiateCallback seems to
|
|
# cause an immediate segfault, so we disable it, unless
|
|
# the user specifically forces it to be on.
|
|
|
|
if test x$enable_xim_inst = xmaybe ; then
|
|
case host in
|
|
*-*-solaris*)
|
|
enable_xim_inst="no"
|
|
;;
|
|
*)
|
|
enable_xim_inst="yes"
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
if test "x$enable_xim" = "xyes"; then
|
|
AC_DEFINE(USE_XIM)
|
|
GTK_XIM_FLAGS="-DUSE_XIM"
|
|
if test "x$enable_xim_inst" = "xyes"; then
|
|
AC_DEFINE(USE_X11R6_XIM)
|
|
fi
|
|
fi
|
|
|
|
x_cflags="$X_CFLAGS"
|
|
x_ldflags="$X_LDFLAGS $X_LIBS"
|
|
|
|
# set up things for XInput
|
|
|
|
if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
|
|
AC_DEFINE(XINPUT_GXI)
|
|
xinput_progs=gxid
|
|
x_libs="-lXi $x_libs"
|
|
elif test "x$with_xinput" = "xxfree"; then
|
|
AC_DEFINE(XINPUT_XFREE)
|
|
x_libs="-lXi $x_libs"
|
|
else
|
|
AC_DEFINE(XINPUT_NONE)
|
|
fi
|
|
|
|
CFLAGS="$saved_cflags"
|
|
LDFLAGS="$saved_ldflags"
|
|
|
|
AC_SUBST(x_cflags)
|
|
AC_SUBST(x_includes)
|
|
AC_SUBST(x_ldflags)
|
|
AC_SUBST(x_libs)
|
|
AC_SUBST(xinput_progs)
|
|
|
|
if test "x$enable_shm" = "xyes"; then
|
|
# Check for shared memory
|
|
AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
|
|
AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
|
|
|
|
# Check for the X shared memory extension header file
|
|
AC_MSG_CHECKING(X11/extensions/XShm.h)
|
|
if test "x$no_xext_lib" = "xyes"; then
|
|
AC_MSG_RESULT(no)
|
|
no_xshm=yes
|
|
else
|
|
if test -f "$x_includes/X11/extensions/XShm.h"; then
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XSHM_H)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
no_xshm=yes
|
|
fi
|
|
fi
|
|
fi
|
|
|
|
# Check if X_LOCALE definition is necessary
|
|
|
|
AC_MSG_CHECKING(need -DX_LOCALE)
|
|
|
|
AC_TRY_RUN([
|
|
#include <stdio.h>
|
|
#include <locale.h>
|
|
|
|
int
|
|
main ()
|
|
{
|
|
return setlocale (LC_ALL, "${with_locale}") == NULL;
|
|
}],
|
|
need_x_locale=no,
|
|
need_x_locale=yes)
|
|
AC_MSG_RESULT($need_x_locale)
|
|
|
|
if test $need_x_locale = yes; then
|
|
GTK_LOCALE_CFLAGS="-DX_LOCALE"
|
|
fi
|
|
|
|
# Checks for header files.
|
|
AC_HEADER_STDC
|
|
|
|
# Checks for typedefs, structures, and compiler characteristics.
|
|
AC_C_CONST
|
|
|
|
# Checks for library functions.
|
|
AC_TYPE_SIGNAL
|
|
AC_FUNC_MMAP
|
|
|
|
# Check if <sys/select.h> needs to be included for fd_set
|
|
AC_MSG_CHECKING([for fd_set])
|
|
AC_TRY_COMPILE([#include <sys/types.h>],
|
|
[fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
|
|
if test $gtk_ok = yes; then
|
|
AC_MSG_RESULT([yes, found in sys/types.h])
|
|
else
|
|
AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
|
|
if test $gtk_ok = yes; then
|
|
AC_DEFINE(HAVE_SYS_SELECT_H)
|
|
AC_MSG_RESULT([yes, found in sys/select.h])
|
|
else
|
|
AC_DEFINE(NO_FD_SET)
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
fi
|
|
|
|
# Duplicate `widechar' tests from `glib'.
|
|
# Check for wchar.h
|
|
if test x = y; then
|
|
# will not be executed
|
|
# hack so as not to update `acconfig.h'
|
|
AC_CHECK_HEADERS(wchar.h wctype.h)
|
|
AC_CHECK_FUNCS(broken_wctype)
|
|
fi
|
|
|
|
AC_MSG_CHECKING(for wchar.h)
|
|
AC_TRY_CPP([#include <wchar.h>], gtk_ok=yes, gtk_ok=no)
|
|
if test $gtk_ok = yes; then
|
|
ac_kludge=HAVE_WCHAR_H
|
|
AC_DEFINE($ac_kludge)
|
|
fi
|
|
AC_MSG_RESULT($gtk_ok)
|
|
|
|
# Check for wctype.h (for iswalnum)
|
|
|
|
AC_MSG_CHECKING(for wctype.h)
|
|
AC_TRY_CPP([#include <wctype.h>], gtk_ok=yes, gtk_ok=no)
|
|
if test $gtk_ok = yes; then
|
|
ac_kludge=HAVE_WCTYPE_H
|
|
AC_DEFINE($ac_kludge)
|
|
fi
|
|
AC_MSG_RESULT($gtk_ok)
|
|
|
|
# in Solaris 2.5, `iswalnum' is in -lw
|
|
GDK_WLIBS=
|
|
AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
|
|
|
|
# The following is necessary for Linux libc-5.4.38
|
|
oLIBS="$LIBS"
|
|
LIBS="$LIBS $GDK_WLIBS"
|
|
AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
|
|
AC_TRY_LINK([#include <stdlib.h>],[
|
|
#if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
|
|
# ifdef HAVE_WCTYPE_H
|
|
# include <wctype.h>
|
|
# else
|
|
# ifdef HAVE_WCHAR_H
|
|
# include <wchar.h>
|
|
# endif
|
|
# endif
|
|
#else
|
|
# define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
|
|
#endif
|
|
iswalnum((wchar_t) 0);
|
|
], gtk_ok=yes, gtk_ok=no)
|
|
LIBS="$oLIBS"
|
|
|
|
if test $gtk_ok = no; then
|
|
ac_kludge=HAVE_BROKEN_WCTYPE
|
|
AC_DEFINE($ac_kludge)
|
|
GDK_WLIBS=
|
|
fi
|
|
AC_MSG_RESULT($gtk_ok)
|
|
AC_SUBST(GDK_WLIBS)
|
|
|
|
AC_SUBST(GTK_DEBUG_FLAGS)
|
|
AC_SUBST(GTK_XIM_FLAGS)
|
|
AC_SUBST(GTK_LOCALE_FLAGS)
|
|
|
|
AC_OUTPUT([
|
|
Makefile
|
|
gtk-config
|
|
po/Makefile.in
|
|
docs/Makefile
|
|
gdk/Makefile
|
|
gtk/Makefile
|
|
gtk/gtkfeatures.h
|
|
], [chmod +x gtk-config])
|