gtk2/docs/reference/gtk/meson.build

private_headers = [
]

images = [
  'images/aboutdialog.png',
  'images/accel-label.png',
  'images/action-bar.png',
  'images/appchooserbutton.png',
  'images/appchooserdialog.png',
  'images/arrows.png',
  'images/assistant.png',
  'images/background.png',
  'images/bloatpad-gnome.png',
  'images/bloatpad-osx.png',
  'images/bloatpad-xfce.png',
  'images/border1.png',
  'images/border2.png',
  'images/border3.png',
  'images/box-expand.png',
  'images/box-packing.png',
  'images/builder-shortcuts.png',
  'images/button.png',
  'images/check-button.png',
  'images/checks.png',
  'images/clocks-shortcuts.png',
  'images/color-button.png',
  'images/colorchooser.png',
  'images/combo-box-entry.png',
  'images/combo-box.png',
  'images/combo-box-text.png',
  'images/down-center.png',
  'images/down-end.png',
  'images/down-start.png',
  'images/drawing.png',
  'images/ease-in-out.png',
  'images/ease-in.png',
  'images/ease-out.png',
  'images/ease.png',
  'images/entry.png',
  'images/exampleapp.png',
  'images/expanders.png',
  'images/extensions.png',
  'images/figure-hierarchical-drawing.png',
  'images/figure-windowed-label.png',
  'images/file-button.png',
  'images/filechooser.png',
  'images/flow-box.png',
  'images/focus.png',
  'images/font-button.png',
  'images/fontchooser.png',
  'images/frame-gap.png',
  'images/frame.png',
  'images/frames.png',
  'images/gedit-shortcuts.png',
  'images/getting-started-app10.png',
  'images/getting-started-app1.png',
  'images/getting-started-app2.png',
  'images/getting-started-app3.png',
  'images/getting-started-app4.png',
  'images/getting-started-app6.png',
  'images/getting-started-app7.png',
  'images/getting-started-app8.png',
  'images/getting-started-app9.png',
  'images/glarea.png',
  'images/gradient1.png',
  'images/gradient2.png',
  'images/gradient3.png',
  'images/gradient4.png',
  'images/grid-packing.png',
  'images/handles.png',
  'images/headerbar.png',
  'images/hello-world.png',
  'images/icon-view.png',
  'images/image.png',
  'images/info-bar.png',
  'images/inspector.png',
  'images/label.png',
  'images/layout-btlr.png',
  'images/layout-btrl.png',
  'images/layout-lrbt.png',
  'images/layout-lrtb.png',
  'images/layout-rlbt.png',
  'images/layout-rltb.png',
  'images/layout-tblr.png',
  'images/layout-tbrl.png',
  'images/left-center.png',
  'images/left-end.png',
  'images/left-start.png',
  'images/levelbar.png',
  'images/linear.png',
  'images/link-button.png',
  'images/list-and-tree.png',
  'images/list-box.png',
  'images/lockbutton-locked.png',
  'images/lock-button.png',
  'images/lockbutton.png',
  'images/lockbutton-sorry.png',
  'images/lockbutton-unlocked.png',
  'images/menubar.png',
  'images/menu-button.png',
  'images/messagedialog.png',
  'images/multiline-text.png',
  'images/notebook.png',
  'images/options.png',
  'images/pagesetupdialog.png',
  'images/panes.png',
  'images/placessidebar.png',
  'images/popup-anchors.png',
  'images/popup-at.svg',
  'images/popup-flip.png',
  'images/popup-slide.png',
  'images/printdialog.png',
  'images/progressbar.png',
  'images/radio-group.png',
  'images/right-center.png',
  'images/right-end.png',
  'images/right-start.png',
  'images/scales.png',
  'images/scrollbar.png',
  'images/scrolledwindow.png',
  'images/search-bar.png',
  'images/search-entry.png',
  'images/separator.png',
  'images/sidebar.png',
  'images/slices.png',
  'images/sliders.png',
  'images/spinbutton.png',
  'images/spinner.png',
  'images/stack.png',
  'images/stackswitcher.png',
  'images/statusbar.png',
  'images/switch.png',
  'images/toggle-button.png',
  'images/toolbar.png',
  'images/tree-view-coordinates.png',
  'images/up-center.png',
  'images/up-end.png',
  'images/up-start.png',
  'images/volumebutton.png',
  'images/widget-hvalign.png',
  'images/window-default.png',
  'images/window.png',
]

content_files = [
  'broadway.xml',
  'building.sgml',
  'compiling.sgml',
  'css-overview.xml',
  'css-properties.xml',
  'drawing-model.xml',
  'getting_started.xml',
  'glossary.xml',
  'gtk4-broadwayd.xml',
  'gtk4-builder-tool.xml',
  'gtk4-demo-application.xml',
  'gtk4-demo.xml',
  'gtk4-encode-symbolic-svg.xml',
  'gtk4-icon-browser.xml',
  'gtk4-launch.xml',
  'gtk4-query-settings.xml',
  'gtk4-update-icon-cache.xml',
  'gtk4-widget-factory.xml',
  'input-handling.xml',
  'migrating-2to4.xml',
  'migrating-3to4.xml',
  'mir.xml',
  'osx.sgml',
  'other_software.sgml',
  'overview.xml',
  'question_index.sgml',
  'resources.sgml',
  'running.sgml',
  'text_widget.sgml',
  'tree_widget.sgml',
  'visual_index.xml',
  'wayland.xml',
  'windows.sgml',
  'x11.sgml',
]

expand_content_files = [
  'compiling.sgml',
  'drawing-model.xml',
  'getting_started.xml',
  'glossary.xml',
  'input-handling.xml',
  'migrating-2to4.xml',
  'migrating-3to4.xml',
  'question_index.sgml',
  'text_widget.sgml',
  'tree_widget.sgml',
]

configure_file(input: 'version.xml.in', output: 'version.xml', configuration: version_conf)

types_conf = configuration_data()
if os_win32
  types_conf.set('DISABLE_ON_W32', '%')
else
  types_conf.set('DISABLE_ON_W32', '')
endif

if os_darwin
  types_conf.set('DISABLE_ON_QUARTZ', '%')
else
  types_conf.set('DISABLE_ON_QUARTZ', '')
endif

gnome.gtkdoc('gtk4',
             mode: 'none',
             main_xml: 'gtk4-docs.xml',
             src_dir: [
               gtkinc,
	     ],
             dependencies: libgtk_dep,
             gobject_typesfile: configure_file(
               input: 'gtk4.types.in',
               output: 'gtk4.types',
               configuration: types_conf,
             ),
             scan_args: [
               '--ignore-decorators=_GDK_EXTERN|G_GNUC_WARN_UNUSED_RESULT',
               '--ignore-headers=' + ' '.join(private_headers),
             ],
             fixxref_args: [
               '--html-dir=@0@'.format(docpath),
               '--extra-dir=@0@'.format(join_paths(glib_docpath, 'glib')),
               '--extra-dir=@0@'.format(join_paths(glib_docpath, 'gobject')),
               '--extra-dir=@0@'.format(join_paths(glib_docpath, 'gio')),
               '--extra-dir=@0@'.format(cairo_docpath),
               '--extra-dir=@0@'.format(gdkpixbuf_docpath),
	       '--extra-dir=../gdk',
	       '--extra-dir=../gsk',
             ],
             content_files: content_files,
             expand_content_files: expand_content_files,
             html_assets: images,
             install: true)

xsltproc = find_program('xsltproc', required: false)
if get_option('man-pages') and not xsltproc.found()
  error('No xsltproc found, but man pages were explicitly enabled')
endif

if get_option('man-pages') and xsltproc.found()
  xlstproc_flags = [
    '--nonet',
    '--stringparam', 'man.output.quietly', '1',
    '--stringparam', 'funcsynopsis.style', 'ansi',
    '--stringparam', 'man.th.extra1.suppress', '1',
    '--stringparam', 'man.authors.section.enabled', '0',
    '--stringparam', 'man.copyright.section.enabled', '0',
  ]

  man_files = [
    [ 'gtk4-broadwayd', '1', ],
    [ 'gtk4-builder-tool', '1', ],
    [ 'gtk4-demo', '1', ],
    [ 'gtk4-demo-application', '1', ],
    [ 'gtk4-encode-symbolic-svg', '1', ],
    [ 'gtk4-icon-browser', '1', ],
    [ 'gtk4-launch', '1', ],
    [ 'gtk4-query-settings', '1', ],
    [ 'gtk4-update-icon-cache', '1', ],
    [ 'gtk4-widget-factory', '1', ],
  ]

  foreach man: man_files
    man_name = man.get(0)
    man_section = man.get(1, '1')
    custom_target('@0@.@1@'.format(man_name, man_section),
                  input: '@0@.xml'.format(man_name),
                  output: '@0@.@1@'.format(man_name, man_section),
                  command: [
                    xsltproc,
                    xlstproc_flags,
                    '-o', '@OUTPUT@',
                    'http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl',
                    '@INPUT@',
                  ],
                  install: true,
                  install_dir: join_paths(get_option('mandir'), 'man@0@'.format(man_section)))
  endforeach
endif