forked from AuroraMiddleware/gtk
a92170b6ca
2000-12-21 Alexander Larsson <alexl@redhat.com> * configure.in: For linux-fb get the pangoft2 cflags and libs. This needs a recent pango version. Remove modules/linux-fb/Makefile. * gdk/linux-fb/gdkdrawable-fb2.c: Render glyphs using freetype. * gdk/linux-fb/gdkfb.h: Add new fb-specific functions needed for managing windows. * gdk/linux-fb/gdkmain-fb.c: Remove gdk_font_init/fini() calls. * gdk/linux-fb/gdkpango-fb.c: Remove old implementation. Use pangoft2 instead. * gdk/linux-fb/gdkprivate-fb.h: Remove PangoFBFont and related stuff. * gdk/linux-fb/gdkwindow-fb.c: Implement drawable->get_visible_region. Implement support for _gdk_window_set_child_handler () and _gdk_window_get_decorations(). * modules/Makefile.am: Remove linux-fb subdir. * modules/linux-fb/*: Removed all.
1127 lines
29 KiB
Plaintext
1127 lines
29 KiB
Plaintext
# Process this file with autoconf to produce a configure script.
|
|
AC_INIT(gdk/gdktypes.h)
|
|
|
|
# In the following, there are a the following variants
|
|
# of GLib cflags and libs variables
|
|
#
|
|
# GLIB_CFLAGS: cflags for compiling libraries and example progs
|
|
# GLIB_LIBS: libraries for linking example programs
|
|
# GLIB_DEPLIBS: libraries for linking libraries against
|
|
# glib_cflags: cflags to store in gtk-config
|
|
# glib_libs: libs to store in gtk-config
|
|
# glib_thread_cflags: cflags to store in gtk-config for gtk-config gthread
|
|
# glib_thread_libs: libs to store in gtk-config for gtk-config gthread
|
|
|
|
# Save this value here, since automake will set cflags later
|
|
cflags_set=${CFLAGS+set}
|
|
|
|
dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
|
|
dnl are available for $ac_help expansion (don't we all *love* autoconf?)
|
|
AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
|
|
#
|
|
# Making releases:
|
|
# GTK_MICRO_VERSION += 1;
|
|
# GTK_INTERFACE_AGE += 1;
|
|
# GTK_BINARY_AGE += 1;
|
|
# if any functions have been added, set GTK_INTERFACE_AGE to 0.
|
|
# if backwards compatibility has been broken,
|
|
# set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
|
|
#
|
|
GTK_MAJOR_VERSION=1
|
|
GTK_MINOR_VERSION=3
|
|
GTK_MICRO_VERSION=2
|
|
GTK_INTERFACE_AGE=0
|
|
GTK_BINARY_AGE=0
|
|
GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
|
|
dnl
|
|
AC_DIVERT_POP()dnl
|
|
|
|
AC_SUBST(GTK_MAJOR_VERSION)
|
|
AC_SUBST(GTK_MINOR_VERSION)
|
|
AC_SUBST(GTK_MICRO_VERSION)
|
|
AC_SUBST(GTK_INTERFACE_AGE)
|
|
AC_SUBST(GTK_BINARY_AGE)
|
|
AC_SUBST(GTK_VERSION)
|
|
|
|
# libtool versioning
|
|
LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
|
|
LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
|
|
LT_REVISION=$GTK_INTERFACE_AGE
|
|
LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
|
|
AC_SUBST(LT_RELEASE)
|
|
AC_SUBST(LT_CURRENT)
|
|
AC_SUBST(LT_REVISION)
|
|
AC_SUBST(LT_AGE)
|
|
|
|
#
|
|
# gdk-pixbuf gets versioned separately, and for now, using standard
|
|
# libtool versioning, not GTK+-style versioning
|
|
#
|
|
GDK_PIXBUF_MAJOR=0
|
|
GDK_PIXBUF_MINOR=8
|
|
GDK_PIXBUF_MICRO=0
|
|
GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
|
|
AC_SUBST(GDK_PIXBUF_MAJOR)
|
|
AC_SUBST(GDK_PIXBUF_MINOR)
|
|
AC_SUBST(GDK_PIXBUF_MICRO)
|
|
AC_SUBST(GDK_PIXBUF_VERSION)
|
|
|
|
# For automake.
|
|
VERSION=$GTK_VERSION
|
|
PACKAGE=gtk+
|
|
|
|
GETTEXT_PACKAGE=gtk20
|
|
AC_SUBST(GETTEXT_PACKAGE)
|
|
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
|
|
|
|
# Save this value here, since automake will set cflags later
|
|
cflags_set=${CFLAGS+set}
|
|
|
|
dnl Initialize automake stuff
|
|
AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
|
|
|
|
# Specify a configuration file
|
|
AM_CONFIG_HEADER(config.h)
|
|
|
|
dnl Initialize libtool
|
|
AM_PROG_LIBTOOL
|
|
|
|
dnl Initialize maintainer mode
|
|
AM_MAINTAINER_MODE
|
|
|
|
AC_CANONICAL_HOST
|
|
|
|
dnl figure debugging default, prior to $ac_help setup
|
|
dnl
|
|
AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
|
|
if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
|
|
debug_default=yes
|
|
else
|
|
debug_default=minimum
|
|
fi
|
|
AC_DIVERT_POP()dnl
|
|
|
|
dnl declare --enable-* args and collect ac_help strings
|
|
AC_ARG_ENABLE(debug, [ --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
|
|
AC_ARG_ENABLE(shm, [ --enable-shm support shared memory if available [default=yes]],
|
|
echo $enable_shm, enable_shm="yes")
|
|
AC_ARG_ENABLE(ansi, [ --enable-ansi turn on strict ansi [default=no]],
|
|
, enable_ansi=no)
|
|
AC_ARG_WITH(glib, [ --with-glib=DIR Use uninstalled copy of glib])
|
|
AC_ARG_ENABLE(xim, [ --enable-xim support XIM [default=yes]],
|
|
, enable_xim="yes")
|
|
AC_ARG_ENABLE(xim_inst, [ --disable-xim-inst does not use xim instantiate callback],
|
|
, enable_xim_inst="maybe")
|
|
AC_ARG_ENABLE(xkb, [ --enable-xkb support XKB [default=maybe]],
|
|
, enable_xkb="maybe")
|
|
AC_ARG_ENABLE(rebuilds, [ --disable-rebuilds disable all source autogeneration rules],,enable_rebuilds=yes)
|
|
AC_ARG_WITH(locale, [ --with-locale=LOCALE locale name you want to use ])
|
|
|
|
AC_ARG_WITH(xinput, [ --with-xinput=[no/gxi/xfree] support XInput ])
|
|
|
|
gdktarget=x11
|
|
gdktargetlib=libgdk-x11-1.3.la
|
|
gtktargetlib=libgtk-x11-1.3.la
|
|
AC_ARG_WITH(gdktarget, [ --with-gdktarget=[x11/nanox/linux-fb] select GDK target [default=x11] ],
|
|
gdktarget=$with_gdktarget)
|
|
|
|
AC_SUBST(gdktarget)
|
|
case $gdktarget in
|
|
x11|nanox|linux-fb) ;;
|
|
*) AC_MSG_ERROR([Invalid target for GDK: use x11, nanox or linux-fb.]);;
|
|
esac
|
|
|
|
if test "x$enable_debug" = "xyes"; then
|
|
test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
|
|
GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
|
|
else
|
|
if test "x$enable_debug" = "xno"; then
|
|
GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
|
|
else
|
|
GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
|
|
fi
|
|
fi
|
|
|
|
AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
|
|
|
|
# Build time sanity check...
|
|
AM_SANITY_CHECK
|
|
|
|
# Checks for programs.
|
|
AC_PROG_CC
|
|
AC_ISC_POSIX
|
|
AM_PROG_CC_STDC
|
|
AC_PROG_INSTALL
|
|
AC_PROG_MAKE_SET
|
|
|
|
changequote(,)dnl
|
|
if test "x$GCC" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wall[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wall" ;;
|
|
esac
|
|
|
|
if test "x$enable_ansi" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-ansi[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -ansi" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-pedantic[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -pedantic" ;;
|
|
esac
|
|
fi
|
|
fi
|
|
changequote([,])dnl
|
|
|
|
# Honor aclocal flags
|
|
ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
|
|
|
|
# define a MAINT-like variable REBUILD which is set if Perl
|
|
# and awk are found, so autogenerated sources can be rebuilt
|
|
|
|
AC_PROG_AWK
|
|
AC_CHECK_PROGS(PERL, perl5 perl)
|
|
|
|
# We would like indent, but don't require it.
|
|
AC_CHECK_PROG(INDENT, indent, indent)
|
|
|
|
REBUILD=\#
|
|
if test "x$enable_rebuilds" = "xyes" && \
|
|
test -n "$PERL" && \
|
|
$PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
|
|
test -n "$AWK" ; then
|
|
REBUILD=
|
|
fi
|
|
AC_SUBST(REBUILD)
|
|
|
|
AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
|
|
|
|
AC_MSG_CHECKING(whether make is GNU Make)
|
|
STRIP_BEGIN=
|
|
STRIP_END=
|
|
if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
|
|
STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
|
|
STRIP_END=')'
|
|
AC_MSG_RESULT(yes)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
STRIP_DUMMY=
|
|
AC_SUBST(STRIP_DUMMY)
|
|
AC_SUBST(STRIP_BEGIN)
|
|
AC_SUBST(STRIP_END)
|
|
|
|
# i18n stuff
|
|
ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl no pl pt pt_BR ro ru sk sl sp sr sv tr uk wa zh_TW zh_CN"
|
|
AM_GTK_GNU_GETTEXT
|
|
LIBS="$LIBS $INTLLIBS"
|
|
|
|
# AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
|
|
# this is the directory where the *.{mo,gmo} files are installed
|
|
gtklocaledir='${prefix}/${DATADIRNAME}/locale'
|
|
AC_SUBST(gtklocaledir)
|
|
|
|
dnl The DU4 header files don't provide library prototypes unless
|
|
dnl -std1 is given to the native cc.
|
|
AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
|
|
|
|
gtk_save_LIBS=$LIBS
|
|
LIBS="$LIBS -lm"
|
|
AC_TRY_RUN([#include <math.h>
|
|
int main (void) { return (log(1) != log(1.)); }],
|
|
AC_MSG_RESULT(none needed),
|
|
gtk_save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS -std1"
|
|
AC_TRY_RUN([#include <math.h>
|
|
int main (void) { return (log(1) != log(1.)); }],
|
|
AC_MSG_RESULT(-std1),
|
|
AC_MSG_RESULT()
|
|
CFLAGS="$gtk_save_CFLAGS"
|
|
AC_MSG_WARN(
|
|
[No ANSI prototypes found in library. (-std1 didn't work.)]),
|
|
true
|
|
),
|
|
AC_MSG_RESULT(none needed)
|
|
)
|
|
LIBS=$gtk_save_LIBS
|
|
|
|
MATH_LIB=-lm
|
|
GTK_LIBS_EXTRA=
|
|
AC_MSG_CHECKING(for the BeOS)
|
|
case $host in
|
|
*-*-beos*)
|
|
AC_MSG_RESULT(yes)
|
|
GTK_LIBS_EXTRA="-L\$(top_builddir_full)/gdk/.libs -lgdk"
|
|
MATH_LIB=
|
|
;;
|
|
*)
|
|
AC_MSG_RESULT(no)
|
|
;;
|
|
esac
|
|
AC_SUBST(MATH_LIB)
|
|
AC_SUBST(GTK_LIBS_EXTRA)
|
|
|
|
dnl NeXTStep cc seems to need this
|
|
AC_MSG_CHECKING([for extra flags for POSIX compliance])
|
|
AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
|
|
AC_MSG_RESULT(none needed),
|
|
gtk_save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS -posix"
|
|
AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
|
|
AC_MSG_RESULT(-posix),
|
|
AC_MSG_RESULT()
|
|
CFLAGS="$gtk_save_CFLAGS"
|
|
AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
|
|
|
|
if test x$with_glib = xyes ; then
|
|
AC_MSG_ERROR([
|
|
*** Directory must be specified for --with-glib])
|
|
fi
|
|
|
|
if test x$with_glib = x ; then
|
|
# Look for separately installed glib
|
|
|
|
AM_PATH_GLIB_2_0(1.3.1,,
|
|
AC_MSG_ERROR([
|
|
*** GLIB 1.3.1 or better is required. The latest version of GLIB
|
|
*** is always available from ftp://ftp.gtk.org/.]),
|
|
gobject gmodule gthread)
|
|
|
|
# we do not want to make all gtk progs to link to thread libraries.
|
|
glib_cflags=`$GLIB_CONFIG_2_0 glib gobject gmodule --cflags`
|
|
glib_thread_cflags="$GLIB_CFLAGS"
|
|
glib_libs=`$GLIB_CONFIG_2_0 glib gobject gmodule --libs`
|
|
glib_thread_libs="$GLIB_LIBS"
|
|
GLIB_LIBS="$glib_libs"
|
|
GLIB_DEPLIBS="$glib_libs"
|
|
else
|
|
# Use uninstalled glib (assume they got the version right)
|
|
|
|
GLIB_CONFIG_2_0=$with_glib/glib-config-2.0
|
|
if test -x $GLIB_CONFIG_2_0 ; then
|
|
:
|
|
else
|
|
AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
|
|
fi
|
|
|
|
# For use in gtk-config
|
|
glib_cflags=`$GLIB_CONFIG_2_0 --cflags gmodule`
|
|
glib_thread_cflags=`$GLIB_CONFIG_2_0 --cflags gmodule gthread`
|
|
glib_libs=`$GLIB_CONFIG_2_0 --libs gmodule`
|
|
glib_thread_libs=`$GLIB_CONFIG_2_0 --libs gmodule gthread`
|
|
|
|
glib_release=`$GLIB_CONFIG_2_0 --version | sed 's%\\.[[0-9]]*$%%'`
|
|
|
|
# canonicalize relative paths
|
|
case $with_glib in
|
|
/*)
|
|
glib_dir=$with_glib
|
|
;;
|
|
*)
|
|
glib_dir="\$(top_builddir)/$with_glib"
|
|
;;
|
|
esac
|
|
|
|
GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
|
|
GLIB_LIBS="$glib_dir/libglib-1.3.la $glib_dir/gmodule/libgmodule-1.3.la"
|
|
GLIB_DEPLIBS=
|
|
|
|
AC_SUBST(GLIB_CFLAGS)
|
|
AC_SUBST(GLIB_LIBS)
|
|
fi
|
|
|
|
AC_SUBST(glib_cflags)
|
|
AC_SUBST(glib_libs)
|
|
AC_SUBST(glib_thread_cflags)
|
|
AC_SUBST(glib_thread_libs)
|
|
AC_SUBST(GLIB_DEPLIBS)
|
|
|
|
AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
|
|
AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
|
|
AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
|
|
AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
|
|
|
|
saved_cflags="$CFLAGS"
|
|
saved_ldflags="$LDFLAGS"
|
|
|
|
if test "x$gdktarget" = "xx11"; then
|
|
# Find the X11 include and library directories
|
|
AC_PATH_X
|
|
AC_PATH_XTRA
|
|
|
|
if test "x$x_includes" = "x"; then
|
|
x_includes="/usr/include"
|
|
fi
|
|
|
|
CFLAGS="$CFLAGS $X_CFLAGS"
|
|
LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
|
|
|
|
if test "x$no_x" = "xyes"; then
|
|
AC_MSG_ERROR([
|
|
*** X libraries or include files not found. Check 'config.log' for
|
|
*** more details.])
|
|
fi
|
|
|
|
# Checks for libraries.
|
|
# Check for the X11 library
|
|
AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
|
|
AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
|
|
$X_EXTRA_LIBS)
|
|
|
|
if test "x$enable_shm" = "xyes"; then
|
|
# Check for the Xext library (needed for XShm extention)
|
|
AC_CHECK_LIB(Xext, XShmAttach,
|
|
x_libs="-lXext $x_libs",
|
|
# On AIX, it is in XextSam instead, but we still need -lXext
|
|
AC_CHECK_LIB(XextSam, XShmAttach,
|
|
x_libs="-lXextSam -lXext $x_libs",
|
|
no_xext_lib=yes, $x_libs),
|
|
$x_libs)
|
|
fi
|
|
|
|
# Check for shaped window extension
|
|
|
|
AC_CHECK_LIB(Xext, XShapeCombineMask,
|
|
if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
|
|
x_libs="-lXext $x_libs"
|
|
fi
|
|
AC_DEFINE(HAVE_SHAPE_EXT),
|
|
,
|
|
$x_libs)
|
|
|
|
# Check for XConvertCase (X11R6 specific)
|
|
|
|
AC_CHECK_LIB(X11, XConvertCase,
|
|
AC_DEFINE(HAVE_XCONVERTCASE),
|
|
,
|
|
$x_libs)
|
|
|
|
#
|
|
# Checks for FreeType
|
|
#
|
|
FREETYPE_LIBS=
|
|
FREETYPE_CFLAGS=
|
|
have_freetype=false
|
|
AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
|
|
if test "x$FREE_CONFIG" != "xno" ; then
|
|
FREETYPE_CFLAGS=`freetype-config --cflags`
|
|
FREETYPE_LIBS=`freetype-config --libs`
|
|
|
|
AC_CHECK_LIB(freetype, FT_New_Face, have_freetype=true
|
|
,:,$FREETYPE_LIBS)
|
|
fi
|
|
AC_SUBST(FREETYPE_CFLAGS)
|
|
|
|
#
|
|
# Checks for Xft/XRender
|
|
#
|
|
have_xft=false
|
|
XFT_LIBS=""
|
|
XFT_CFLAGS=""
|
|
if test $have_freetype = true ; then
|
|
AC_CHECK_LIB(Xrender, XRenderFindFormat,
|
|
AC_CHECK_LIB(Xft, XftFontOpen, have_xft=true, :, -lXrender -lXext $X_LIBS $FREETYPE_LIBS)
|
|
,:,-lXext $X_LIBS)
|
|
|
|
if $have_xft = 'true' ; then
|
|
X_LIBS="-lXft -lXrender -lXext $FREETYPE_LIBS $X_LIBS"
|
|
AC_DEFINE(HAVE_XFT)
|
|
fi
|
|
fi
|
|
|
|
AC_SUBST(XFT_LIBS)
|
|
AM_CONDITIONAL(HAVE_XFT, $have_xft)
|
|
|
|
# Check for XIM support.
|
|
|
|
AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
|
|
: ,
|
|
enable_xim_inst="no",
|
|
$x_libs)
|
|
|
|
# On Solaris, calling XRegisterIMInstantiateCallback seems to
|
|
# cause an immediate segfault, so we disable it, unless
|
|
# the user specifically forces it to be on.
|
|
|
|
if test x$enable_xim_inst = xmaybe ; then
|
|
case host in
|
|
*-*-solaris*)
|
|
enable_xim_inst="no"
|
|
;;
|
|
*)
|
|
enable_xim_inst="yes"
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
if test "x$enable_xim" = "xyes"; then
|
|
GTK_XIM_FLAGS="-DUSE_XIM"
|
|
if test "x$enable_xim_inst" = "xyes"; then
|
|
AC_DEFINE(USE_X11R6_XIM)
|
|
fi
|
|
fi
|
|
|
|
# Check for XKB support.
|
|
|
|
if test "x$enable_xkb" = "xyes"; then
|
|
AC_MSG_WARN(XKB support explicitly enabled)
|
|
AC_DEFINE(HAVE_XKB)
|
|
elif test "x$enable_xkb" = "xmaybe"; then
|
|
AC_CHECK_LIB(X11, XkbQueryExtension,
|
|
AC_DEFINE(HAVE_XKB),
|
|
,
|
|
$x_libs)
|
|
else
|
|
AC_MSG_WARN(XKB support explicitly disabled)
|
|
fi
|
|
|
|
x_cflags="$X_CFLAGS"
|
|
x_ldflags="$X_LDFLAGS $X_LIBS"
|
|
|
|
# set up things for XInput
|
|
|
|
if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
|
|
AC_DEFINE(XINPUT_GXI)
|
|
xinput_progs=gxid
|
|
x_libs="-lXi $x_libs"
|
|
elif test "x$with_xinput" = "xxfree"; then
|
|
AC_DEFINE(XINPUT_XFREE)
|
|
x_libs="-lXi $x_libs"
|
|
else
|
|
AC_DEFINE(XINPUT_NONE)
|
|
fi
|
|
|
|
AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
|
|
AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
|
|
|
|
if test "x$enable_shm" = "xyes"; then
|
|
# Check for shared memory
|
|
AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
|
|
AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
|
|
|
|
# Check for the X shared memory extension header file
|
|
AC_MSG_CHECKING(X11/extensions/XShm.h)
|
|
if test "x$no_xext_lib" = "xyes"; then
|
|
AC_MSG_RESULT(no)
|
|
no_xshm=yes
|
|
else
|
|
if test -f "$x_includes/X11/extensions/XShm.h"; then
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XSHM_H)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
no_xshm=yes
|
|
fi
|
|
fi
|
|
fi
|
|
|
|
more_cflags="$x_cflags"
|
|
more_ldflags="$x_ldflags"
|
|
more_libs="$x_libs"
|
|
more_includes="$x_includes"
|
|
|
|
# these are already defined above
|
|
#gdktargetlib = "libgdk-x11-1.3.la"
|
|
#gtktargetlib = "libgtk-x11-1.3.la"
|
|
|
|
AM_CONDITIONAL(USE_X11, true)
|
|
else
|
|
AM_CONDITIONAL(USE_X11, false)
|
|
fi
|
|
|
|
if test "x$gdktarget" = "xnanox"; then
|
|
AC_CHECK_LIB(nano-X, GrOpen,,AC_MSG_ERROR([nano-X libraries not found.]))
|
|
# nano-X may require additional libraries
|
|
more_cflags=
|
|
more_ldflags=
|
|
more_libs="-lnano-X"
|
|
more_includes=
|
|
|
|
gdktargetlib="libgdk-nanox-1.3.la"
|
|
gtktargetlib="libgtk-nanox-1.3.la"
|
|
|
|
with_xinput=no
|
|
AC_DEFINE(XINPUT_NONE)
|
|
x_cflags=
|
|
x_includes=
|
|
x_ldflags=
|
|
x_libs=
|
|
xinput_progs=
|
|
AM_CONDITIONAL(USE_NANOX, true)
|
|
else
|
|
AM_CONDITIONAL(USE_NANOX, false)
|
|
fi
|
|
|
|
if test "x$gdktarget" = "xlinux-fb"; then
|
|
more_cflags=
|
|
more_ldflags=
|
|
more_libs=
|
|
more_includes=
|
|
|
|
gdktargetlib="libgdk-linux-fb-1.3.la"
|
|
gtktargetlib="libgtk-linux-fb-1.3.la"
|
|
|
|
with_xinput=no
|
|
AC_DEFINE(XINPUT_NONE)
|
|
x_cflags=
|
|
x_includes=
|
|
x_ldflags=
|
|
x_libs=
|
|
xinput_progs=
|
|
|
|
AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
|
|
if test x$FREETYPE_CONFIG = xno ; then
|
|
AC_MSG_ERROR([*** freetype-config not found])
|
|
fi
|
|
|
|
FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
|
|
FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
|
|
CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
|
|
|
|
AM_CONDITIONAL(USE_LINUX_FB, true)
|
|
else
|
|
AM_CONDITIONAL(USE_LINUX_FB, false)
|
|
fi
|
|
AC_SUBST(FREETYPE_LIBS)
|
|
AC_SUBST(FREETYPE_CFLAGS)
|
|
|
|
#
|
|
# Check for Pango
|
|
#
|
|
AC_PATH_PROG(PANGO_CONFIG, pango-config, no)
|
|
if test x$PANGO_CONFIG = xno ; then
|
|
AC_MSG_ERROR([*** pango-config not found])
|
|
fi
|
|
|
|
if test "x$gdktarget" = "xx11"; then
|
|
PANGO_CFLAGS="`$PANGO_CONFIG --cflags pangox`"
|
|
PANGO_LIBS="`$PANGO_CONFIG --libs pangox`"
|
|
if $have_xft = true ; then
|
|
PANGO_LIBS="$PANGO_LIBS -lpangoxft"
|
|
fi
|
|
elif test "x$gdktarget" = "xlinux-fb"; then
|
|
PANGO_CFLAGS="`$PANGO_CONFIG --cflags pangoft2`"
|
|
PANGO_LIBS="`$PANGO_CONFIG --libs pangoft2`"
|
|
else
|
|
PANGO_CFLAGS="`$PANGO_CONFIG --cflags pango`"
|
|
PANGO_LIBS="`$PANGO_CONFIG --libs pango`"
|
|
fi
|
|
CFLAGS="$CFLAGS $PANGO_CFLAGS"
|
|
AC_SUBST(PANGO_LIBS)
|
|
AC_SUBST(PANGO_CFLAGS)
|
|
|
|
AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
|
|
*** Pango not found. Pango is required to build
|
|
*** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS $x_ldflags $x_libs)
|
|
|
|
CFLAGS="$saved_cflags"
|
|
LDFLAGS="$saved_ldflags"
|
|
|
|
AC_SUBST(x_cflags)
|
|
AC_SUBST(x_includes)
|
|
AC_SUBST(x_ldflags)
|
|
AC_SUBST(x_libs)
|
|
AC_SUBST(xinput_progs)
|
|
|
|
AC_SUBST(more_cflags)
|
|
AC_SUBST(more_includes)
|
|
AC_SUBST(more_ldflags)
|
|
AC_SUBST(more_libs)
|
|
AC_SUBST(gdktargetlib)
|
|
AC_SUBST(gtktargetlib)
|
|
|
|
|
|
# Check if X_LOCALE definition is necessary
|
|
|
|
AC_MSG_CHECKING(need -DX_LOCALE)
|
|
|
|
AC_TRY_RUN([
|
|
#include <stdio.h>
|
|
#include <locale.h>
|
|
|
|
int
|
|
main ()
|
|
{
|
|
return setlocale (LC_ALL, "${with_locale}") == NULL;
|
|
}],
|
|
need_x_locale=no,
|
|
need_x_locale=yes,
|
|
need_x_locale=no)
|
|
AC_MSG_RESULT($need_x_locale)
|
|
|
|
if test $need_x_locale = yes; then
|
|
GTK_LOCALE_FLAGS="-DX_LOCALE"
|
|
fi
|
|
|
|
# Checks for header files.
|
|
AC_HEADER_STDC
|
|
|
|
# Checks for typedefs, structures, and compiler characteristics.
|
|
AC_C_CONST
|
|
|
|
# Checks for library functions.
|
|
AC_TYPE_SIGNAL
|
|
AC_FUNC_MMAP
|
|
|
|
# Check if <sys/select.h> needs to be included for fd_set
|
|
AC_MSG_CHECKING([for fd_set])
|
|
AC_TRY_COMPILE([#include <sys/types.h>],
|
|
[fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
|
|
if test $gtk_ok = yes; then
|
|
AC_MSG_RESULT([yes, found in sys/types.h])
|
|
else
|
|
AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
|
|
if test $gtk_ok = yes; then
|
|
AC_DEFINE(HAVE_SYS_SELECT_H)
|
|
AC_MSG_RESULT([yes, found in sys/select.h])
|
|
else
|
|
AC_DEFINE(NO_FD_SET)
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
fi
|
|
|
|
# `widechar' tests for gdki18n.h
|
|
AC_MSG_CHECKING(for wchar.h)
|
|
AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
|
|
if test $gdk_wchar_h = yes; then
|
|
AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
|
|
fi
|
|
AC_MSG_RESULT($gdk_wchar_h)
|
|
|
|
# Check for wctype.h (for iswalnum)
|
|
AC_MSG_CHECKING(for wctype.h)
|
|
AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
|
|
if test $gdk_wctype_h = yes; then
|
|
AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
|
|
fi
|
|
AC_MSG_RESULT($gdk_wctype_h)
|
|
|
|
# in Solaris 2.5, `iswalnum' is in -lw
|
|
GDK_WLIBS=
|
|
AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
|
|
|
|
oLIBS="$LIBS"
|
|
LIBS="$LIBS $GDK_WLIBS"
|
|
# The following is necessary for Linux libc-5.4.38
|
|
AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
|
|
AC_TRY_LINK([#include <stdlib.h>],[
|
|
#if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
|
|
# ifdef HAVE_WCTYPE_H
|
|
# include <wctype.h>
|
|
# else
|
|
# ifdef HAVE_WCHAR_H
|
|
# include <wchar.h>
|
|
# endif
|
|
# endif
|
|
#else
|
|
# define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
|
|
#endif
|
|
iswalnum((wchar_t) 0);
|
|
], gdk_working_wctype=yes, gdk_working_wctype=no)
|
|
LIBS="$oLIBS"
|
|
|
|
if test $gdk_working_wctype = no; then
|
|
AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
|
|
GDK_WLIBS=
|
|
fi
|
|
AC_MSG_RESULT($gdk_working_wctype)
|
|
AC_SUBST(GDK_WLIBS)
|
|
|
|
AC_SUBST(GTK_DEBUG_FLAGS)
|
|
AC_SUBST(GTK_XIM_FLAGS)
|
|
AC_SUBST(GTK_LOCALE_FLAGS)
|
|
|
|
##################################################
|
|
# Checks for gdk-pixbuf
|
|
##################################################
|
|
|
|
AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
|
|
|
|
AC_ARG_ENABLE(modules, [ --disable-modules Disables dynamic module loading],[
|
|
if test x$withval = xyes; then
|
|
with_modules=yes
|
|
else
|
|
with_modules=no
|
|
fi
|
|
])
|
|
|
|
dynworks=false
|
|
deps=
|
|
if test x$with_modules = xno; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
AC_MSG_CHECKING(whether dynamic modules work)
|
|
oLIBS="$LIBS"
|
|
oCFLAGS="$CFLAGS"
|
|
CFLAGS="$GLIB_CFLAGS"
|
|
LIBS="$GLIB_LIBS"
|
|
AC_TRY_RUN([
|
|
#include <glib.h>
|
|
#include <gmodule.h>
|
|
main ()
|
|
{
|
|
if (g_module_supported ())
|
|
exit (0);
|
|
else
|
|
exit (1);
|
|
}
|
|
], dynworks=true)
|
|
LIBS="$oLIBS"
|
|
CFLAGS="$oCFLAGS"
|
|
fi
|
|
|
|
dnl Now we check to see if our libtool supports shared lib deps
|
|
dnl (in a rather ugly way even)
|
|
if $dynworks; then
|
|
pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
|
|
pixbuf_deplibs_check=`$pixbuf_libtool_config | \
|
|
grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
|
|
sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
|
|
if test "x$pixbuf_deplibs_check" = "xnone" || \
|
|
test "x$pixbuf_deplibs_check" = "xunknown" || \
|
|
test "x$pixbuf_deplibs_check" = "x"; then
|
|
dynworks=false
|
|
fi
|
|
fi
|
|
|
|
if $dynworks; then
|
|
AC_DEFINE(USE_GMODULE)
|
|
GMODULE_LIBS="`$GLIB_CONFIG_2_0 --libs gmodule`"
|
|
GMODULE_FLAGS="`$GLIB_CONFIG_2_0 --cflags gmodule`"
|
|
AC_SUBST(GMODULE_LIBS)
|
|
AC_SUBST(GMODULE_FLAGS)
|
|
AC_MSG_RESULT(yes)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
|
|
dnl Test for libtiff
|
|
if test -z "$LIBTIFF"; then
|
|
AC_CHECK_LIB(tiff, TIFFReadScanline,
|
|
AC_CHECK_HEADER(tiffio.h,
|
|
TIFF='tiff'; LIBTIFF='-ltiff',
|
|
AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
|
|
AC_CHECK_LIB(tiff, TIFFWriteScanline,
|
|
AC_CHECK_HEADER(tiffio.h,
|
|
TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
|
|
AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
|
|
AC_CHECK_LIB(tiff34, TIFFFlushData,
|
|
AC_CHECK_HEADER(tiffio.h,
|
|
TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
|
|
AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
|
|
AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
|
|
fi
|
|
|
|
dnl Test for libjpeg
|
|
if test -z "$LIBJPEG"; then
|
|
AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
|
|
jpeg_ok=yes,
|
|
jpeg_ok=no
|
|
AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
|
|
if test "$jpeg_ok" = yes; then
|
|
AC_MSG_CHECKING([for jpeglib.h])
|
|
AC_TRY_CPP(
|
|
[#include <stdio.h>
|
|
#undef PACKAGE
|
|
#undef VERSION
|
|
#include <jpeglib.h>],
|
|
jpeg_ok=yes,
|
|
jpeg_ok=no)
|
|
AC_MSG_RESULT($jpeg_ok)
|
|
if test "$jpeg_ok" = yes; then
|
|
LIBJPEG='-ljpeg'
|
|
AC_CHECK_LIB(jpeg, jpeg_simple_progression,
|
|
AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
|
|
AC_MSG_WARN(JPEG library does not support progressive saving.))
|
|
else
|
|
AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
|
|
fi
|
|
fi
|
|
fi
|
|
|
|
dnl Test for libpng
|
|
if test -z "$LIBPNG"; then
|
|
AC_CHECK_LIB(png, png_read_info,
|
|
AC_CHECK_HEADER(png.h,
|
|
png_ok=yes,
|
|
png_ok=no),
|
|
AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
|
|
if test "$png_ok" = yes; then
|
|
AC_MSG_CHECKING([for png_structp in png.h])
|
|
AC_TRY_COMPILE([#include <png.h>],
|
|
[png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
|
|
png_ok=yes,
|
|
png_ok=no)
|
|
AC_MSG_RESULT($png_ok)
|
|
if test "$png_ok" = yes; then
|
|
PNG='png'; LIBPNG='-lpng -lz'
|
|
else
|
|
AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
|
|
fi
|
|
else
|
|
AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
|
|
fi
|
|
fi
|
|
|
|
deps="$LIBTIFF $LIBJPEG $LIBPNG"
|
|
|
|
AC_SUBST(LIBTIFF)
|
|
AC_SUBST(LIBJPEG)
|
|
AC_SUBST(LIBPNG)
|
|
|
|
AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
|
|
|
|
AC_HEADER_STDC
|
|
AC_HEADER_DIRENT
|
|
AC_HEADER_SYS_WAIT
|
|
|
|
AC_TYPE_SIGNAL
|
|
|
|
AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
|
|
AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
|
|
AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
|
|
|
|
GDK_PIXBUF_LIBDIR='-L${libdir}'
|
|
GDK_PIXBUF_INCLUDEDIR="-I${includedir} $GTK_CFLAGS"
|
|
GDK_PIXBUF_LIBS="$GLIB_LIBS -lgdk_pixbuf $deps $GTK_LIBS"
|
|
AC_SUBST(STATIC_LIB_DEPS)
|
|
STATIC_LIB_DEPS="$deps"
|
|
|
|
AC_SUBST(GDK_PIXBUF_LIBDIR)
|
|
AC_SUBST(GDK_PIXBUF_INCLUDEDIR)
|
|
AC_SUBST(GDK_PIXBUF_LIBS)
|
|
|
|
GDK_PIXBUF_XLIB_LIBDIR=$GDK_PIXBUF_LIBDIR
|
|
GDK_PIXBUF_XLIB_INCLUDEDIR=$GDK_PIXBUF_INCLUDEDIR
|
|
GDK_PIXBUF_XLIB_LIBS="$GLIB_LIBS -lgdk_pixbuf_xlib $deps $X11_LIBS"
|
|
|
|
AC_SUBST(GDK_PIXBUF_XLIB_LIBDIR)
|
|
AC_SUBST(GDK_PIXBUF_XLIB_INCLUDEDIR)
|
|
AC_SUBST(GDK_PIXBUF_XLIB_LIBS)
|
|
|
|
# Checks to see if we should compile in MMX support (there will be
|
|
# a runtime test when the code is actually run to see if it should
|
|
# be used - this just checks if we can compile it.)
|
|
#
|
|
# This code is partially taken from Mesa
|
|
#
|
|
AC_MSG_CHECKING(for x86 platform)
|
|
case $host_cpu in
|
|
i386|i486|i586|i686|i786|k6|k7)
|
|
use_x86_asm=yes
|
|
;;
|
|
*)
|
|
use_x86_asm=no
|
|
esac
|
|
AC_MSG_RESULT($use_x86_asm)
|
|
|
|
use_mmx_asm=no
|
|
if test $use_x86_asm = yes; then
|
|
save_ac_ext=$ac_ext
|
|
ac_ext=S
|
|
|
|
AC_MSG_CHECKING(compiler support for MMX)
|
|
cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
|
|
if AC_TRY_EVAL(ac_compile); then
|
|
use_mmx_asm=yes
|
|
fi
|
|
|
|
rm -rf conftest*
|
|
|
|
ac_ext=$save_ac_ext
|
|
if test $use_mmx_asm = yes; then
|
|
AC_DEFINE(USE_MMX)
|
|
AC_MSG_RESULT(yes)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
fi
|
|
|
|
AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
|
|
|
|
|
|
##################################################
|
|
# Checks for gtk-doc and docbook-tools
|
|
##################################################
|
|
|
|
AC_ARG_WITH(html-dir, [ --with-html-dir=PATH path to installed docs ])
|
|
|
|
if test "x$with_html_dir" = "x" ; then
|
|
HTML_DIR='${datadir}/gtk-doc/html'
|
|
else
|
|
HTML_DIR=$with_html_dir
|
|
fi
|
|
|
|
AC_SUBST(HTML_DIR)
|
|
|
|
AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
|
|
AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
|
|
AC_SUBST(HAVE_GTK_DOC)
|
|
|
|
AC_CHECK_PROG(DB2HTML, db2html, true, false)
|
|
AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
|
|
|
|
dnl Let people disable the gtk-doc stuff.
|
|
AC_ARG_ENABLE(gtk-doc, [ --enable-gtk-doc Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
|
|
|
|
if test x$enable_gtk_doc = xauto ; then
|
|
if test x$GTKDOC = xtrue ; then
|
|
enable_gtk_doc=yes
|
|
else
|
|
enable_gtk_doc=no
|
|
fi
|
|
fi
|
|
|
|
dnl NOTE: We need to use a separate automake conditional for this
|
|
dnl to make this work with the tarballs.
|
|
AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
|
|
|
|
GDK_PIXBUF_DIR=`(cd $srcdir; pwd)`
|
|
AC_SUBST(GDK_PIXBUF_DIR)
|
|
|
|
|
|
##################################################
|
|
# Output commands
|
|
##################################################
|
|
|
|
AC_OUTPUT_COMMANDS([
|
|
|
|
## Generate `gdk/gdkconfig.h' in two cases
|
|
## 1. `config.status' is run either explicitly, or via configure.
|
|
## Esp. not when it is run in `Makefile' to generate makefiles and
|
|
## config.h
|
|
## 2. CONFIG_OTHER is set explicitly
|
|
##
|
|
## Case 1 is difficult. We know that `automake' sets one of
|
|
## CONFIG_FILES or CONFIG_HEADERS to empty. This heuristic works
|
|
## only when AM_CONFIG_HEADER is set, however.
|
|
|
|
if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
|
|
# Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
|
|
CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
|
|
fi
|
|
case "$CONFIG_OTHER" in
|
|
*gdk/gdkconfig.h*)
|
|
echo creating gdk/gdkconfig.h
|
|
outfile=gdkconfig.h-tmp
|
|
cat > $outfile <<\_______EOF
|
|
/* gdkconfig.h
|
|
*
|
|
* This is a generated file. Please modify `configure.in'
|
|
*/
|
|
|
|
#ifndef GDKCONFIG_H
|
|
#define GDKCONFIG_H
|
|
|
|
#ifdef __cplusplus
|
|
extern "C" {
|
|
#endif /* __cplusplus */
|
|
|
|
_______EOF
|
|
|
|
cat >>$outfile <<_______EOF
|
|
$gdk_windowing
|
|
$gdk_wc
|
|
_______EOF
|
|
|
|
cat >>$outfile <<_______EOF
|
|
|
|
#ifdef __cplusplus
|
|
}
|
|
#endif /* __cplusplus */
|
|
|
|
#endif /* GDKCONFIG_H */
|
|
_______EOF
|
|
|
|
|
|
if cmp -s $outfile gdk/gdkconfig.h; then
|
|
echo gdk/gdkconfig.h is unchanged
|
|
rm -f $outfile
|
|
else
|
|
mv $outfile gdk/gdkconfig.h
|
|
fi ;;
|
|
esac
|
|
],[
|
|
# Currently we always use X11 on those systems where we run configure...
|
|
if test "x$gdktarget" = "xx11" ; then
|
|
gdk_windowing='
|
|
#define GDK_WINDOWING_X11'
|
|
elif test "x$gdktarget" = "xnanox" ; then
|
|
gdk_windowing='
|
|
#define GDK_WINDOWING_NANOX'
|
|
elif test "x$gdktarget" = "xlinux-fb" ; then
|
|
gdk_windowing='
|
|
#define GDK_WINDOWING_FB
|
|
#define GDK_NATIVE_WINDOW_POINTER'
|
|
fi
|
|
|
|
if test x$gdk_wchar_h = xyes; then
|
|
gdk_wc='
|
|
#define GDK_HAVE_WCHAR_H 1'
|
|
fi
|
|
if test x$gdk_wctype_h = xyes; then
|
|
gdk_wc="\$gdk_wc
|
|
#define GDK_HAVE_WCTYPE_H 1"
|
|
fi
|
|
if test x$gdk_working_wctype = xno; then
|
|
gdk_wc="\$gdk_wc
|
|
#define GDK_HAVE_BROKEN_WCTYPE 1"
|
|
fi
|
|
|
|
|
|
])
|
|
|
|
AC_PATH_PROG(SGML2HTML, sgml2html, no)
|
|
AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
|
|
|
|
AC_OUTPUT([
|
|
gtk+.spec
|
|
docs/gtk-config.1
|
|
Makefile
|
|
gtk-config-2.0
|
|
gdk-pixbuf-2.0.pc
|
|
gdk-2.0.pc
|
|
gtk+-2.0.pc
|
|
po/Makefile.in
|
|
build/Makefile
|
|
build/win32/Makefile
|
|
demos/Makefile
|
|
demos/gtk-demo/Makefile
|
|
tests/Makefile
|
|
docs/Makefile
|
|
docs/reference/Makefile
|
|
docs/reference/gdk-pixbuf/Makefile
|
|
docs/reference/gdk/Makefile
|
|
docs/reference/gtk/Makefile
|
|
docs/faq/Makefile
|
|
docs/tutorial/Makefile
|
|
gdk-pixbuf/Makefile
|
|
gdk-pixbuf/makefile.mingw
|
|
gdk-pixbuf/gdk-pixbuf-features.h
|
|
gdk-pixbuf/pixops/Makefile
|
|
gdk-pixbuf/pixops/makefile.mingw
|
|
gdk/Makefile
|
|
gdk/makefile.mingw
|
|
gdk/x11/Makefile
|
|
gdk/win32/Makefile
|
|
gdk/win32/makefile.mingw
|
|
gdk/win32/rc/Makefile
|
|
gdk/win32/rc/gdk.rc
|
|
gdk/nanox/Makefile
|
|
gdk/linux-fb/Makefile
|
|
gtk/Makefile
|
|
gtk/makefile.mingw
|
|
gtk/makefile.msc
|
|
gtk/gtkcompat.h
|
|
gtk/gtk-win32.rc
|
|
gtk/stock-icons/Makefile
|
|
modules/Makefile
|
|
modules/input/Makefile
|
|
contrib/Makefile
|
|
contrib/gdk-pixbuf-xlib/Makefile
|
|
contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
|
|
], [chmod +x gtk-config-2.0])
|