qt5base-lts/cmake/QtPluginDependencies.cmake.in

set(@target@_FOUND FALSE)

# note: _third_party_deps example: "ICU\\;FALSE\\;1.0\\;i18n uc data;ZLIB\\;FALSE\\;\\;"
set(__qt_@target@_third_party_deps "@third_party_deps@")

foreach(__qt_@target@_target_dep ${__qt_@target@_third_party_deps})
    list(GET __qt_@target@_target_dep 0 __qt_@target@_pkg)
    list(GET __qt_@target@_target_dep 1 __qt_@target@_is_optional)
    list(GET __qt_@target@_target_dep 2 __qt_@target@_version)
    list(GET __qt_@target@_target_dep 3 __qt_@target@_components)
    list(GET __qt_@target@_target_dep 4 __qt_@target@_optional_components)
    set(__qt_@target@_find_package_args "${__qt_@target@_pkg}")
    if(__qt_@target@_version)
        list(APPEND __qt_@target@_find_package_args "${__qt_@target@_version}")
    endif()
    if(__qt_@target@_components)
        string(REPLACE " " ";" __qt_@target@_components "${__qt_@target@_components}")
        list(APPEND __qt_@target@_find_package_args COMPONENTS ${__qt_@target@_components})
    endif()
    if(__qt_@target@_optional_components)
        string(REPLACE " " ";" __qt_@target@_optional_components "${__qt_@target@_optional_components}")
        list(APPEND __qt_@target@_find_package_args OPTIONAL_COMPONENTS ${__qt_@target@_optional_components})
    endif()

    if(__qt_@target@_is_optional)
        if(${CMAKE_FIND_PACKAGE_NAME}_FIND_QUIETLY)
            list(APPEND __qt_@target@_find_package_args QUIET)
        endif()
        find_package(${__qt_@target@_find_package_args})
    else()
        find_dependency(${__qt_@target@_find_package_args})
    endif()
endforeach()

set(__qt_use_no_default_path_for_qt_packages "NO_DEFAULT_PATH")
if(QT_DISABLE_NO_DEFAULT_PATH_IN_QT_PACKAGES)
    set(__qt_use_no_default_path_for_qt_packages "")
endif()

# note: target_deps example: "Qt6Core\;5.12.0;Qt6Gui\;5.12.0"
set(__qt_@target@_target_deps "@target_deps@")
set(__qt_@target@_find_dependency_paths "@find_dependency_paths@")
_qt_internal_find_dependencies(__qt_@target@_target_deps __qt_@target@_find_dependency_paths)

set(@target@_FOUND TRUE)