47 lines
1.0 KiB
Plaintext
47 lines
1.0 KiB
Plaintext
|
#
|
||
|
|
# W A R N I N G
|
||
|
|
# -------------
|
||
|
|
#
|
||
|
|
# This file is not part of the Qt API. It exists purely as an
|
||
|
|
# implementation detail. It may change from version to version
|
||
|
|
# without notice, or even be removed.
|
||
|
|
#
|
||
|
|
# We mean it.
|
||
|
|
#
|
||
|
|
|
||
|
|
staticlib: \
|
||
|
|
CONFIG += static
|
||
|
|
else: dll: \
|
||
|
|
CONFIG += shared
|
||
|
|
|
||
|
|
CONFIG(static, static|shared) {
|
||
|
|
CONFIG -= shared dll
|
||
|
|
contains(TEMPLATE, ".*lib"): CONFIG += staticlib
|
||
|
|
} else {
|
||
|
|
CONFIG -= static staticlib
|
||
|
|
contains(TEMPLATE, ".*lib"): CONFIG += dll
|
||
|
|
}
|
||
|
|
|
||
|
|
static_and_shared {
|
||
|
|
!macx-xcode: addExclusiveBuilds(static, Static, shared, Shared)
|
||
|
|
} else: fix_output_dirs {
|
||
|
|
static: \
|
||
|
|
fixExclusiveOutputDirs(static, shared)
|
||
|
|
else: \
|
||
|
|
fixExclusiveOutputDirs(shared, static)
|
||
|
|
}
|
||
|
|
|
||
|
|
CONFIG(debug, debug|release): \
|
||
|
|
CONFIG -= release
|
||
|
|
else: \
|
||
|
|
CONFIG -= debug
|
||
|
|
|
||
|
|
debug_and_release {
|
||
|
|
!macx-xcode: addExclusiveBuilds(debug, Debug, release, Release)
|
||
|
|
} else: fix_output_dirs {
|
||
|
|
debug: \
|
||
|
|
fixExclusiveOutputDirs(debug, release)
|
||
|
|
else: \
|
||
|
|
fixExclusiveOutputDirs(release, debug)
|
||
|
|
}
|