Use dependencies instead of CONFIG+=ordered

Also drops a few instances where the dependency was purely runtime, especially for examples. Change-Id: I2a0476f79928143596bdb3b8f01193af90574ae8 Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@qt.io>
2017-11-20 12:29:03 +01:00 · 2017-11-20 12:29:03 +01:00 · 2c25a431d0
commit 2c25a431d0
parent beb9ca92df
17 changed files with 39 additions and 29 deletions
--- a/examples/corelib/tools/tools.pro
+++ b/examples/corelib/tools/tools.pro
@ -1,7 +1,6 @@
 requires(qtHaveModule(widgets))

 TEMPLATE      = subdirs
-CONFIG       += ordered
 SUBDIRS       = contiguouscache \
                customtype \
                customtypesending
--- a/examples/dbus/complexpingpong/complexpingpong.pro
+++ b/examples/dbus/complexpingpong/complexpingpong.pro
@ -1,4 +1,3 @@
 TEMPLATE = subdirs
-CONFIG += ordered
 win32:CONFIG += console
 SUBDIRS = complexping.pro complexpong.pro
--- a/examples/dbus/pingpong/pingpong.pro
+++ b/examples/dbus/pingpong/pingpong.pro
@ -1,4 +1,3 @@
 TEMPLATE = subdirs
-CONFIG += ordered
 win32:CONFIG += console
 SUBDIRS = ping.pro pong.pro
--- a/examples/widgets/desktop/desktop.pro
+++ b/examples/widgets/desktop/desktop.pro
@ -1,3 +1,2 @@
 TEMPLATE      = subdirs
-CONFIG       += ordered
 SUBDIRS       = screenshot systray
--- a/tests/auto/corelib/global/qlogging/qlogging.pro
+++ b/tests/auto/corelib/global/qlogging/qlogging.pro
@ -1,6 +1,8 @@
 TEMPLATE = subdirs
-CONFIG += ordered

-!winrt: SUBDIRS += app
+!winrt {
+    test.depends = app
+    SUBDIRS += app
+}

 SUBDIRS += test
--- a/tests/auto/corelib/kernel/qobject/qobject.pro
+++ b/tests/auto/corelib/kernel/qobject/qobject.pro
@ -1,6 +1,8 @@
 TEMPLATE = subdirs
-CONFIG += ordered

-!winrt: SUBDIRS+= signalbug
+!winrt {
+    test.depends = signalbug
+    SUBDIRS += signalbug
+}

 SUBDIRS += test
--- a/tests/auto/corelib/plugin/qfactoryloader/qfactoryloader.pro
+++ b/tests/auto/corelib/plugin/qfactoryloader/qfactoryloader.pro
@ -1,6 +1,7 @@
 QT = core-private
 TEMPLATE = subdirs
-CONFIG  += ordered
+
+test.depends = plugin1 plugin2
 SUBDIRS = \
    plugin1 \
    plugin2 \
--- a/tests/auto/corelib/plugin/qlibrary/qlibrary.pro
+++ b/tests/auto/corelib/plugin/qlibrary/qlibrary.pro
@ -1,6 +1,7 @@
 QT = core
 TEMPLATE    =	subdirs
-CONFIG  += ordered
+
+tst.depends = lib lib2

 SUBDIRS =   lib \
            lib2 \
--- a/tests/auto/corelib/plugin/qpluginloader/qpluginloader.pro
+++ b/tests/auto/corelib/plugin/qpluginloader/qpluginloader.pro
@ -1,12 +1,18 @@
 QT = core
-TEMPLATE    =	subdirs
-CONFIG  += ordered
-SUBDIRS	=	lib \
-                theplugin \
-		tst
-!android: !win32: !mac: SUBDIRS += almostplugin
-macx-*: qtConfig(private_tests): SUBDIRS += machtest
-TARGET = tst_qpluginloader
+TEMPLATE = subdirs
+
+tst.depends = lib theplugin
+SUBDIRS = lib \
+          theplugin \
+          tst
+!android:!win32:!darwin {
+    tst.depends += almostplugin
+    SUBDIRS += almostplugin
+}
+macos:qtConfig(private_tests) {
+    tst.depends += machtest
+    SUBDIRS += machtest
+}

 # no special install rule for subdir
 INSTALLS =
--- a/tests/auto/corelib/thread/qthreadstorage/qthreadstorage.pro
+++ b/tests/auto/corelib/thread/qthreadstorage/qthreadstorage.pro
@ -1,7 +1,8 @@
 TEMPLATE = subdirs
-SUBDIRS = \
-    test

-!winrt: SUBDIRS += crashonexit
+!winrt {
+    test.depends = crashonexit
+    SUBDIRS += crashonexit
+}

-CONFIG += ordered
+SUBDIRS += test
--- a/tests/auto/dbus/qdbusabstractadaptor/qdbusabstractadaptor.pro
+++ b/tests/auto/dbus/qdbusabstractadaptor/qdbusabstractadaptor.pro
@ -2,5 +2,6 @@ CONFIG += testcase
 TARGET = tst_qdbusabstractadaptor
 QT = core core-private testlib
 TEMPLATE = subdirs
-CONFIG += ordered
+
+qdbusabstractadaptor.depends = qmyserver
 SUBDIRS = qmyserver qdbusabstractadaptor
--- a/tests/auto/dbus/qdbusabstractinterface/qdbusabstractinterface.pro
+++ b/tests/auto/dbus/qdbusabstractinterface/qdbusabstractinterface.pro
@ -1,6 +1,6 @@
 CONFIG += testcase
 TARGET = tst_qdbusabstractinterface
 TEMPLATE = subdirs
-CONFIG += ordered
+qdbusabstractinterface.depends = qpinger
 SUBDIRS = qpinger qdbusabstractinterface
 OTHER_FILES += org.qtproject.QtDBus.Pinger.xml
--- a/tests/auto/dbus/qdbusinterface/qdbusinterface.pro
+++ b/tests/auto/dbus/qdbusinterface/qdbusinterface.pro
@ -2,5 +2,5 @@ CONFIG += testcase
 TARGET = tst_qdbusinterface
 QT = core testlib
 TEMPLATE = subdirs
-CONFIG += ordered
+qdbusinterface.depends = qmyserver
 SUBDIRS = qmyserver qdbusinterface
--- a/tests/auto/dbus/qdbusmarshall/qdbusmarshall.pro
+++ b/tests/auto/dbus/qdbusmarshall/qdbusmarshall.pro
@ -1,7 +1,7 @@
 CONFIG += testcase
 TARGET = tst_qdbusmarshall
 TEMPLATE = subdirs
-CONFIG += ordered
+qdbusmarshall.depends = qpong
 SUBDIRS = qpong qdbusmarshall

 QT = core-private testlib
--- a/tests/auto/other/macplist/macplist.pro
+++ b/tests/auto/other/macplist/macplist.pro
@ -1,7 +1,7 @@
 TEMPLATE = subdirs

+test.depends = app
 SUBDIRS = app test 
-CONFIG += ordered



--- a/tests/benchmarks/corelib/io/qprocess/qprocess.pro
+++ b/tests/benchmarks/corelib/io/qprocess/qprocess.pro
@ -1,3 +1,3 @@
 TEMPLATE = subdirs
-CONFIG += ordered
+test.depends = testProcessLoopback
 SUBDIRS = testProcessLoopback test
--- a/tests/benchmarks/dbus/qdbusperformance/qdbusperformance.pro
+++ b/tests/benchmarks/dbus/qdbusperformance/qdbusperformance.pro
@ -1,3 +1,3 @@
 TEMPLATE = subdirs
-CONFIG += ordered
+test.depends = server
 SUBDIRS = server test