8185fe84a6
- remove the unconditional CONFIG+=c++11 from default_pre.prf, so the
change actually has any effect
- fix up the description fields somewhat
this amends 091df96fb8, which was rushed in without maintainer review.
Change-Id: I88b859d6e2f0fe3d6a4771afe464a7c445e7b47b
Reviewed-by: Lars Knoll <lars.knoll@qt.io>
72 lines
2.8 KiB
Plaintext
72 lines
2.8 KiB
Plaintext
# This file is loaded by qmake right before each actual project file.
|
|
# Note that evaluating variable assignments from the command line
|
|
# still happens in between these two steps.
|
|
|
|
load(exclusive_builds)
|
|
CONFIG = \
|
|
lex yacc debug exceptions depend_includepath \
|
|
testcase_targets import_plugins import_qpa_plugin \
|
|
$$CONFIG
|
|
|
|
!build_pass:defined(QT_EDITION, var):!equals(QT_EDITION, "OpenSource"):!equals(QT_EDITION, "Preview") {
|
|
#
|
|
# call license checker (but cache result for one day)
|
|
#
|
|
today = $$section(_DATE_, " ", 0, 2)
|
|
!isEqual(QMAKE_LICHECK_TIMESTAMP, $$today) {
|
|
!system("$$system_quote($$system_path($$[QT_HOST_BINS/src]/$$QT_LICHECK)) check" \
|
|
"$$QT_RELEASE_DATE $$[QMAKE_SPEC] $$[QMAKE_XSPEC]"): \
|
|
error("License check failed! Giving up ...")
|
|
|
|
cache(QMAKE_LICHECK_TIMESTAMP, set stash, today)
|
|
}
|
|
unset(today)
|
|
}
|
|
|
|
isEmpty(QMAKE_DEFAULT_INCDIRS):!host_build {
|
|
#
|
|
# Get default include and library paths from compiler
|
|
#
|
|
gcc {
|
|
!equals(QMAKE_HOST.os, Windows) {
|
|
cmd_prefix = "LC_ALL=C"
|
|
cmd_suffix = "</dev/null >/dev/null"
|
|
} else {
|
|
cmd_prefix = "set LC_ALL=C&"
|
|
cmd_suffix = "<NUL >NUL"
|
|
}
|
|
output = $$system("$$cmd_prefix $$QMAKE_CXX $$QMAKE_CXXFLAGS -xc++ -E -v - 2>&1 $$cmd_suffix", lines)
|
|
add_includes = false
|
|
for (line, output) {
|
|
line ~= s/^ *// # remove leading spaces
|
|
contains(line, "LIBRARY_PATH=.*") {
|
|
line ~= s/^LIBRARY_PATH=// # remove leading LIBRARY_PATH=
|
|
paths = $$split(line, $$QMAKE_DIRLIST_SEP)
|
|
for (path, paths): \
|
|
QMAKE_DEFAULT_LIBDIRS += $$clean_path($$path)
|
|
} else: contains(line, "$${LITERAL_HASH}include <.*") { # #include <...> search starts here:
|
|
add_includes = true
|
|
} else: contains(line, "End of search.*") {
|
|
add_includes = false
|
|
} else: $$add_includes {
|
|
!contains(line, ".* \\(framework directory\\)"): \
|
|
QMAKE_DEFAULT_INCDIRS += $$clean_path($$line)
|
|
}
|
|
}
|
|
QMAKE_DEFAULT_LIBDIRS = $$unique(QMAKE_DEFAULT_LIBDIRS)
|
|
} else: msvc {
|
|
LIB = $$getenv("LIB")
|
|
QMAKE_DEFAULT_LIBDIRS = $$split(LIB, $$QMAKE_DIRLIST_SEP)
|
|
INCLUDE = $$getenv("INCLUDE")
|
|
QMAKE_DEFAULT_INCDIRS = $$split(INCLUDE, $$QMAKE_DIRLIST_SEP)
|
|
}
|
|
|
|
unix {
|
|
isEmpty(QMAKE_DEFAULT_INCDIRS): QMAKE_DEFAULT_INCDIRS = /usr/include /usr/local/include
|
|
isEmpty(QMAKE_DEFAULT_LIBDIRS): QMAKE_DEFAULT_LIBDIRS = /lib /usr/lib
|
|
}
|
|
|
|
!isEmpty(QMAKE_DEFAULT_INCDIRS): cache(QMAKE_DEFAULT_INCDIRS, set stash)
|
|
!isEmpty(QMAKE_DEFAULT_LIBDIRS): cache(QMAKE_DEFAULT_LIBDIRS, set stash)
|
|
}
|