087efb572a
qdocconf files can now reference $QT_INSTALL_DOCS to pick up e.g. global includes, instead of using relative paths. Qt modules will automatically get a doc target that builds and installs into the right place (including supporting shadow-builds) if they set QMAKE_DOCS before loading(qt_module). Change-Id: Ia408385199e56e3ead0afa45645a059d1a8b0d48 Reviewed-by: Tor Arne Vestbø <tor.arne.vestbo@digia.com>
58 lines
1.7 KiB
Plaintext
58 lines
1.7 KiB
Plaintext
#library
|
|
!qt_no_install_library {
|
|
win32 {
|
|
dlltarget.path = $$[QT_INSTALL_BINS]
|
|
INSTALLS += dlltarget
|
|
}
|
|
target.path = $$[QT_INSTALL_LIBS]
|
|
INSTALLS += target
|
|
}
|
|
|
|
#headers
|
|
qt_install_headers {
|
|
INSTALL_HEADERS = $$SYNCQT.HEADER_FILES
|
|
|
|
equals(TARGET, phonon) {
|
|
class_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
|
|
} else {
|
|
flat_headers.files = $$INSTALL_HEADERS
|
|
flat_headers.path = $$[QT_INSTALL_HEADERS]/Qt
|
|
INSTALLS += flat_headers
|
|
|
|
class_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
|
|
}
|
|
class_headers.files = $$SYNCQT.HEADER_CLASSES
|
|
INSTALLS += class_headers
|
|
|
|
targ_headers.files = $$INSTALL_HEADERS
|
|
targ_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
|
|
INSTALLS += targ_headers
|
|
|
|
private_headers.files = $$SYNCQT.PRIVATE_HEADER_FILES
|
|
private_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET/$$eval(QT.$${MODULE}.VERSION)/$$TARGET/private
|
|
INSTALLS += private_headers
|
|
|
|
qpa_headers.files = $$SYNCQT.QPA_HEADER_FILES
|
|
qpa_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET/$$eval(QT.$${MODULE}.VERSION)/$$TARGET/qpa
|
|
INSTALLS += qpa_headers
|
|
}
|
|
|
|
#module
|
|
qt_install_module {
|
|
!isEmpty(MODULE_PRI) {
|
|
pritarget.path = $$[QT_HOST_DATA]/mkspecs/modules
|
|
pritarget.files = $$MODULE_PRI
|
|
INSTALLS += pritarget
|
|
} else {
|
|
warning("Project $$basename(_PRO_FILE_) is a module, but has not defined MODULE_PRI, which is required for Qt to expose the module to other projects.")
|
|
}
|
|
}
|
|
|
|
qt_install_module_docs {
|
|
module_docs.files = $$QMAKE_DOCS_OUTPUTDIR
|
|
module_docs.path = $$[QT_INSTALL_DOCS]
|
|
module_docs.CONFIG += no_check_exist directory
|
|
module_docs.depends += docs
|
|
INSTALLS += module_docs
|
|
}
|