34dc76c851
Added branching to plugandpaint example to get correct library architecture to the build Fixes: QTBUG-56322 Pick-to: 5.15 Change-Id: I4d0eb4e24681642991d08c3dd2bad73d10caf962 Reviewed-by: Assam Boudjelthia <assam.boudjelthia@qt.io>
38 lines
896 B
Prolog
38 lines
896 B
Prolog
#! [0]
|
|
TARGET = plugandpaint
|
|
DESTDIR = ..
|
|
|
|
QT += widgets
|
|
|
|
HEADERS = interfaces.h \
|
|
mainwindow.h \
|
|
paintarea.h \
|
|
plugindialog.h
|
|
SOURCES = main.cpp \
|
|
mainwindow.cpp \
|
|
paintarea.cpp \
|
|
plugindialog.cpp
|
|
|
|
LIBS = -L../plugins
|
|
|
|
macx-xcode {
|
|
LIBS += -lpnp_basictools$($${QMAKE_XCODE_LIBRARY_SUFFIX_SETTING})
|
|
} else {
|
|
android {
|
|
LIBS += -lpnp_basictools_$${QT_ARCH}
|
|
} else {
|
|
LIBS += -lpnp_basictools
|
|
}
|
|
if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
|
|
mac:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)_debug
|
|
win32:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)d
|
|
}
|
|
}
|
|
#! [0]
|
|
|
|
# install
|
|
target.path = $$[QT_INSTALL_EXAMPLES]/widgets/tools/plugandpaint
|
|
INSTALLS += target
|
|
|
|
CONFIG += install_ok # Do not cargo-cult this!
|