e1109df7a9
This is actually a list in CMake, not a value to be prepended to paths. Specify the QT_SYSROOT instead to root the location of include directories. CMake will soon get a CMAKE_SYSROOT variable which will replace this. Change-Id: I239f69f127f3676a3835aa4f29638f44ef209819 Reviewed-by: Volker Krause <volker.krause@kdab.com> Reviewed-by: Stephen Kelly <stephen.kelly@kdab.com> Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@digia.com>
66 lines
1.3 KiB
Plaintext
66 lines
1.3 KiB
Plaintext
#
|
|
# W A R N I N G
|
|
# -------------
|
|
#
|
|
# This file is not part of the Qt API. It exists purely as an
|
|
# implementation detail. It may change from version to version
|
|
# without notice, or even be removed.
|
|
#
|
|
# We mean it.
|
|
#
|
|
|
|
defineReplace(cmakeModuleName) {
|
|
_module = $$1
|
|
_name = $$eval(QT.$${_module}.name)
|
|
cmake_module_name = $$replace(_name, ^Qt, )
|
|
return ($$cmake_module_name)
|
|
}
|
|
|
|
defineReplace(cmakeModuleList) {
|
|
variable = $$1
|
|
out =
|
|
for(v, variable) {
|
|
out += $$cmakeModuleName($$v)
|
|
}
|
|
return ($$join(out, ";"))
|
|
}
|
|
|
|
defineReplace(cmakeTargetPath) {
|
|
SYSR = $$[QT_SYSROOT]
|
|
!isEmpty(SYSR): path = $$relative_path($$1, $$[QT_SYSROOT])
|
|
else: path = $$1
|
|
return(/$$path)
|
|
}
|
|
|
|
defineReplace(cmakeTargetPaths) {
|
|
variable = $$1
|
|
out =
|
|
for(v, variable) {
|
|
out += \"$$cmakeTargetPath($$v)\"
|
|
}
|
|
return ($$join(out, " "))
|
|
}
|
|
|
|
defineReplace(cmakePortablePaths) {
|
|
variable = $$1
|
|
out =
|
|
for(v, variable) {
|
|
out += $$[QT_SYSROOT]$$cmakeTargetPath($$v)
|
|
}
|
|
return ($$join(out, ";"))
|
|
}
|
|
|
|
defineReplace(cmakeProcessLibs) {
|
|
variable = $$1
|
|
out =
|
|
for(v, variable) {
|
|
if(!equals(v, -framework):!equals(v, -L.*)) {
|
|
v ~= s,^-l,,
|
|
v ~= s,^-lib,,
|
|
v ~= s,.lib$,,
|
|
out += $$v
|
|
}
|
|
}
|
|
return ($$join(out, ";"))
|
|
}
|