6cd358db7e
otherwise it's sometimes quite hard to tell it apart from configure's own messages. Change-Id: I2f4908344367a9a3ce38e032bf76486fc4552ffd Reviewed-by: Lars Knoll <lars.knoll@qt.io>
48 lines
1.2 KiB
Plaintext
48 lines
1.2 KiB
Plaintext
equals(QMAKE_HOST.os, Windows) {
|
|
SETENV_PFX = "set "
|
|
SETENV_SFX = "&"
|
|
} else {
|
|
SETENV_PFX =
|
|
SETENV_SFX =
|
|
}
|
|
|
|
QMAKE_MAKE = $$(MAKE)
|
|
!isEmpty(QMAKE_MAKE) {
|
|
# We were called recursively. Use the same make.
|
|
} else: if(equals(MAKEFILE_GENERATOR, UNIX)|equals(MAKEFILE_GENERATOR, MINGW)) {
|
|
!equals(QMAKE_HOST.os, Windows): \
|
|
QMAKE_MAKE = make
|
|
else: \
|
|
QMAKE_MAKE = mingw32-make
|
|
} else: if(equals(MAKEFILE_GENERATOR, MSVC.NET)|equals(MAKEFILE_GENERATOR, MSBUILD)) {
|
|
QMAKE_MAKE = nmake
|
|
} else {
|
|
error("Configure tests are not supported with the $$MAKEFILE_GENERATOR Makefile generator.")
|
|
}
|
|
# Make sure we don't inherit MAKEFLAGS - -i in particular is fatal.
|
|
QMAKE_MAKE = "$${SETENV_PFX}MAKEFLAGS=$$SETENV_SFX $$QMAKE_MAKE"
|
|
|
|
isEmpty(QMAKE_CONFIG_VERBOSE): QMAKE_CONFIG_VERBOSE = false
|
|
|
|
defineTest(qtLog) {
|
|
write_file($$QMAKE_CONFIG_LOG, 1, append)
|
|
$$QMAKE_CONFIG_VERBOSE: for (l, 1): log("$$l$$escape_expand(\\n)")
|
|
}
|
|
|
|
defineTest(qtRunLoggedCommand) {
|
|
qtLog("+ $$1")
|
|
|
|
output = $$system("( $$1 ) 2>&1", lines, result)
|
|
lg =
|
|
for (l, output): \
|
|
lg += "> $$l"
|
|
qtLog($$lg)
|
|
!isEmpty(2) {
|
|
$$2 = $$output
|
|
export($$2)
|
|
}
|
|
|
|
!equals(result, 0): return(false)
|
|
return(true)
|
|
}
|