38be0d1383
This is the beginning of revision history for this module. If you want to look at revision history older than this, please refer to the Qt Git wiki for how to use Git history grafting. At the time of writing, this wiki is located here: http://qt.gitorious.org/qt/pages/GitIntroductionWithQt If you have already performed the grafting and you don't see any history beyond this commit, try running "git log" with the "--follow" argument. Branched from the monolithic repo, Qt master branch, at commit 896db169ea224deb96c59ce8af800d019de63f12
24 lines
986 B
Plaintext
24 lines
986 B
Plaintext
|
|
for(source, SOURCES) {
|
|
contains(source,.*\\.mm?$) {
|
|
warning(Objective-C source \'$$source\' found in SOURCES but should be in OBJECTIVE_SOURCES)
|
|
SOURCES -= $$source
|
|
OBJECTIVE_SOURCES += $$source
|
|
}
|
|
}
|
|
|
|
isEmpty(QMAKE_OBJECTIVE_CC):QMAKE_OBJECTIVE_CC = $$QMAKE_CC
|
|
|
|
OBJECTIVE_C_OBJECTS_DIR = $$OBJECTS_DIR
|
|
isEmpty(OBJECTIVE_C_OBJECTS_DIR):OBJECTIVE_C_OBJECTS_DIR = .
|
|
isEmpty(QMAKE_EXT_OBJECTIVE_C):QMAKE_EXT_OBJECTIVE_C = .mm .m
|
|
|
|
objective_c.dependency_type = TYPE_C
|
|
objective_c.variables = QMAKE_OBJECTIVE_CFLAGS
|
|
objective_c.commands = $$QMAKE_OBJECTIVE_CC -c $(QMAKE_COMP_QMAKE_OBJECTIVE_CFLAGS) $(DEFINES) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
|
|
objective_c.output = $$OBJECTIVE_C_OBJECTS_DIR/${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
|
|
objective_c.input = OBJECTIVE_SOURCES
|
|
objective_c.name = Compile ${QMAKE_FILE_IN}
|
|
silent:objective_c.commands = @echo objective-c ${QMAKE_FILE_IN} && $$objective_c.commands
|
|
QMAKE_EXTRA_COMPILERS += objective_c
|