dbb9d96bdb
A common issue for our users is that they do not provide the path to their cross compiler or don't have it in their $PATH. Introduce a qmake testFunction to sanity check the presence of the compiler. Change-Id: I7d41db139d2a9c67334908b96e9f5e8f996426f6 Reviewed-by: Girish Ramakrishnan <girish.1.ramakrishnan@nokia.com> Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>
39 lines
991 B
Plaintext
39 lines
991 B
Plaintext
# Load generated qdevice.pri
|
|
exists($$_QMAKE_CACHE_) {
|
|
# set in default_pre, so it's the first place to check for qdevice.pri
|
|
DIR = $$fromfile($$_QMAKE_CACHE_, QT_BUILD_TREE)
|
|
!isEmpty(DIR):DEVICE_PRI = $$DIR/mkspecs/qdevice.pri
|
|
}
|
|
|
|
isEmpty(DEVICE_PRI) {
|
|
# OUTDIR environ is set by configure (arch detection) and compile.test
|
|
DIR = $$(OUTDIR)
|
|
!isEmpty(DIR):DEVICE_PRI = $$DIR/mkspecs/qdevice.pri
|
|
}
|
|
|
|
isEmpty(DEVICE_PRI) {
|
|
DIR = $$[QT_HOST_DATA]
|
|
!isEmpty(DIR):DEVICE_PRI = $$DIR/mkspecs/qdevice.pri
|
|
}
|
|
|
|
isEmpty(DEVICE_PRI) {
|
|
error(Could not locate qdevice.pri)
|
|
}
|
|
|
|
exists($$DEVICE_PRI):include($$DEVICE_PRI)
|
|
|
|
unset(DEVICE_PRI)
|
|
unset(DIR)
|
|
|
|
# Provide a function to be used by mkspecs
|
|
defineTest(deviceSanityCheckCompiler) {
|
|
# Check if the binary exists, e.g. with an absolute path
|
|
exists($$QMAKE_CXX):return()
|
|
|
|
# Check if the compiler is in the path
|
|
system("which $$QMAKE_CXX > /dev/null"):return()
|
|
|
|
error("Compiler $$QMAKE_CXX not found")
|
|
}
|
|
|