fb1b20eab3
CMakeLists.txt and .cmake files of significant size (more than 2 lines according to our check in tst_license.pl) now have the copyright and license header. Existing copyright statements remain intact Task-number: QTBUG-88621 Change-Id: I3b98cdc55ead806ec81ce09af9271f9b95af97fa Reviewed-by: Jörg Bornemann <joerg.bornemann@qt.io>
55 lines
1.6 KiB
CMake
55 lines
1.6 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0
|
|
|
|
#.rst:
|
|
# FindInterbase
|
|
# ---------
|
|
#
|
|
# Try to locate the Interbase client library.
|
|
# If found, this will define the following variables:
|
|
#
|
|
# ``Interbase_FOUND``
|
|
# True if the Interbase library is available
|
|
# ``Interbase_INCLUDE_DIR``
|
|
# The Interbase include directories
|
|
# ``Interbase_LIBRARY``
|
|
# The Interbase libraries for linking
|
|
#
|
|
# If ``Interbase_FOUND`` is TRUE, it will also define the following
|
|
# imported target:
|
|
#
|
|
# ``Interbase::Interbase``
|
|
# The Interbase client library
|
|
|
|
find_path(Interbase_INCLUDE_DIR
|
|
NAMES ibase.h
|
|
HINTS ${Interbase_INCLUDEDIR}
|
|
)
|
|
|
|
find_library(Interbase_LIBRARY
|
|
NAMES firebase_ms fbclient gds
|
|
HINTS ${Interbase_LIBDIR}
|
|
)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(Interbase DEFAULT_MSG Interbase_LIBRARY Interbase_INCLUDE_DIR)
|
|
|
|
if(Interbase_FOUND)
|
|
set(Interbase_INCLUDE_DIRS "${Interbase_INCLUDE_DIR}")
|
|
set(Interbase_LIBRARIES "${Interbase_LIBRARY}")
|
|
if(NOT TARGET Interbase::Interbase)
|
|
add_library(Interbase::Interbase UNKNOWN IMPORTED)
|
|
set_target_properties(Interbase::Interbase PROPERTIES
|
|
IMPORTED_LOCATION "${Interbase_LIBRARIES}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${Interbase_INCLUDE_DIRS};")
|
|
endif()
|
|
endif()
|
|
|
|
mark_as_advanced(Interbase_INCLUDE_DIR Interbase_LIBRARY)
|
|
|
|
include(FeatureSummary)
|
|
set_package_properties(Interbase PROPERTIES
|
|
URL "https://www.embarcadero.com/products/interbase"
|
|
DESCRIPTION "Interbase client library")
|
|
|