fb1b20eab3
CMakeLists.txt and .cmake files of significant size (more than 2 lines according to our check in tst_license.pl) now have the copyright and license header. Existing copyright statements remain intact Task-number: QTBUG-88621 Change-Id: I3b98cdc55ead806ec81ce09af9271f9b95af97fa Reviewed-by: Jörg Bornemann <joerg.bornemann@qt.io>
35 lines
1.5 KiB
CMake
35 lines
1.5 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0
|
|
|
|
# Enable compiler warnings by default. All compilers except MSVC support -Wall -Wextra
|
|
#
|
|
# You can disable the warnings for specific targets (for instance containing 3rd party code)
|
|
# by calling qt_disable_warnings(target). This will set the QT_COMPILE_OPTIONS_DISABLE_WARNINGS
|
|
# property checked below, and is equivalent to qmake's CONFIG += warn_off.
|
|
|
|
set(_qt_compiler_warning_flags_on "")
|
|
set(_qt_compiler_warning_flags_off "")
|
|
|
|
if (MSVC)
|
|
list(APPEND _qt_compiler_warning_flags_on /W3)
|
|
list(APPEND _qt_compiler_warning_flags_off -W0)
|
|
else()
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "GHS") # There is no -Wextra flag for GHS compiler.
|
|
list(APPEND _qt_compiler_warning_flags_on -Wall)
|
|
else()
|
|
list(APPEND _qt_compiler_warning_flags_on -Wall -Wextra)
|
|
endif()
|
|
list(APPEND _qt_compiler_warning_flags_off -w)
|
|
endif()
|
|
|
|
set(_qt_compiler_warning_flags_condition
|
|
"$<BOOL:$<TARGET_PROPERTY:QT_COMPILE_OPTIONS_DISABLE_WARNINGS>>")
|
|
set(_qt_compiler_warning_flags_genex
|
|
"$<IF:${_qt_compiler_warning_flags_condition},${_qt_compiler_warning_flags_off},${_qt_compiler_warning_flags_on}>")
|
|
|
|
# Need to replace semicolons so that the list is not wrongly expanded in the add_compile_options
|
|
# call.
|
|
string(REPLACE ";" "$<SEMICOLON>"
|
|
_qt_compiler_warning_flags_genex "${_qt_compiler_warning_flags_genex}")
|
|
add_compile_options(${_qt_compiler_warning_flags_genex})
|