90779d96ad
Commit 80dea664 broke .ui files with global includes that are not part
of the project, because we blindly added every file path that falls
out of 'uic -d' as dependency.
Introduce the extra compiler CONFIG flag dep_existing_only to bring
back the old behavior that ignores non-existent dependencies and set
it for uic.
Change-Id: I6eaa82817c932a98ebac6d08115a9815d4b9dd21
Fixes: QTBUG-78144
Reviewed-by: Kai Koehne <kai.koehne@qt.io>
21 lines
706 B
Plaintext
21 lines
706 B
Plaintext
qtPrepareTool(QMAKE_UIC, uic, _DEP)
|
|
|
|
isEmpty(UI_DIR):UI_DIR = .
|
|
isEmpty(QMAKE_MOD_UIC):QMAKE_MOD_UIC = ui_
|
|
|
|
uic.depends += $$QMAKE_UIC_EXE
|
|
uic.commands = $$QMAKE_UIC $$QMAKE_UIC_FLAGS ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
|
|
uic.depend_command = $$QMAKE_UIC_DEP -d ${QMAKE_FILE_IN}
|
|
uic.output = $$UI_DIR/$${QMAKE_MOD_UIC}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
uic.input = FORMS
|
|
uic.variable_out = GENERATED_FILES
|
|
uic.CONFIG += no_link target_predeps dep_lines dep_existing_only
|
|
uic.name = UIC ${QMAKE_FILE_IN}
|
|
silent:uic.commands = @echo uic ${QMAKE_FILE_IN} && $$uic.commands
|
|
QMAKE_EXTRA_COMPILERS += uic
|
|
INCREDIBUILD_XGE += uic
|
|
|
|
!isEmpty(FORMS) {
|
|
INCLUDEPATH += $$absolute_path($$UI_DIR, $$OUT_PWD)
|
|
}
|