5dcc36b15c
User applications are those that users run directly, whether it be for development or not. The executable binaries that the user does not usually run but is still required for proper functioning are called "program executables" in Autoconf and they are placed in libexec. This commit adds support for "program executables" in Qt by adding the -libexecdir option to the configures, the qmake variable QT_INSTALL_LIBEXECS (note the plural, to match all other properties), and QLibraryInfo::LibraryExecutables. At the time of this commit, the only expected "program executable" is the QtWebProcess, the WebKit2 helper process from QtWebKit. Change-Id: I66c3a3e0cf7f9d93b5f88f55f18e957faff608fc Reviewed-by: Lars Knoll <lars.knoll@digia.com>
40 lines
1.6 KiB
Plaintext
40 lines
1.6 KiB
Plaintext
QMAKE_QT_CONFIG = $$[QT_HOST_DATA/get]/mkspecs/qconfig.pri
|
|
!exists($$QMAKE_QT_CONFIG)|!include($$QMAKE_QT_CONFIG, "", true) {
|
|
debug(1, "Cannot load qconfig.pri!")
|
|
} else {
|
|
debug(1, "Loaded .qconfig.pri from ($$QMAKE_QT_CONFIG)")
|
|
QMAKE_MODULE_PATH = $$split($$list($$(QMAKEMODULES)), $$DIRLIST_SEPARATOR)
|
|
QMAKE_MODULE_PATH += $$QMAKEMODULES
|
|
QMAKE_MODULE_PATH += $$split($$list($$[QMAKEMODULES]), $$DIRLIST_SEPARATOR)
|
|
QMAKE_MODULE_PATH += $$replace($$list($$split($$list($$[QMAKE_MKSPECS]), $$DIRLIST_SEPARATOR)), \
|
|
\$, /modules)
|
|
QMAKE_MODULE_PATH = $$unique(QMAKE_MODULE_PATH)
|
|
QMAKE_MODULE_PATH = $$reverse(QMAKE_MODULE_PATH)
|
|
for(dir, QMAKE_MODULE_PATH) {
|
|
debug(1, "Loading modules from $${dir}")
|
|
for(mod, $$list($$files($$dir/qt_*.pri))) {
|
|
# For installed Qt these paths will be common for all modules
|
|
# For development these will vary per module, and syncqt will override the value in the
|
|
# qt_<module>.pri forwarding file
|
|
QT_MODULE_INCLUDE_BASE = $$[QT_INSTALL_HEADERS]
|
|
QT_MODULE_LIB_BASE = $$[QT_INSTALL_LIBS]
|
|
QT_MODULE_PLUGIN_BASE = $$[QT_INSTALL_PLUGINS]
|
|
QT_MODULE_LIBEXEC_BASE = $$[QT_INSTALL_LIBEXECS]
|
|
QT_MODULE_BIN_BASE = $$[QT_INSTALL_BINS]
|
|
QT_MODULE_IMPORT_BASE = $$[QT_INSTALL_IMPORTS]
|
|
QT_MODULE_QML_BASE = $$[QT_INSTALL_QML]
|
|
include($$mod)
|
|
}
|
|
}
|
|
unset(QT_MODULE_INCLUDE_BASE)
|
|
unset(QT_MODULE_LIB_BASE)
|
|
unset(QT_MODULE_PLUGIN_BASE)
|
|
unset(QT_MODULE_LIBEXEC_BASE)
|
|
unset(QT_MODULE_BIN_BASE)
|
|
unset(QT_MODULE_IMPORT_BASE)
|
|
unset(QT_MODULE_QML_BASE)
|
|
}
|
|
|
|
load(qt_functions)
|
|
|