600f2397b8
The new 'prepare_docs' CONFIG option triggers the documentation rules in default_post to generate two extra targets: prepare_docs and generate_docs. The prepare_docs stage runs qdoc with the -prepare option, which means qdoc will only generate index files, and the generate_docs stage will call qdoc with -generate, which reads the index files and generates the final output. The regular docs target will then run the prepare_docs target for all submodules before running the generate_docs target. This ensures that when generating the final output, qdoc has all the index files for all the other modules available, to be able to resolve cross-references between the various Qt modules. This patch needs a follow-up in qt5.git to add CONFIG+=prepare_docs, so that the root Qt5 build will be able to hook into this new behavior. Change-Id: I654d7f0d4d5a41d9be208e6d3a8923bf0194f9ad Reviewed-by: Jerome Pasion <jerome.pasion@digia.com>
99 lines
3.7 KiB
Plaintext
99 lines
3.7 KiB
Plaintext
contains(TEMPLATE, ".*(lib|app)"):CONFIG += have_target
|
|
|
|
!have_target:!force_qt: CONFIG -= qt
|
|
|
|
!shared:!dll:!static:!staticlib {
|
|
contains(QT_CONFIG, static): CONFIG += static
|
|
else: CONFIG += shared
|
|
}
|
|
|
|
QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
|
|
!isEmpty(QT_BREAKPAD_ROOT_PATH): \ # quick test first whether requested ...
|
|
!staticlib:!static:CONFIG(release, debug|release):have_target: \ # is it applicable?
|
|
!contains(TARGET, .*phony_target.*): \ # monster hack, you don't really see this here, right? ;)
|
|
system($$QT_BREAKPAD_ROOT_PATH/qtbreakpadsymbols --breakpad-exists) { # do we really have it?
|
|
CONFIG += breakpad force_debug_info
|
|
CONFIG -= no_debug_info separate_debug_info
|
|
}
|
|
|
|
force_debug_info {
|
|
QMAKE_CFLAGS_RELEASE = $$QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO
|
|
QMAKE_CXXFLAGS_RELEASE = $$QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO
|
|
QMAKE_LFLAGS_RELEASE = $$QMAKE_LFLAGS_RELEASE_WITH_DEBUGINFO
|
|
}
|
|
|
|
CONFIG(debug, debug|release):load(debug)
|
|
else:load(release)
|
|
debug_and_release:load(debug_and_release)
|
|
incredibuild_xge {
|
|
CONFIG -= incredibuild_xge
|
|
CONFIG = incredibuild_xge $$CONFIG
|
|
}
|
|
|
|
force_debug_info:win32 {
|
|
load(resolve_target)
|
|
QMAKE_CLEAN += $$replace(QMAKE_RESOLVED_TARGET, ...$, pdb) # for the debug case it is hardcoded in qmake
|
|
}
|
|
|
|
breakpad {
|
|
load(resolve_target)
|
|
DEBUGFILENAME = $$shell_quote($$shell_path($$QMAKE_RESOLVED_TARGET))
|
|
PROJECTPATH = $$shell_quote($$shell_path($$OUT_PWD))
|
|
|
|
!isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK = $$QMAKE_POST_LINK$$escape_expand(\\n\\t)
|
|
QMAKE_POST_LINK = $$QMAKE_POST_LINK$$quote($${QT_BREAKPAD_ROOT_PATH}$${QMAKE_DIR_SEP}qtbreakpadsymbols $$DEBUGFILENAME $$PROJECTPATH)
|
|
!isEmpty(QMAKE_STRIP):QMAKE_POST_LINK = $$QMAKE_POST_LINK$$escape_expand(\\n\\t)$$quote($$QMAKE_STRIP $$DEBUGFILENAME)
|
|
}
|
|
|
|
QMAKE_INCDIR += $$QMAKE_INCDIR_POST
|
|
QMAKE_LIBDIR += $$QMAKE_LIBDIR_POST
|
|
|
|
# Let every project have a standard GNU `check' target
|
|
!contains(QMAKE_EXTRA_TARGETS, check) {
|
|
contains(TEMPLATE, subdirs): \
|
|
prepareRecursiveTarget(check)
|
|
else: \
|
|
check.depends = first # `make check' implies build
|
|
QMAKE_EXTRA_TARGETS += check
|
|
}
|
|
|
|
!contains(QMAKE_EXTRA_TARGETS, docs) {
|
|
contains(TEMPLATE, subdirs) {
|
|
prepare_docs {
|
|
prepareRecursiveTarget(prepare_docs)
|
|
prepareRecursiveTarget(generate_docs)
|
|
docs.commands = $(MAKE) -f $(MAKEFILE) prepare_docs && $(MAKE) -f $(MAKEFILE) generate_docs
|
|
} else {
|
|
prepareRecursiveTarget(docs)
|
|
}
|
|
} else {
|
|
# apps and libs only generate docs if QMAKE_DOCS is set
|
|
!isEmpty(QMAKE_DOCS) {
|
|
!exists($$QMAKE_DOCS):error("Cannot find documentation specification file $$QMAKE_DOCS")
|
|
qtPrepareTool(QDOC, qdoc)
|
|
for(index, QMAKE_DOCS_INDEX):QDOC_INDEX += -indexdir $$index
|
|
!isEmpty(QMAKE_DOCS_OUTPUTDIR):QMAKE_DOCS_OPTIONS += -outputdir $$QMAKE_DOCS_OUTPUTDIR
|
|
!isEmpty(QMAKE_DOCS_INSTALLDIR):QMAKE_DOCS_OPTIONS += -installdir $$QMAKE_DOCS_INSTALLDIR
|
|
doc_command = $$QDOC $$QMAKE_DOCS_OPTIONS $$QDOC_INDEX $$QMAKE_DOCS
|
|
|
|
prepare_docs {
|
|
prepare_docs.commands += $$doc_command -prepare -no-link-errors
|
|
generate_docs.commands += $$doc_command -generate
|
|
docs.depends += generate_docs
|
|
} else {
|
|
docs.commands += $$doc_command
|
|
}
|
|
}
|
|
}
|
|
QMAKE_EXTRA_TARGETS += docs
|
|
prepare_docs: QMAKE_EXTRA_TARGETS += prepare_docs generate_docs
|
|
}
|
|
|
|
!contains(QMAKE_EXTRA_TARGETS, install_docs) {
|
|
contains(TEMPLATE, subdirs) {
|
|
prepareRecursiveTarget(install_docs)
|
|
prepareRecursiveTarget(uninstall_docs)
|
|
}
|
|
QMAKE_EXTRA_TARGETS += install_docs uninstall_docs
|
|
}
|