59985b3c29
the order of the arguments passed to addExclusiveBuilds() determines the
name of the CONFIG flag which actually enables the mode. that is
historically fixed to iphonesimulator_and_iphoneos and we cannot just
change the order.
to get around this, add a new "overload" of the function which allows
specifying the flag independently from the order of the builds, and make
use of it in ios' resolve_config.prf.
amends d2b4a789c.
Change-Id: Ia3fabea0c0c30beae680b57e75bdcdf35ef6503d
Reviewed-by: Jake Petroules <jake.petroules@qt.io>
43 lines
1.0 KiB
Plaintext
43 lines
1.0 KiB
Plaintext
|
|
defineTest(addExclusiveBuildsProper) {
|
|
!$$1:!fix_output_dirs: \
|
|
return(true)
|
|
|
|
for(build, 2) {
|
|
isEmpty($${build}.name) {
|
|
$${build}.name = $$title($$build)
|
|
export($${build}.name)
|
|
}
|
|
isEmpty($${build}.target) {
|
|
$${build}.target = $$lower($$build)
|
|
export($${build}.target)
|
|
}
|
|
isEmpty($${build}.dir_affix) {
|
|
$${build}.dir_affix = $$lower($$build)
|
|
export($${build}.dir_affix)
|
|
}
|
|
|
|
$${build}.exclusive = $$2
|
|
export($${build}.exclusive)
|
|
|
|
QMAKE_EXCLUSIVE_BUILDS += $$build
|
|
}
|
|
|
|
CONFIG *= exclusive_builds
|
|
export(CONFIG)
|
|
|
|
export(QMAKE_EXCLUSIVE_BUILDS)
|
|
return(true)
|
|
}
|
|
|
|
defineTest(addExclusiveBuilds) {
|
|
lessThan(ARGC, 2): \
|
|
error("addExclusiveBuilds() requires at least two arguments")
|
|
|
|
addExclusiveBuildsProper($$join(ARGS, _and_), $$ARGS)
|
|
}
|
|
|
|
# Default directories to process
|
|
QMAKE_DIR_REPLACE = OBJECTS_DIR MOC_DIR RCC_DIR PRECOMPILED_DIR QGLTF_DIR DESTDIR
|
|
QMAKE_DIR_REPLACE_SANE += QGLTF_DIR
|