a0d1b99609
Introduce PKG_CONFIG_SYSROOT_DIR and PKG_CONFIG_LIBDIR for cross-compilation environments Change-Id: I859d55f125b18d6bdef0f1dfaeb43721b85d22f5 Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>
25 lines
769 B
Plaintext
25 lines
769 B
Plaintext
PKG_CONFIG = $$pkgConfigExecutable()
|
|
|
|
for(PKGCONFIG_LIB, $$list($$unique(PKGCONFIG))) {
|
|
# don't proceed if the .pro asks for a package we don't have!
|
|
!packagesExist($$PKGCONFIG_LIB):error("Package $$PKGCONFIG_LIB not found")
|
|
|
|
PKGCONFIG_CFLAGS = $$system($$PKG_CONFIG --cflags $$PKGCONFIG_LIB)
|
|
|
|
PKGCONFIG_INCLUDEPATH = $$find(PKGCONFIG_CFLAGS, ^-I.*)
|
|
PKGCONFIG_INCLUDEPATH ~= s/^-I(.*)/\\1/g
|
|
|
|
PKGCONFIG_DEFINES = $$find(PKGCONFIG_CFLAGS, ^-D.*)
|
|
PKGCONFIG_DEFINES ~= s/^-D(.*)/\\1/g
|
|
|
|
PKGCONFIG_CFLAGS ~= s/^-[ID].*//g
|
|
|
|
INCLUDEPATH *= $$PKGCONFIG_INCLUDEPATH
|
|
DEFINES *= $$PKGCONFIG_DEFINES
|
|
|
|
QMAKE_CXXFLAGS += $$PKGCONFIG_CFLAGS
|
|
QMAKE_CFLAGS += $$PKGCONFIG_CFLAGS
|
|
LIBS += $$system($$PKG_CONFIG --libs $$PKGCONFIG_LIB)
|
|
}
|
|
|