4a58853aea
qpa header files were not installed under qpa/. Change-Id: I243c3a7e83a342f7485791a1a29b65c9a8f25d6b Reviewed-by: Marius Storm-Olsen <marius.storm-olsen@nokia.com>
42 lines
1.2 KiB
Plaintext
42 lines
1.2 KiB
Plaintext
#always install the library
|
|
win32 {
|
|
dlltarget.path=$$[QT_INSTALL_BINS]
|
|
INSTALLS += dlltarget
|
|
}
|
|
target.path=$$[QT_INSTALL_LIBS]
|
|
INSTALLS += target
|
|
|
|
#headers
|
|
qt_install_headers {
|
|
INSTALL_HEADERS = $$SYNCQT.HEADER_FILES
|
|
equals(TARGET, QtCore) {
|
|
#headers created by configure
|
|
INSTALL_HEADERS *= $$QT_BUILD_TREE/src/corelib/global/qconfig.h
|
|
}
|
|
|
|
equals(TARGET, phonon) {
|
|
class_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
|
|
} else {
|
|
flat_headers.files = $$INSTALL_HEADERS
|
|
flat_headers.path = $$[QT_INSTALL_HEADERS]/Qt
|
|
INSTALLS += flat_headers
|
|
|
|
class_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
|
|
}
|
|
class_headers.files = $$SYNCQT.HEADER_CLASSES
|
|
INSTALLS += class_headers
|
|
|
|
targ_headers.files = $$INSTALL_HEADERS
|
|
targ_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
|
|
INSTALLS += targ_headers
|
|
|
|
private_headers.files = $$SYNCQT.PRIVATE_HEADER_FILES
|
|
private_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET/$$eval(QT.$${MODULE}.VERSION)/$$TARGET/private
|
|
INSTALLS += private_headers
|
|
|
|
qpa_headers.files = $$SYNCQT.QPA_HEADER_FILES
|
|
qpa_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET/$$eval(QT.$${MODULE}.VERSION)/$$TARGET/qpa
|
|
INSTALLS += qpa_headers
|
|
}
|
|
|