82bf3bd775
Since modules cannot rely on QtCore having a build directory, nor can they build the applications directly into $$[QT_INSTALL_BINS] each module needs their own bin/. Add this path to each module's pri file, so others can use their applications
31 lines
1.5 KiB
Plaintext
31 lines
1.5 KiB
Plaintext
# This file is loaded by the mkspecs, before .qmake.cache has been loaded.
|
|
# Consequently, we have to do some stunts to get values out of the cache.
|
|
|
|
exists($$_QMAKE_CACHE_):QMAKE_QT_CONFIG = $$fromfile($$_QMAKE_CACHE_, QMAKE_QT_CONFIG)
|
|
isEmpty(QMAKE_QT_CONFIG)|!exists($$QMAKE_QT_CONFIG) {
|
|
!isEmpty(QT_BUILD_TREE):QMAKE_QT_CONFIG = $$QT_BUILD_TREE/mkspecs/qconfig.pri
|
|
else:exists($$_QMAKE_CACHE_):infile($$_QMAKE_CACHE_, QT_BUILD_TREE):QMAKE_QT_CONFIG = $$fromfile($$_QMAKE_CACHE_, QT_BUILD_TREE)/mkspecs/qconfig.pri
|
|
else:exists($$[QT_INSTALL_DATA]/mkspecs/qconfig.pri):QMAKE_QT_CONFIG = $$[QT_INSTALL_DATA]/mkspecs/qconfig.pri
|
|
}
|
|
!exists($$QMAKE_QT_CONFIG)|!include($$QMAKE_QT_CONFIG, "", true) {
|
|
debug(1, "Cannot load qconfig.pri!")
|
|
} else {
|
|
debug(1, "Loaded .qconfig.pri from ($$QMAKE_QT_CONFIG)")
|
|
for(dir, $$list($$unique($$list($$dirname(QMAKE_QT_CONFIG) \
|
|
$$split($$list($$[QMAKE_MKSPECS]), $$DIRLIST_SEPARATOR))))) {
|
|
debug(1, "Loading modules from $${dir}")
|
|
for(mod, $$list($$files($$dir/modules/qt_*.pri))) {
|
|
# For installed Qt these paths will be common for all modules
|
|
# For development these will vary per module, and syncqt will override the value in the
|
|
# qt_<module>.pri forwarding file
|
|
QT_MODULE_INCLUDE_BASE = $$[QT_INSTALL_HEADERS]
|
|
QT_MODULE_LIB_BASE = $$[QT_INSTALL_LIBS]
|
|
QT_MODULE_BIN_BASE = $$[QT_INSTALL_BINS]
|
|
include($$mod)
|
|
}
|
|
}
|
|
}
|
|
|
|
load(qt_functions)
|
|
|