bb793f8b50
modules which demand it (i.e., qtwebkit) need forwarding pris, etc., even when not making a -prefix build. Change-Id: Id405be8763e94cc074854f799bd785e9cdf62e8e Reviewed-by: Tor Arne Vestbø <tor.arne.vestbo@digia.com> Reviewed-by: Andras Becsi <andras.becsi@digia.com> Reviewed-by: Joerg Bornemann <joerg.bornemann@digia.com> Reviewed-by: Simon Hausmann <simon.hausmann@digia.com>
50 lines
1.3 KiB
Plaintext
50 lines
1.3 KiB
Plaintext
#
|
|
# W A R N I N G
|
|
# -------------
|
|
#
|
|
# This file is not part of the Qt API. It exists purely as an
|
|
# implementation detail. It may change from version to version
|
|
# without notice, or even be removed.
|
|
#
|
|
# We mean it.
|
|
#
|
|
|
|
equals(TEMPLATE, app): TEMPLATE = aux
|
|
|
|
isEmpty(TARGETPATH): error("Must set TARGETPATH (QML import name)")
|
|
|
|
fq_qml_files = $$_PRO_FILE_PWD_/qmldir
|
|
|
|
for(qmlf, QML_FILES): fq_qml_files += $$absolute_path($$qmlf, $$_PRO_FILE_PWD_)
|
|
|
|
# Only for Qt Creator's project view
|
|
OTHER_FILES += $$fq_qml_files
|
|
|
|
qml1_target: \
|
|
instbase = $$[QT_INSTALL_IMPORTS]
|
|
else: \
|
|
instbase = $$[QT_INSTALL_QML]
|
|
|
|
!force_independent {
|
|
# These bizarre rules copy the files to the qtbase build directory
|
|
|
|
defineReplace(qmlModStripSrcDir) {
|
|
return($$relative_path($$1, $$_PRO_FILE_PWD_))
|
|
}
|
|
|
|
qmlfiles2build.input = fq_qml_files
|
|
qmlfiles2build.output = $$instbase/$$TARGETPATH/${QMAKE_FUNC_FILE_IN_qmlModStripSrcDir}
|
|
!contains(TEMPLATE, vc.*): qmlfiles2build.variable_out = PRE_TARGETDEPS
|
|
qmlfiles2build.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
|
|
qmlfiles2build.name = COPY ${QMAKE_FILE_IN}
|
|
qmlfiles2build.CONFIG = no_link no_clean
|
|
|
|
QMAKE_EXTRA_COMPILERS += qmlfiles2build
|
|
}
|
|
|
|
# Install rules
|
|
qmldir.base = $$_PRO_FILE_PWD_
|
|
qmldir.files = $$fq_qml_files
|
|
qmldir.path = $$instbase/$$TARGETPATH
|
|
INSTALLS += qmldir
|