fda41c1857
the idea is that "tools" actually means "graphical applications". that means that all bootstrapped/build tools are consistently built, regardless of their location in the source tree. non-bootstrapped non-graphical tools are a bit of a grey area. it's going to be decided on a case-by-case basis. Change-Id: I28b959b7e659d8aa86cf6769ab6d2689c855ec6b Reviewed-by: Joerg Bornemann <joerg.bornemann@digia.com>
69 lines
2.0 KiB
Plaintext
69 lines
2.0 KiB
Plaintext
#
|
|
# W A R N I N G
|
|
# -------------
|
|
#
|
|
# This file is not part of the Qt API. It exists purely as an
|
|
# implementation detail. It may change from version to version
|
|
# without notice, or even be removed.
|
|
#
|
|
# We mean it.
|
|
#
|
|
|
|
!contains(QMAKE_INTERNAL_INCLUDED_FILES, .*qmodule\\.pri) {
|
|
QMAKE_QT_MODULE = $$[QT_HOST_DATA/get]/mkspecs/qmodule.pri
|
|
!exists($$QMAKE_QT_MODULE)|!include($$QMAKE_QT_MODULE, "", true) {
|
|
error("Cannot load qmodule.pri!")
|
|
} else {
|
|
debug(1, "Loaded qmodule.pri from ($$QMAKE_QT_MODULE)")
|
|
}
|
|
} else {
|
|
debug(1, "Not loading qmodule.pri twice")
|
|
}
|
|
|
|
# force_independent can be set externally. prefix_build not.
|
|
!exists($$[QT_HOST_DATA]/.qmake.cache): \
|
|
CONFIG += prefix_build force_independent
|
|
|
|
!build_pass:!isEmpty(_QMAKE_SUPER_CACHE_):force_independent {
|
|
# When doing a -prefix build of top-level qt5/qt.pro, we need to announce
|
|
# this repo's module pris' location to the other repos.
|
|
isEmpty(MODULE_QMAKE_OUTDIR): MODULE_QMAKE_OUTDIR = $$shadowed($$dirname(_QMAKE_CONF_))
|
|
modpath = $$MODULE_QMAKE_OUTDIR/mkspecs/modules
|
|
!contains(QMAKEMODULES, $$modpath): \
|
|
cache(QMAKEMODULES, add super, modpath)
|
|
unset(modpath)
|
|
}
|
|
|
|
mac {
|
|
!isEmpty(QMAKE_RPATHDIR){
|
|
CONFIG += absolute_library_soname
|
|
}
|
|
}
|
|
|
|
cross_compile: \
|
|
CONFIG += force_bootstrap
|
|
|
|
CONFIG += \
|
|
create_prl link_prl \
|
|
prepare_docs qt_docs_targets \
|
|
no_private_qt_headers_warning QTDIR_build \
|
|
# Qt modules get compiled without exceptions enabled by default.
|
|
# However, testcases should be still built with exceptions.
|
|
exceptions_off testcase_exceptions
|
|
|
|
|
|
defineTest(qtBuildPart) {
|
|
bp = $$eval($$upper($$section(_QMAKE_CONF_, /, -2, -2))_BUILD_PARTS)
|
|
isEmpty(bp): bp = $$QT_BUILD_PARTS
|
|
contains(bp, $$1): return(true)
|
|
return(false)
|
|
}
|
|
|
|
defineTest(qtNomakeTools) {
|
|
qtBuildPart(tools): return()
|
|
for (d, 1) {
|
|
$${d}.CONFIG += no_default_target no_default_install
|
|
export($${d}.CONFIG)
|
|
}
|
|
}
|