3c23317552
If Vulkan headers are present on the system when qtbase is configured, QtGui and QtOpenGL should be compiled with Vulkan support. If a user project uses a Qt built with Vulkan support, but their system is missing Vulkan headers, the project configuration needs to succeed. The project will get compilation errors if it uses Vulkan headers, but that's intended. This use case was broken when fixing Vulkan to be found when building Qt for Android. Fix the regression with a combination of things 1) Mark the WrapVulkanHeaders package as optional (already the case) 2) Use the include directories directly when compiling Gui and OpenGL 3) Propagate WrapVulkanHeaders::WrapVulkanHeaders link requirement to consumers only if the target exists. It won't exist if Vulkan include dirs are not found This also requires some changes in pri and prl file generation. For prl file generation, we don't want to link to the WrapVulkanHeaders target, so we filter out all dependencies that use TARGET_NAME_IF_EXISTS for anything that calls __qt_internal_walk_libs which includes qt_collect_libs. For pri files, we make sure to generate a uses=vulkan/nolink clause by inspecting a new _qt_is_nolink_target property on the target. We also don't add include dirs to the pri file if the new _qt_skip_include_dir_for_pri property is set. This is intended for Vulkan, because there is separate qmake logic to try and find the include dirs when configuring a user project. As a drive-by, fix nolink handling for WrapOpenSSLHeaders. Amendsbb25536a3dAmends7b9904849fPick-to: 6.2 Fixes: QTBUG-95391 Change-Id: I21e2f4be5c386f9e40033e4691f4786a91ba0e2d Reviewed-by: Qt CI Bot <qt_ci_bot@qt-project.org> Reviewed-by: Alexey Edelev <alexey.edelev@qt.io> Reviewed-by: Alexandru Croitor <alexandru.croitor@qt.io>
43 lines
1.5 KiB
CMake
43 lines
1.5 KiB
CMake
# We can't create the same interface imported target multiple times, CMake will complain if we do
|
|
# that. This can happen if the find_package call is done in multiple different subdirectories.
|
|
if(TARGET WrapOpenSSLHeaders::WrapOpenSSLHeaders)
|
|
set(WrapOpenSSLHeaders_FOUND ON)
|
|
return()
|
|
endif()
|
|
|
|
set(WrapOpenSSLHeaders_FOUND OFF)
|
|
|
|
# When cross-compiling (to Android for example), we need to add the OPENSSL_ROOT_DIR as a root path,
|
|
# otherwise the value would just be appended to the sysroot, which is wrong.
|
|
if(OPENSSL_ROOT_DIR)
|
|
set(__find_wrap_openssl_headers_backup_root_dir "${CMAKE_FIND_ROOT_PATH}")
|
|
list(APPEND CMAKE_FIND_ROOT_PATH "${OPENSSL_ROOT_DIR}")
|
|
endif()
|
|
|
|
find_package(OpenSSL ${WrapOpenSSLHeaders_FIND_VERSION})
|
|
|
|
if(OPENSSL_ROOT_DIR)
|
|
set(CMAKE_FIND_ROOT_PATH "${__find_wrap_openssl_headers_backup_root_dir}")
|
|
endif()
|
|
|
|
# We are interested only in include headers. The libraries might be missing, so we can't check the
|
|
# _FOUND variable.
|
|
if(OPENSSL_INCLUDE_DIR)
|
|
set(WrapOpenSSLHeaders_FOUND ON)
|
|
|
|
add_library(WrapOpenSSLHeaders::WrapOpenSSLHeaders INTERFACE IMPORTED)
|
|
target_include_directories(WrapOpenSSLHeaders::WrapOpenSSLHeaders INTERFACE
|
|
${OPENSSL_INCLUDE_DIR})
|
|
|
|
set_target_properties(WrapOpenSSLHeaders::WrapOpenSSLHeaders PROPERTIES
|
|
_qt_is_nolink_target TRUE)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WrapOpenSSLHeaders
|
|
REQUIRED_VARS
|
|
OPENSSL_INCLUDE_DIR
|
|
VERSION_VAR
|
|
OPENSSL_VERSION
|
|
)
|