8d406e988c
The beagleboard and Archos gen8 tablets are built on the same hardware and OpenEmbedded platform build system. The makespecs enable OpenGL/ES2 support and EGLFS as the default platform. Reviewed-by: Girish Ramakrishnan <girish.1.ramakrishnan@nokia.com> Reviewed-by: Donald Carr <donald.carr@nokia.com> Change-Id: I04938676f82f9136efd662ff3ede16221eadf275 Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com> Reviewed-by: Girish Ramakrishnan <girish.1.ramakrishnan@nokia.com>
60 lines
1.8 KiB
Plaintext
60 lines
1.8 KiB
Plaintext
#
|
|
# qmake configuration for the BeagleBoard and BeagleBoard xM boards
|
|
# http://beagleboard.org/
|
|
|
|
MAKEFILE_GENERATOR = UNIX
|
|
TARGET_PLATFORM = unix
|
|
TEMPLATE = app
|
|
CONFIG += qt warn_on release incremental link_prl gdb_dwarf_index
|
|
QT += core gui
|
|
QMAKE_INCREMENTAL_STYLE = sublib
|
|
|
|
include(../../common/linux.conf)
|
|
include(../../common/gcc-base-unix.conf)
|
|
include(../../common/g++-unix.conf)
|
|
|
|
load(device_config)
|
|
|
|
QT_QPA_DEFAULT_PLATFORM = eglfs
|
|
|
|
isEmpty(CROSS_COMPILE) {
|
|
CROSS_COMPILE = arm-angstrom-linux-gnueabi-
|
|
}
|
|
|
|
# modifications to g++.conf
|
|
QMAKE_CC = $${CROSS_COMPILE}gcc
|
|
QMAKE_CXX = $${CROSS_COMPILE}g++
|
|
QMAKE_LINK = $${QMAKE_CXX}
|
|
QMAKE_LINK_SHLIB = $${QMAKE_CXX}
|
|
|
|
# modifications to linux.conf
|
|
QMAKE_AR = $${CROSS_COMPILE}ar cqs
|
|
QMAKE_OBJCOPY = $${CROSS_COMPILE}objcopy
|
|
QMAKE_STRIP = $${CROSS_COMPILE}strip
|
|
|
|
COMPILER_FLAGS = -march=armv7-a -mtune=cortex-a8 -mfpu=neon -mfloat-abi=softfp
|
|
|
|
#modifications to gcc-base.conf
|
|
QMAKE_CFLAGS += $${COMPILER_FLAGS}
|
|
QMAKE_CXXFLAGS += $${COMPILER_FLAGS}
|
|
QMAKE_CXXFLAGS_RELEASE += -O3
|
|
|
|
QMAKE_LIBS += -lrt -lpthread -ldl
|
|
|
|
# Extra stuff (OpenGL, DirectFB, ...)
|
|
QMAKE_INCDIR_EGL = $$[QT_SYSROOT]/usr/include
|
|
QMAKE_LIBDIR_EGL = $$[QT_SYSROOT]/usr/lib
|
|
QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}
|
|
QMAKE_LIBDIR_OPENGL_ES2 = $${QMAKE_LIBDIR_EGL}
|
|
QMAKE_INCDIR_OPENVG = $${QMAKE_INCDIR_EGL}
|
|
QMAKE_LIBDIR_OPENVG = $${QMAKE_LIBDIR_EGL}
|
|
|
|
QMAKE_LIBS_EGL = -lEGL -lIMGegl -lsrv_um
|
|
QMAKE_LIBS_OPENGL_ES2 = -lGLESv2 $${QMAKE_LIBS_EGL}
|
|
QMAKE_LIBS_OPENVG = -lOpenVG $${QMAKE_LIBS_EGL}
|
|
|
|
# Sanity check
|
|
deviceSanityCheckCompiler()
|
|
|
|
load(qt_config)
|