c04cf29b78
qtAddToolEnv() (via qtPrepareTool()) does not write the tool wrapper scripts during build passes, while qt_docs.prf (which calls it for qdoc and qhelpgenerator) was loaded only during build passes. the consequence was that the makefiles tried calling non-existent scripts. amends 5418d77a1, sort of. Change-Id: I64ab573495ca339be4c7b5e8c6848b298b6cb605 Reviewed-by: Joerg Bornemann <joerg.bornemann@theqtcompany.com>
46 lines
1.3 KiB
Plaintext
46 lines
1.3 KiB
Plaintext
#
|
|
# W A R N I N G
|
|
# -------------
|
|
#
|
|
# This file is not part of the Qt API. It exists purely as an
|
|
# implementation detail. It may change from version to version
|
|
# without notice, or even be removed.
|
|
#
|
|
# We mean it.
|
|
#
|
|
|
|
DOC_TARGETS = \
|
|
install_html_docs uninstall_html_docs \
|
|
install_qch_docs uninstall_qch_docs \
|
|
install_docs uninstall_docs \
|
|
qch_docs
|
|
|
|
prepare_docs {
|
|
DOC_TARGETS += prepare_docs generate_docs
|
|
html_docs.commands = $(MAKE) -f $(MAKEFILE) prepare_docs && $(MAKE) -f $(MAKEFILE) generate_docs
|
|
QMAKE_EXTRA_TARGETS += html_docs
|
|
} else {
|
|
DOC_TARGETS += html_docs
|
|
}
|
|
|
|
docs.commands = $(MAKE) -f $(MAKEFILE) html_docs && $(MAKE) -f $(MAKEFILE) qch_docs
|
|
QMAKE_EXTRA_TARGETS += docs
|
|
|
|
contains(TEMPLATE, subdirs) {
|
|
for(inst, DOC_TARGETS): \
|
|
prepareRecursiveTarget($$inst)
|
|
} else {
|
|
debug_and_release:!build_pass {
|
|
sub = $$first(BUILDS)
|
|
for(inst, DOC_TARGETS) {
|
|
$${inst}.CONFIG = recursive
|
|
$${inst}.recurse = $$sub
|
|
}
|
|
}
|
|
# Apps and libs request docs creation by setting QMAKE_DOCS.
|
|
# This is a backwards compat hack - technically, the modules which need it
|
|
# are supposed to load(qt_docs) themselves.
|
|
!isEmpty(QMAKE_DOCS): load(qt_docs)
|
|
}
|
|
QMAKE_EXTRA_TARGETS += $$DOC_TARGETS
|