523c90810d
the variable can contain a complex command which would make a mess of the makefile. also, the tool doesn't change all that often, so it's not particularly useful to depend on the binary. Change-Id: I965d6555cb22bd6d5306b324f5cad0d747128e99 Reviewed-by: Joerg Bornemann <joerg.bornemann@digia.com>
36 lines
933 B
Plaintext
36 lines
933 B
Plaintext
!debug_and_release|build_pass {
|
|
CONFIG(debug, debug|release) {
|
|
LIBS += -lQAxContainerd
|
|
} else {
|
|
LIBS += -lQAxContainer
|
|
}
|
|
} else {
|
|
LIBS += -lQAxContainer
|
|
}
|
|
|
|
QMAKE_LIBDIR += $$QT.activeqt.libs
|
|
INCLUDEPATH += $$QT.activeqt.includes
|
|
QMAKE_LIBS += $$QMAKE_LIBS_GUI
|
|
|
|
qtPrepareTool(QMAKE_DUMPCPP, dumpcpp)
|
|
|
|
dumpcpp_decl.commands = $$QMAKE_DUMPCPP ${QMAKE_FILE_IN} -o ${QMAKE_FILE_BASE}
|
|
qaxcontainer_compat: dumpcpp_decl.commands += -compat
|
|
dumpcpp_decl.output = ${QMAKE_FILE_BASE}.h
|
|
dumpcpp_decl.input = TYPELIBS
|
|
dumpcpp_decl.variable_out = HEADERS
|
|
dumpcpp_decl.name = DUMP
|
|
dumpcpp_decl.CONFIG += no_link
|
|
|
|
QMAKE_EXTRA_COMPILERS += dumpcpp_decl
|
|
|
|
|
|
dumpcpp_impl.commands = $$QMAKE_DUMPCPP -donothing
|
|
dumpcpp_impl.output = ${QMAKE_FILE_BASE}.cpp
|
|
dumpcpp_impl.input = TYPELIBS
|
|
dumpcpp_impl.variable_out = SOURCES
|
|
dumpcpp_impl.name = CPP
|
|
dumpcpp_impl.depends = ${QMAKE_FILE_BASE}.h
|
|
|
|
QMAKE_EXTRA_COMPILERS += dumpcpp_impl
|