aa17350eb6
The Qt buildsystem is creating the config files for it even when it is not building QtDBus, so Qt5DBus_FOUND = True. Re-enable the CI testing on mac with this change. Task-number: QTBUG-25522 Change-Id: I5d2690d17fde6c5aabcbdd3e2eef9f0846edd97d Reviewed-by: Alexander Neundorf <neundorf@kde.org> Reviewed-by: Rohan McGovern <rohan.mcgovern@nokia.com>
55 lines
1.8 KiB
Prolog
55 lines
1.8 KiB
Prolog
|
|
CMAKE_VERSION = $$system(cmake --version)
|
|
|
|
# Cause make to do nothing.
|
|
TEMPLATE = subdirs
|
|
|
|
check.commands =
|
|
isEmpty(CMAKE_VERSION) {
|
|
message("cmake executable not found. Not running CMake unit tests")
|
|
} else {
|
|
CTEST_VERSION = $$system(ctest --version)
|
|
isEmpty(CTEST_VERSION) {
|
|
message("ctest executable not found. Not running CMake unit tests")
|
|
} else {
|
|
CMAKE_VERSION = $$last(CMAKE_VERSION)
|
|
CMAKE_VERSION_MAJOR = $$section(CMAKE_VERSION, ., 0, 0)
|
|
CMAKE_VERSION_MINOR = $$section(CMAKE_VERSION, ., 1, 1)
|
|
CMAKE_VERSION_PATCH = $$section(CMAKE_VERSION, ., 2, 2)
|
|
|
|
VERSION_OK =
|
|
greaterThan(CMAKE_VERSION_MAJOR, 2) {
|
|
VERSION_OK = 1
|
|
} else:greaterThan(CMAKE_VERSION_MAJOR, 1):greaterThan(CMAKE_VERSION_MINOR, 8) {
|
|
VERSION_OK = 1
|
|
} else:greaterThan(CMAKE_VERSION_MAJOR, 1):greaterThan(CMAKE_VERSION_MINOR, 7):greaterThan(CMAKE_VERSION_PATCH, 2) {
|
|
VERSION_OK = 1
|
|
}
|
|
|
|
isEmpty(VERSION_OK) {
|
|
message("cmake $$CMAKE_VERSION is too old for this test.")
|
|
} else {
|
|
SET = set
|
|
equals(QMAKE_DIR_SEP, "/"):SET = export
|
|
|
|
CMAKE_BUILD_TYPE = Debug
|
|
CONFIG(release, debug|release):CMAKE_BUILD_TYPE = Release
|
|
|
|
BUILD_DIR = $$replace($$list($$OUT_PWD/build), /, $$QMAKE_DIR_SEP)
|
|
|
|
check.commands = \
|
|
cd . && $$SET CMAKE_PREFIX_PATH=$$[QT_INSTALL_PREFIX] && \
|
|
$(MKDIR) $$BUILD_DIR && cd $$BUILD_DIR && \
|
|
cmake $$_PRO_FILE_PWD_ -DCMAKE_BUILD_TYPE=$${CMAKE_BUILD_TYPE} && \
|
|
$(TESTRUNNER) ctest --output-on-failure
|
|
|
|
}
|
|
}
|
|
}
|
|
|
|
insignificant_test:!isEmpty(check.commands) {
|
|
check.commands = -$${check.commands}
|
|
}
|
|
|
|
QMAKE_EXTRA_TARGETS *= check
|