AuroraMiddleware/qt5base-lts
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity
ad5a65b6a2
qt5base-lts/qmake/qmake.pro
Giuseppe D'Angelo 14090760a8 Long Live QMap as a refcounted std::map! 
... and QMultiMap as std::multimap.

Just use the implementation from the STL; we can't really claim that
our code is much better than STL's, or does things any differently
(de facto they're both red-black trees).

Decouple QMultiMap from QMap, by making it NOT inherit from
QMap any longer. This completes the deprecation started in 5.15:
QMap now does not store duplicated keys any more.

Something to establish is where to put the
QExplictlySharedDataPointer replcement that is in there as an
ad-hoc solution. There's a number of patches in-flight by Marc
that try to introduce the same (or very similar) functionality.

Miscellanea changes to the Q(Multi)Map code itself:

* consistently use size_type instead of int;
* pass iterators by value;
* drop QT_STRICT_ITERATORS;
* iterators implictly convert to const_iterators, and APIs
  take const_iterators;
* iterators are just bidirectional and not random access;
* added noexcept where it makes sense;
* "inline" dropped (churn);
* qMapLessThanKey dropped (undocumented, 0 hits in Qt, 1 hit in KDE);
* operator== on Q(Multi)Map requires operator== on the key type
  (we're checking for equality, not equivalence!).

Very few breakages occur in qtbase.

[ChangeLog][Potentially Source-Incompatible Changes] QMap does not
support multiple equivalent keys any more. Any related functionality
has been removed from QMap, following the deprecation that happened
in Qt 5.15. Use QMultiMap for this use case.

[ChangeLog][Potentially Source-Incompatible Changes] QMap and
QMultiMap iterators random-access API have been removed. Note that
the iterators have always been just bidirectional; moving
an iterator by N positions can still be achieved using std::next
or std::advance, at the same cost as before (O(N)).

[ChangeLog][Potentially Source-Incompatible Changes] QMultiMap does
not inherit from QMap any more. Amongst other things, this means
that iterators on a QMultiMap now belong to the QMultiMap class
(and not to the QMap class); new Java iterators have been added.

Change-Id: I5a0fe9b020f92c21b37065a1defff783b5d2b7a9
Reviewed-by: Thiago Macieira <thiago.macieira@intel.com>
Reviewed-by: Lars Knoll <lars.knoll@qt.io>
2020-08-06 19:15:39 +02:00

262 lines
6.2 KiB
Prolog
Raw Blame History

# This project is not actually used to build qmake, but to support development
# with Qt Creator. The real build system is made up by the Makefile templates
# and the configures.
option(host_build)
CONFIG += cmdline
CONFIG -= qt
DEFINES += \
PROEVALUATOR_FULL \
QT_BOOTSTRAPPED \
QT_BUILD_QMAKE \
QT_USE_QSTRINGBUILDER \
QT_NO_FOREACH \
$$shell_quote(QT_VERSION_STR=\"$$QT_VERSION\") \
QT_VERSION_MAJOR=$$QT_MAJOR_VERSION \
QT_VERSION_MINOR=$$QT_MINOR_VERSION \
QT_VERSION_PATCH=$$QT_PATCH_VERSION \
PCRE2_DISABLE_JIT
win32: DEFINES += \
UNICODE \
_ENABLE_EXTENDED_ALIGNED_STORAGE \
_CRT_SECURE_NO_WARNINGS _SCL_SECURE_NO_WARNINGS
# qmake code
PRECOMPILED_HEADER = qmake_pch.h
INCLUDEPATH += \
. \
library \
generators \
generators/unix \
generators/win32 \
generators/mac \
../src/3rdparty/tinycbor/src
SOURCES += \
main.cpp \
meta.cpp \
option.cpp \
project.cpp \
property.cpp \
library/ioutils.cpp \
library/proitems.cpp \
library/qmakebuiltins.cpp \
library/qmakeevaluator.cpp \
library/qmakeglobals.cpp \
library/qmakeparser.cpp \
library/qmakevfs.cpp \
generators/makefile.cpp \
generators/makefiledeps.cpp \
generators/metamakefile.cpp \
generators/projectgenerator.cpp \
generators/xmloutput.cpp \
generators/mac/pbuilder_pbx.cpp \
generators/unix/unixmake.cpp \
generators/unix/unixmake2.cpp \
generators/win32/mingw_make.cpp \
generators/win32/msbuild_objectmodel.cpp \
generators/win32/msvc_nmake.cpp \
generators/win32/msvc_objectmodel.cpp \
generators/win32/msvc_vcproj.cpp \
generators/win32/msvc_vcxproj.cpp \
generators/win32/winmakefile.cpp
HEADERS += \
cachekeys.h \
meta.h \
option.h \
project.h \
property.h \
library/ioutils.h \
library/proitems.h \
library/qmake_global.h \
library/qmakeevaluator.h \
library/qmakeevaluator_p.h \
library/qmakeglobals.h \
library/qmakeparser.h \
library/qmakevfs.h \
generators/makefile.h \
generators/makefiledeps.h \
generators/metamakefile.h \
generators/projectgenerator.h \
generators/xmloutput.h \
generators/mac/pbuilder_pbx.h \
generators/unix/unixmake.h \
generators/win32/mingw_make.h \
generators/win32/msbuild_objectmodel.h \
generators/win32/msvc_nmake.h \
generators/win32/msvc_objectmodel.h \
generators/win32/msvc_vcproj.h \
generators/win32/msvc_vcxproj.h \
generators/win32/winmakefile.h
# qt code
bp = $$shadowed(..)
INCLUDEPATH += \
$$bp/include $$bp/include/QtCore \
$$bp/include/QtCore/$$QT_VERSION $$bp/include/QtCore/$$QT_VERSION/QtCore \
$$bp/src/corelib/global
VPATH += \
../src/corelib/global \
../src/corelib/text \
../src/corelib/tools \
../src/corelib/kernel \
../src/corelib/plugin \
../src/corelib/io \
../src/corelib/time \
../src/corelib/serialization
SOURCES += \
qabstractfileengine.cpp \
qarraydata.cpp \
qbitarray.cpp \
qbuffer.cpp \
qbytearray.cpp \
qbytearraymatcher.cpp \
qcalendar.cpp \
qcborstreamwriter.cpp \
qcborvalue.cpp \
qcryptographichash.cpp \
qdatetime.cpp \
qdir.cpp \
qdiriterator.cpp \
qfile.cpp \
qfiledevice.cpp \
qfileinfo.cpp \
qfilesystemengine.cpp \
qfilesystementry.cpp \
qfsfileengine.cpp \
qfsfileengine_iterator.cpp \
qglobal.cpp \
qgregoriancalendar.cpp \
qhash.cpp \
qiodevice.cpp \
qjsonarray.cpp \
qjsoncbor.cpp \
qjsondocument.cpp \
qjsonobject.cpp \
qjsonparser.cpp \
qjsonvalue.cpp \
qlibraryinfo.cpp \
qlist.cpp \
qlocale.cpp \
qlocale_tools.cpp \
qlogging.cpp \
qmalloc.cpp \
qmetatype.cpp \
qnumeric.cpp \
qregularexpression.cpp \
qromancalendar.cpp \
qsettings.cpp \
qstring.cpp \
qstringbuilder.cpp \
qstringconverter.cpp \
qstringlist.cpp \
qsystemerror.cpp \
qtemporaryfile.cpp \
qtextstream.cpp \
quuid.cpp \
qvariant.cpp \
qversionnumber.cpp \
qvsnprintf.cpp \
HEADERS += \
qabstractfileengine_p.h \
qarraydata.h \
qarraydataops.h \
qarraydatapointer.h \
qbitarray.h \
qbuffer.h \
qbytearray.h \
qbytearraymatcher.h \
qcalendar.h \
qcalendarbackend_p.h \
qcalendarmath_p.h \
qcborstreamwriter.h \
qcborvalue.h \
qcborvalue_p.h \
qchar.h \
qcryptographichash.h \
qdatetime.h \
qdatetime_p.h \
qdir.h \
qdir_p.h \
qdiriterator.h \
qfile.h \
qfileinfo.h \
qglobal.h \
qgregoriancalendar_p.h \
qhash.h \
qiodevice.h \
qjson_p.h \
qjsonarray.h \
qjsondocument.h \
qjsonobject.h \
qjsonparser_p.h \
qjsonvalue.h \
qjsonwriter_p.h \
qlist.h \
qlocale.h \
qlocale_tools_p.h \
qmap.h \
qmetatype.h \
qnumeric.h \
qregularexpression.h \
qromancalendar_p.h \
qstring.h \
qstringbuilder.h \
qstringconverter_p.h \
qstringconverter.h \
qstringlist.h \
qstringmatcher.h \
qsystemerror_p.h \
qtemporaryfile.h \
qtextstream.h \
quuid.h \
qvector.h \
qversionnumber.h \
include(../src/3rdparty/pcre2/pcre2.pri)
unix {
SOURCES += \
qcore_unix.cpp \
qfilesystemengine_unix.cpp \
qfilesystemiterator_unix.cpp \
qfsfileengine_unix.cpp \
qlocale_unix.cpp
macos {
SOURCES += \
qcore_foundation.mm \
qcore_mac.mm \
qoperatingsystemversion_darwin.mm \
qsettings_mac.cpp
LIBS += \
-framework ApplicationServices \
-framework CoreServices \
-framework Foundation
QMAKE_CXXFLAGS += -fconstant-cfstrings
}
} else {
SOURCES += \
qfilesystemengine_win.cpp \
qfilesystemiterator_win.cpp \
qfsfileengine_win.cpp \
qlocale_win.cpp \
qoperatingsystemversion_win.cpp \
qsettings_win.cpp \
qsystemlibrary.cpp \
library/registry.cpp
LIBS += -lole32 -ladvapi32 -lkernel32 -lnetapi32
mingw: LIBS += -luuid
clang: QMAKE_CXXFLAGS += -fms-compatibility-version=19.00.23506 -Wno-microsoft-enum-value
}
load(qt_tool)
Reference in New Issue View Git Blame Copy Permalink