10075973e2
this is needed by webkit's creative directory layout. Change-Id: I2317162c11696d2820423d63563b10d3024a6cb6 Reviewed-by: Joerg Bornemann <joerg.bornemann@nokia.com>
34 lines
1.2 KiB
Plaintext
34 lines
1.2 KiB
Plaintext
load(exclusive_builds)
|
|
CONFIG = lex yacc warn_on debug exceptions $$CONFIG
|
|
|
|
!build_pass:exists($$_PRO_FILE_PWD_/sync.profile) {
|
|
# If the install directory is a build directory, we tell syncqt to do a -developer-build.
|
|
QTDIR = $$[QT_HOST_DATA]
|
|
exists($$QTDIR/.qmake.cache) {
|
|
QTFWD = -module-fwd $$QTDIR/mkspecs/modules -developer-build
|
|
} else {
|
|
isEmpty(MODULE_QMAKE_OUTDIR): MODULE_QMAKE_OUTDIR = $$OUT_PWD
|
|
modpath = $$MODULE_QMAKE_OUTDIR/mkspecs/modules
|
|
QTFWD = -module-fwd $$modpath -cache-module-fwd
|
|
unset(modpath)
|
|
}
|
|
|
|
qtPrepareTool(QMAKE_SYNCQT, syncqt)
|
|
|
|
isEmpty(MODULE_BASE_OUTDIR): MODULE_BASE_OUTDIR = $$OUT_PWD
|
|
MSG = $$quote($$QMAKE_SYNCQT -qtdir $$[QT_HOST_DATA/get] $$QTFWD -generator $$MAKEFILE_GENERATOR -outdir $$MODULE_BASE_OUTDIR $$_PRO_FILE_PWD_)
|
|
!silent:message($$MSG)
|
|
system($$MSG) {
|
|
# success! Nothing to do
|
|
} else {
|
|
error("Failed to run: $$MSG")
|
|
}
|
|
|
|
unset(QTFWD)
|
|
}
|
|
|
|
# Populate the installdir which will be passed to qdoc in the default_post.prf
|
|
# This allows a project to remove the installdir if need be, to trigger building online docs,
|
|
# which Qt Creator does.
|
|
QMAKE_DOCS_INSTALLDIR = $$[QT_INSTALL_DOCS]
|