95a05904b9
Add a 'd' to debug builds to allow both release and debug builds to be used. - Add .def-files for Debug - Build all libraries debug/release - Add description to README.qt - Differentiate debug/release in qmake.conf. Task-number: QTBUG-28196 Change-Id: Ib3081004a6ed2ad71d353244154684d2e0ebbc86 Reviewed-by: Andy Shaw <andy.shaw@digia.com>
30 lines
1.0 KiB
Plaintext
30 lines
1.0 KiB
Plaintext
# WinCE does not have a platform directory for .prf files, and the
|
|
# win32 directory is searched for .prfs by qmake on WinCE. Ideally
|
|
# there should be a features/wince/opengl.prf which contains the wince
|
|
# block below.
|
|
|
|
wince* {
|
|
include(../unix/opengl.prf)
|
|
} else {
|
|
contains(QT_CONFIG, opengles2) {
|
|
# For Desktop, use the ANGLE library location passed on from configure.
|
|
INCLUDEPATH += $$QMAKE_INCDIR_OPENGL_ES2
|
|
CONFIG(debug, debug|release) {
|
|
QMAKE_LIBDIR += $$QMAKE_LIBDIR_OPENGL_ES2_DEBUG
|
|
contains(QT_CONFIG, angle) {
|
|
LIBS += $$QMAKE_LIBS_OPENGL_ES2_DEBUG
|
|
} else {
|
|
LIBS += $$QMAKE_LIBS_OPENGL_ES2
|
|
}
|
|
} else {
|
|
LIBS += $$QMAKE_LIBS_OPENGL_ES2
|
|
QMAKE_LIBDIR += $$QMAKE_LIBDIR_OPENGL_ES2_RELEASE
|
|
}
|
|
DEFINES += QT_OPENGL_ES_2 QT_OPENGL_ES_2_ANGLE
|
|
QT_CONFIG -= opengl
|
|
} else {
|
|
QMAKE_LIBS += $$QMAKE_LIBS_OPENGL
|
|
QMAKE_LFLAGS += $$QMAKE_LFLAGS_OPENGL
|
|
}
|
|
}
|