21b5c7875c
First of all cmake and qmake used a different standard. Secondly, the qmake logic enforced lvl 23 (if it was installed which is the case on the failing machine). When this is combined withf71a400bf6which requires lvl 28 API to build, the android build fails to compile. cmake logic was even worse as it enforced lvl 21 API to be used if installed. This change requires pick to 5.15 asf71a400bf6was picked as well. Pick-to: 5.15 Change-Id: I89a7193b711b8bf927d02907343a49d6f27082ce Reviewed-by: Eskil Abrahamsen Blomfeldt <eskil.abrahamsen-blomfeldt@qt.io>
22 lines
1009 B
Plaintext
22 lines
1009 B
Plaintext
API_VERSION_TO_USE = $$(ANDROID_API_VERSION)
|
|
isEmpty(API_VERSION_TO_USE): API_VERSION_TO_USE = $$API_VERSION
|
|
isEmpty(API_VERSION_TO_USE): API_VERSION_TO_USE = android-28
|
|
|
|
ANDROID_JAR_FILE = $$ANDROID_SDK_ROOT/platforms/$$API_VERSION_TO_USE/android.jar
|
|
!exists($$ANDROID_JAR_FILE) {
|
|
ANDROID_API_VERSION = $$section(API_VERSION_TO_USE, -, 1, 1) # Get version number from android-XY to ensure numeric comparison
|
|
ANDROID_API_VERSIONS = $$files($$ANDROID_SDK_ROOT/platforms/*)
|
|
for (VERSION, ANDROID_API_VERSIONS) {
|
|
BASENAME = $$basename(VERSION)
|
|
BASENAME = $$section(BASENAME, -, 1, 1)
|
|
greaterThan(BASENAME, $$ANDROID_API_VERSION): ANDROID_API_VERSION = $$BASENAME
|
|
}
|
|
API_VERSION_TO_USE = android-$$ANDROID_API_VERSION
|
|
ANDROID_JAR_FILE = $$ANDROID_SDK_ROOT/platforms/$$API_VERSION_TO_USE/android.jar
|
|
}
|
|
!exists($$ANDROID_JAR_FILE) {
|
|
error("No suitable Android SDK platform found. Minimum version is $${API_VERSION_TO_USE}.")
|
|
}
|
|
JAVACLASSPATH += $$ANDROID_JAR_FILE
|
|
|