1456b8091a
For nmake and VS projects we added the NDEBUG define for the release
configuration unconditionally within the qmake generators. To undefine
it, users had to use a nasty work-around.
Now, define NDEBUG within the MSVC mkspecs. In order to do that we
introduce the DEFINES_RELEASE and DEFINES_DEBUG variables that are
merged into DEFINES in default_pre.prf.
Users can unset NDEBUG by writing
DEFINES -= NDEBUG
in their .pro file.
Note that DEFINES_RELEASE and DEFINES_DEBUG are merged in
default_pre.prf in order to give extra compilers (like moc) the chance
to see the fully resolved DEFINES variable. This is different from the
QMAKE_CFLAGS_(DEBUG|RELEASE) variables that get merged in default_post.prf.
Fixes: QTBUG-78071
Change-Id: I381770a1d2f974fbae9b09a2254e3f2fc7842b68
Reviewed-by: Kai Koehne <kai.koehne@qt.io>
36 lines
1.0 KiB
Plaintext
36 lines
1.0 KiB
Plaintext
# This file is loaded by qmake right before each actual project file.
|
|
# Note that evaluating variable assignments from the command line
|
|
# still happens in between these two steps.
|
|
|
|
# In early configure setup; nothing useful to be done here.
|
|
isEmpty(QMAKE_CXX): return()
|
|
|
|
load(exclusive_builds)
|
|
CONFIG = \
|
|
lex yacc debug exceptions depend_includepath \
|
|
testcase_targets import_plugins import_qpa_plugin \
|
|
$$CONFIG
|
|
|
|
!build_pass:!isEmpty(QT_LICHECK):!QTDIR_build {
|
|
#
|
|
# call license checker (but cache result for one day)
|
|
#
|
|
today = $$section(_DATE_, " ", 0, 2)
|
|
!isEqual(QMAKE_LICHECK_TIMESTAMP, $$today) {
|
|
!system("$$system_quote($$system_path($$[QT_HOST_BINS/src]/$$QT_LICHECK)) check" \
|
|
"$$QT_RELEASE_DATE $$[QMAKE_SPEC] $$[QMAKE_XSPEC]"): \
|
|
error("License check failed! Giving up ...")
|
|
|
|
cache(QMAKE_LICHECK_TIMESTAMP, set stash, today)
|
|
}
|
|
unset(today)
|
|
}
|
|
|
|
CONFIG(debug, debug|release) {
|
|
DEFINES += $$DEFINES_DEBUG
|
|
} else {
|
|
DEFINES += $$DEFINES_RELEASE
|
|
}
|
|
|
|
load(toolchain)
|