1cc571593a
cf53aa21bfand3aaa5d6b32were reverted because of reconstruction in 5.7. defineTest(qtConfTest_checkCompiler) in configure.pri is smart enough to cover the case ina9474d1260. DirectWrite: Fix advances being scaled to 0 Since131eee5cd, the stretch of a font can be 0, meaning "whatever the font provides". In combination withec7fee96, this would cause advances in the DirectWrite engine to be scaled to 0, causing the QRawFont test to fail. Conflicts: configure mkspecs/features/uikit/device_destinations.sh mkspecs/features/uikit/xcodebuild.mk src/corelib/global/qglobal.cpp src/corelib/global/qnamespace.qdoc src/plugins/platforms/cocoa/qcocoamenuitem.h src/plugins/platforms/windows/qwindowsservices.cpp src/plugins/platformthemes/gtk3/qgtk3dialoghelpers.cpp src/plugins/platforms/windows/qwindowsfontenginedirectwrite.cpp src/widgets/kernel/qapplication.cpp tests/auto/widgets/dialogs/qfiledialog/tst_qfiledialog.cpp tests/auto/widgets/dialogs/qfiledialog2/tst_qfiledialog2.cpp Change-Id: I4656d8133da7ee9fcc84ad3f1c7950f924432d1e
42 lines
1.1 KiB
Plaintext
42 lines
1.1 KiB
Plaintext
#
|
|
# W A R N I N G
|
|
# -------------
|
|
#
|
|
# This file is not part of the Qt API. It exists purely as an
|
|
# implementation detail. It may change from version to version
|
|
# without notice, or even be removed.
|
|
#
|
|
# We mean it.
|
|
#
|
|
|
|
equals(TEMPLATE, subdirs): return()
|
|
|
|
# It's likely that these extra flags will be wrong for host builds,
|
|
# and the bootstrapped tools usually don't need them anyway.
|
|
host_build:cross_compile: return()
|
|
|
|
# The headersclean check needs defines and includes even for
|
|
# header-only modules.
|
|
DEFINES += $$EXTRA_DEFINES
|
|
INCLUDEPATH += $$EXTRA_INCLUDEPATH
|
|
|
|
# The other flags are relevant only for actual libraries.
|
|
equals(TEMPLATE, aux): return()
|
|
|
|
QMAKE_LIBDIR += $$EXTRA_LIBDIR
|
|
QMAKE_FRAMEWORKPATH += $$EXTRA_FRAMEWORKPATH
|
|
|
|
# Static libs need no rpaths
|
|
static: return()
|
|
|
|
for (rp, EXTRA_RPATHS) {
|
|
absrp = $$absolute_path($$rp, $$[QT_INSTALL_LIBS])
|
|
!isEqual(absrp, $$rp) {
|
|
isEmpty(QMAKE_REL_RPATH_BASE)|!contains(INSTALLS, target): \
|
|
rp = $$absrp
|
|
else: \
|
|
rp = $$relative_path($$absrp, $$qtRelativeRPathBase())
|
|
}
|
|
QMAKE_RPATHDIR += $$rp
|
|
}
|