84e98fd9d2
For some reference platforms and SDKs we will need to pass in extra paths. Currently users have to modify the mkspec to adjust paths or set environment variables that will be picked up. This change introduces the -device <name> and -device-option <key=value> option. The key value pairs will be written to a qdevice.pri and can be used by the qmake.conf of the device spec. The reason to not save the key value pairs in qconfig.pri is becase of the fact that the device spec loads the qdevice.pri earlier than the qconfig.pri. qdevice.pri allows the mkspec to set the compiler flags and qconfig.pri allows configure to add to those compiler flags. Done-with: Holger Freyther Change-Id: I931a197b8be72397e1eedfee09502eefc01c9d4f Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com> Reviewed-by: Girish Ramakrishnan <girish.1.ramakrishnan@nokia.com> Reviewed-by: Johannes Zellner <johannes.zellner@nokia.com> Reviewed-by: Donald Carr <donald.carr@nokia.com>
28 lines
669 B
Plaintext
28 lines
669 B
Plaintext
# Load generated qdevice.pri
|
|
exists($$_QMAKE_CACHE_) {
|
|
# set in default_pre, so it's the first place to check for qdevice.pri
|
|
DIR = $$fromfile($$_QMAKE_CACHE_, QT_BUILD_TREE)
|
|
!isEmpty(DIR):DEVICE_PRI = $$DIR/mkspecs/qdevice.pri
|
|
}
|
|
|
|
isEmpty(DEVICE_PRI) {
|
|
# OUTDIR environ is set by configure (arch detection) and compile.test
|
|
DIR = $$(OUTDIR)
|
|
!isEmpty(DIR):DEVICE_PRI = $$DIR/mkspecs/qdevice.pri
|
|
}
|
|
|
|
isEmpty(DEVICE_PRI) {
|
|
DIR = $$[QT_HOST_DATA]
|
|
!isEmpty(DIR):DEVICE_PRI = $$DIR/mkspecs/qdevice.pri
|
|
}
|
|
|
|
isEmpty(DEVICE_PRI) {
|
|
error(Could not locate qdevice.pri)
|
|
}
|
|
|
|
exists($$DEVICE_PRI):include($$DEVICE_PRI)
|
|
|
|
unset(DEVICE_PRI)
|
|
unset(DIR)
|
|
|