b0a7af6b4d
Extension .a for Mac and Linux and .lib for Windows. Change-Id: I1e979b2a6b29eeab35620aa0bbabb27f10cdda68 Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>
63 lines
2.4 KiB
Plaintext
63 lines
2.4 KiB
Plaintext
!contains(DESTDIR, (/|.:[/\\\\]).*):QMAKE_RESOLVED_TARGET = $${OUT_PWD}/
|
|
!isEmpty(DESTDIR):QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${DESTDIR}/
|
|
|
|
win32 {
|
|
QMAKE_RESOLVED_TARGET ~= s,/,\\,
|
|
contains(TEMPLATE, .*lib) {
|
|
isEmpty(TARGET_VERSION_EXT):!isEmpty(VERSION) {
|
|
TARGET_VERSION_EXT = $$section(VERSION, ., 0, 0)
|
|
isEqual(TARGET_VERSION_EXT, 0):unset(TARGET_VERSION_EXT)
|
|
}
|
|
static:TARGET_EXT = .lib
|
|
else:TARGET_EXT = .dll
|
|
} else {
|
|
TARGET_EXT = .exe
|
|
}
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}$${TARGET_VERSION_EXT}$${TARGET_EXT}
|
|
} else {
|
|
contains(TEMPLATE, .*lib):LIBPREFIX = lib
|
|
|
|
macx {
|
|
equals(TEMPLATE, lib) {
|
|
lib_bundle {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}.framework/$${TARGET}
|
|
} else {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}
|
|
!plugin {
|
|
TEMP_VERSION = $$section(VERSION, ., 0, 0)
|
|
isEmpty(TEMP_VERSION):TEMP_VERSION = 1
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}.$${TEMP_VERSION}
|
|
}
|
|
static:QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}.$${QMAKE_EXTENSION_STATICLIB}
|
|
else:QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}.$${QMAKE_EXTENSION_SHLIB}
|
|
}
|
|
} else {
|
|
app_bundle {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}.app/Contents/MacOS/$${TARGET}
|
|
} else {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}
|
|
}
|
|
}
|
|
} else {
|
|
equals(TEMPLATE, lib) {
|
|
static {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}.a
|
|
} else:plugin {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}.so
|
|
} else {
|
|
TEMP_VERSION = $$VERSION
|
|
isEmpty(TEMP_VERSION):TEMP_VERSION = 1.0.0
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}.so.$${TEMP_VERSION}
|
|
}
|
|
} else {
|
|
QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}
|
|
}
|
|
}
|
|
}
|
|
|
|
unset(TARGET_VERSION_EXT)
|
|
unset(TARGET_EXT)
|
|
unset(LIBPREFIX)
|
|
unset(TEMP_VERSION)
|
|
|