176a216f4f
In NDK version r18, the libc++.so file we used for clang has been removed. However, in r17 this was actually just redirecting to libc++_shared.so, which is still available in r18, so we can link directly to that instead. [ChangeLog][Android] Fix build issue with Android NDK r18 and clang. Task-number: QTBUG-70631 Change-Id: I658c0cabf49f27a47f38305de3c86067c8b18b25 Reviewed-by: Liang Qi <liang.qi@qt.io> Reviewed-by: BogDan Vatra <bogdan@kdab.com>
48 lines
2.0 KiB
Plaintext
48 lines
2.0 KiB
Plaintext
# qmake configuration for building with android-clang
|
|
MAKEFILE_GENERATOR = UNIX
|
|
QMAKE_PLATFORM = android
|
|
QMAKE_COMPILER = gcc clang llvm
|
|
|
|
CONFIG += android_install unversioned_soname unversioned_libname plugin_with_soname android_deployment_settings
|
|
|
|
include(../common/linux.conf)
|
|
include(../common/gcc-base-unix.conf)
|
|
include(../common/clang.conf)
|
|
include(../common/android-base-head.conf)
|
|
|
|
NDK_LLVM_PATH = $$NDK_ROOT/toolchains/llvm/prebuilt/$$NDK_HOST
|
|
QMAKE_CC = $$NDK_LLVM_PATH/bin/clang
|
|
QMAKE_CXX = $$NDK_LLVM_PATH/bin/clang++
|
|
|
|
equals(ANDROID_TARGET_ARCH, armeabi-v7a): \
|
|
QMAKE_CFLAGS += -target armv7-none-linux-androideabi
|
|
else: equals(ANDROID_TARGET_ARCH, armeabi): \
|
|
QMAKE_CFLAGS += -target armv5te-none-linux-androideabi
|
|
else: equals(ANDROID_TARGET_ARCH, arm64-v8a): \
|
|
QMAKE_CFLAGS += -target aarch64-none-linux-android
|
|
else: equals(ANDROID_TARGET_ARCH, x86): \
|
|
QMAKE_CFLAGS += -target i686-none-linux-android -mstackrealign
|
|
else: equals(ANDROID_TARGET_ARCH, x86_64): \
|
|
QMAKE_CFLAGS += -target x86_64-none-linux-android
|
|
else: equals(ANDROID_TARGET_ARCH, mips): \
|
|
QMAKE_CFLAGS += -target mipsel-none-linux-android
|
|
else: equals(ANDROID_TARGET_ARCH, mips64): \
|
|
QMAKE_CFLAGS += -target mips64el-none-linux-android
|
|
|
|
QMAKE_CFLAGS += -gcc-toolchain $$NDK_TOOLCHAIN_PATH
|
|
QMAKE_LINK = $$QMAKE_CXX $$QMAKE_CFLAGS -Wl,--exclude-libs,libgcc.a
|
|
QMAKE_CFLAGS += -DANDROID_HAS_WSTRING --sysroot=$$NDK_ROOT/sysroot \
|
|
-isystem $$NDK_ROOT/sysroot/usr/include/$$NDK_TOOLS_PREFIX \
|
|
-isystem $$NDK_ROOT/sources/cxx-stl/llvm-libc++/include \
|
|
-isystem $$NDK_ROOT/sources/android/support/include \
|
|
-isystem $$NDK_ROOT/sources/cxx-stl/llvm-libc++abi/include
|
|
|
|
ANDROID_SOURCES_CXX_STL_LIBDIR = $$NDK_ROOT/sources/cxx-stl/llvm-libc++/libs/$$ANDROID_TARGET_ARCH
|
|
|
|
ANDROID_STDCPP_PATH = $$ANDROID_SOURCES_CXX_STL_LIBDIR/libc++_shared.so
|
|
ANDROID_CXX_STL_LIBS = -lc++_shared
|
|
|
|
QMAKE_CFLAGS_OPTIMIZE_SIZE = -Oz
|
|
|
|
include(../common/android-base-tail.conf)
|